cAN1011	;Selectie item ;%AN101 ; [ 01/04/01  8:18 AM ]
	G 1
	;
T0	;Selectie item ;
	;
T0F	;Sélection sujet ;
	;
T0E	;Selection item ;
	;
S1(S1,S2)	         ; volgende (1) of vorige (-1) index
	I $G(RIND2) D S11(S1,S2) G S1Z  ; via index2
S1A	K J S J=$O(@RSD@(S1),S2) I $L(J) S J(0)=^(J)
S1B	I $E(RSI(1))'="*",$E(J,1,$L(RSJ(1)))'=RSJ(1) S J=""
S1C	I $E(RSI(1))="*",$L(J),$P(J," ")'[RSJ(1) S S1=J G S1A
S1D	I J="",S2<0 S J=0
S1Z	Q
	;
S11(S1,S2)	; via index 2
	S $ZT="TRAP^cAN000"
	S S1=$P(S1," ")
	I $L($G(J(0))) S J=S1 G S11C
	I '$D(RSL),$L(S1) D  ; bepalen 1ste $o
	. I S2'=-1 S S1=$O(@RSD@(S1),-1) Q   ; voorwaarts 
	. ; achterwaarts
	. I S1'?1.N1"~" S S1=$O(@RSD@(S1),1) Q   ; alfanumerische input
	. S J=$O(@RSD@(""),-1)
	. I J'?1.N S S1=$O(@RSD@(S1),1) Q   ; index bevat ook alfanumerische inputs
	. X "S S1=RSJ(1)+1*1E"_($L(J)-1)
S11A	S J=$O(@RSD@(S1),S2),J(0)=""
	I J="" G S11Z
	I $E(RSI(1))="*" G S11B
	I $E(J,1,$L(RSJ(1)))=RSJ(1) G S11B
	; I +RSJ(1)'=RSJ(1)&(+J'=J) S J="" G S11Z
	I +RSJ(1)'=RSJ(1) S J="" G S11Z  ; alfanum. input
	I +J'=J S S1=J G S11A  ; num. input, apfanum. index
	I (+RSJ(1)=RSJ(1)&RSJ(1)&(+J=J)) D  G S11A  ; num. input, num index
	. N i
	. ; voorwaarts
	. I S2'=-1 D  Q
	.. S i=RSJ(1)*10 F  Q:(i-1)'<J  S i=i*10
	.. S S1=i-1
	. ; achterwaarts
	. S i=RSJ(1) F  Q:(i_9)'<J  S i=i_9
	. I i=RSJ(1) S S1=0 Q
	. S S1=i+1
S11B	I $E(RSI(1))="*",$L(J),J'[RSJ(1) S S1=J G S11A
	I J="" S:S2<0 J=0 G S11Z
S11C	S J(0)=$O(@RSD@(J,J(0)),S2) I '$L(J(0)) G S11A
S11Z	S:S2<0&'$L(J) J=0 Q
	;
	; tonen van de lijn
S2	N K,S1,S2,UI1,VAN,LEN,TOT,MAX,ZZ S $ZT="TRAP^cAN000"
S2A	S MAX=$P(QW(QW),D,4)-($P(QW(QW),D,5)*2),ZZ=$J("",MAX)
S2B	S S1="" F  S S1=$O(RSM("LAY",S1)) Q:S1=""  S S2=RSM("LAY",S1) D
	. S UI1=RSL(I,0),K=$P($G(@RSREF@($P(S2,D)\100-1)),D,$P(S2,D)#100)
	. S VAN=$P(S2,D,2),LEN=$P(S2,D,3),TOT=VAN+LEN-1
	. I $L($P(S2,D,5)) X $P(S2,D,5) ; wat ipv K
	. I $P(S2,D,4) S K=$J(K,LEN)    ; rechts
	. E  S K=$E(K_$J("",LEN),1,LEN) ; links
	. S ZZ=$S(VAN>1:$E(ZZ,1,VAN-1),1:"")_K_$S(TOT<MAX:$E(ZZ,TOT+1,MAX),1:"")
S2Y	W /CUP(I+2,1),ZZ S RSL(I,9)=ZZ
S2Z	Q
	;
	; test op niveau & 2° input & filter
S3()	N S1,S2,UI1 S S1=1
S3A	S UI1=J(0),S2=+$P($G(@RSREF@(0)),D,30) I S2'=RSN S S1=0
S3B	I S1,$L($G(RSJ(2))) D
	. S S2=$P($G(^(RSM(2,"B")\100-1)),D,RSM(2,"B")#100)
	. S S2=$$DP^cAFA1($$UC^cAFA1(S2))
	. I $E(RSI(2))'="*",$E(S2,1,$L(RSJ(2)))'=RSJ(2) S S1=0
	. I $E(RSI(2))="*",S2'[RSJ(2) S S1=0
S3C	I S1,$L($G(RSFLT)) X RSFLT S S1=$T
S3Z	Q S1
	;
	; balk aan/af
BALK(C)	W /CUP(II+2,1),/SGR(C),$G(RSL(II,9),$J("",$P(QW(QW),D,4)-($P(QW(QW),D,5)*2)))
BALKZ	W /CUP(II+2,1),/WDSP Q
	;
1	N RIND2
	S $ZT="TRAP^cAN000"
	S RIND2=0
	W /WSCROFF,/CUP(3,1),/WCMD
11	S RSJ(1)=$$DP^cAFA1($$UC^cAFA1(RSI(1))),RSJ(2)=$$DP^cAFA1($$UC^cAFA1(RSI(2))) D
	. I $L($G(RSM(1,"X"))) S RSJ(1)=RSJ(1)_" "
	. D IND(RSM(1,"B"))  ; KU : 20.02.07
	. I $L($P(RSM(1,"B"),D,2)) D  ; via multiple
	.. S RSI(1)="*",RSJ(1)=""
	.. F I=2:1 S J=$P(RSM(1,"B"),D,I) Q:J=""  S RSD=$NA(@RSD@(J))
13	I RSJ(1)="",$L(RSJ(2)),$E(RSI(1))'="*",$E(RSI(2))'="*" D
	. S RSJ(1)=RSJ(2),RSJ(2)=""
	. I $L($G(RSM(2,"X"))) S RSJ(1)=RSJ(1)_" "
	. D IND(RSM(2,"B"))  ; KU : 20.02.07
	. I $O(@RSD@(""))="" D
	.. S RSJ(2)=$P(RSJ(1)," "),RSJ(1)=""
	.. D IND(RSM(1,"B"))  ; KU : 20.02.07
	I $G(RIND2) S RSJ(1)=$P(RSJ(1)," "),RSJ(2)=$P(RSJ(2)," ")  ; KU : 03.07.07
15	K J S J=$S($E(RSI(1))="*":"",1:RSJ(1))_" "
	S II=1,JJ=$P(QW(QW),D,3)-($P(QW(QW),D,5)*2)-2,RK=0
16	K RSL I $L($G(RSX)) D
	. N R,UI1
	. I RSDD=1 S UI1=$G(@$G(^DMC(UQC,USC,"DATA","OUD"))@(RSX))
	. I RSDD=2 S UI1=RSX_" "
	. I RSDD>2 S UI1=RSX
	. I $L(UI1) S I=RSM(1,"B") D
	.. I $L($P(I,D,2)) S J=$O(^DMC(UQC,USC,"MULTI",$P(I,D),"~"),-1) I $L(J) S I=^(J)
	.. I I,$P(I,D,2)="" S R=$P($G(@RSREF@(I\100-1)),D,I#100) Q
	. S J=$$DI^cAN000($G(R),RSX),RSX=J  ; ,RSX=$P(J," ",2)  ; KU : 20.02.07
	. I $L($G(RSM(1,"X"))) S J=J_"~",RSJ(1)=""
	. I $G(RIND2) S J(0)=$P(J," ",2),RSX=$P(J," ",2),J=$P(J," "),RSL=""  ; KU : 20.02.07
	. F I=1:1:JJ\2+1 D S1(J,-1) Q:J=0
17	S I=0 F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 S RSL(I)=J,RSL(I,0)=J(0) D S2 I $S('$G(RIND2):J=$G(RSX),1:J(0)=$G(RSX)) S II=I  ; KU : 20.02.07
19	I I=1,'RSCONF,'$L($G(RSX)) S RK=28 G 3
	;
	; scroll met balk
2	S RSV=RK D BALK(7) K REFRESH
21	D ^cAFA0(RK,0,0,0,0,"23\24\25\26\31\32\70\84"_RSKEYS,0,0,0)
	;
3	; speciale funkties
320	I $D(^DMC(UQC,USC,"SYN",0,0,RK)) G Y:$D(^(RK,0)) I $D(^(1)) X ^(1) G 2:$G(REFRESH),Y
323	I RK=23 D  G 2                                              ; Home
	. I '$D(RSL(1)) D BEL Q
	. D BALK(0) S II=1 I '$D(RSL(JJ)) Q
	. K RSL,J W /CUP(3,1),/WCMD
	. S I=0,J=$S($E(RSI(1))="*":"",1:RSJ(1))_" " F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 D
	.. S RSL(I)=J,RSL(I,0)=J(0)
	. F I=JJ:-1:1 I $D(RSL(I)) D S2 S II=I
324	I RK=24 D  G 2                                              ; End
	. I '$D(RSL(1)) D BEL Q
	. D BALK(0) S II=$O(RSL(""),-1) I '$D(RSL(JJ)) Q
	. K RSL,J W /CUP(3,1),/WCMD
	. S I=0,J=$S($E(RSI(1))="*":"",1:RSJ(1))_"~" F  Q:I=JJ  D S1(J,-1) Q:J=0  I $$S3 S I=I+1 D
	.. F II=I:-1:2 M RSL(II)=RSL(II-1) K RSL(II-1)
	.. S RSL(1)=J,RSL(1,0)=J(0)
	. F I=1:1:JJ I $D(RSL(I)) D S2 S II=I
325	I RK=25 D  G 2                                              ; PgUp
	. I '$D(RSL(1)) D BEL Q
	. D BALK(0) I II=1 S RSV=RK
	. S II=1 I RK'=RSV!'$D(RSL(JJ)) Q
	. S I=1,J=RSL(1),J(0)=RSL(1,0) F  Q:I=JJ  D S1(J,-1) Q:J=0  I $$S3 S I=I+1 D
	.. F II=JJ:-1:2 K RSL(II) M RSL(II)=RSL(II-1)
	.. K RSL(1) S RSL(1)=J,RSL(1,0)=J(0)
	. F I=JJ:-1:1 D S2 S II=I
326	I RK=26 D  G 2                                              ; PgDn
	. I '$D(RSL(1)) D BEL Q
	. D BALK(0) I II=JJ S RSV=RK
	. S II=$O(RSL(""),-1) I RK'=RSV!'$D(RSL(JJ)) Q
	. S I=1,J=RSL(JJ),J(0)=RSL(JJ,0) F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 D
	.. F II=1:1:JJ-1 K RSL(II) M RSL(II)=RSL(II+1)
	.. K RSL(JJ) S RSL(JJ)=J,RSL(JJ,0)=J(0)
	. F I=1:1:JJ D S2 S II=I
327	I RK=27 G Y                                                 ; Esc
328	I RK=28 S K=$G(RSL(II,0)) S:K="" RK=29 G Y                  ; Enter
329	I RK=29 G Y                                                 ; Tab
331	I RK=31 D  G 2                                              ; Pijl ^
	. I '$D(RSL(1)) D BEL Q
	. D BALK(0)
	. I II>1 S II=II-1 Q
	. S I=0,J=RSL(1),J(0)=RSL(1,0) F  Q:I  D S1(J,-1) Q:J=0  I $$S3 D
	.. F II=JJ:-1:2 I $D(RSL(II-1)) M RSL(II)=RSL(II-1)
	.. S RSL(1)=J,RSL(1,0)=J(0)
	.. F I=JJ:-1:1 I $D(RSL(I)) D S2 S II=I
332	I RK=32 D  G 2                                              ; Pijl v
	. I '$D(RSL(1)) D BEL Q
	. D BALK(0)
	. I II<$O(RSL(""),-1) S II=II+1 Q
	. I $D(RSL(JJ)) S I=0,J=RSL(JJ),J(0)=RSL(JJ,0) F  Q:I  D S1(J,1) Q:J=""  I $$S3 D
	.. F II=1:1:JJ-1 M RSL(II)=RSL(II+1)
	.. S RSL(JJ)=J,RSL(JJ,0)=J(0)
	.. F I=1:1:JJ D S2 S II=I
370	I RK=70 D  G 2                                              ; ^F
	. I '$D(RSL(1))!'RSCONF(RK) D BEL Q
	. N UI1
	. S UI1=RSL(II,0)
	. D ^cA338,R^cAN200(RSDMS,"","","",$$IDEM^cAFA1),^cA339
384	I RK=84 D  G 2                                              ; ^T
	. I '$D(RSL(1)) D BEL Q
	. N TXTUI1,TXTUQC,TXTUSC,R
	. S (R,TXTUI1)=RSL(II,0) I RSDD<3 S R=$P(R," ",3-RSDD)
	. I '$D(^DMC(UQC,USC,"DATA","TXT"))!'$L(R) D BEL Q
	. S TXTUQC=UQC,TXTUSC=USC,R=$NA(@^("TXT")@(R),3)
	. D RT^cAN210("TXT",0,0,0,R)
	;
39	D BEL G 21
	;
Y	D BALK(0) K RSD,RSL,RSX
YZ	Q
	;
BEL	W $C(7) Q
	;
IND(BIN)	; bepalen indexbestand
	S RSD=$NA(@RSQ2@($P(BIN,D))),RIND2=0
	I '$D(Q(49)) G INDZ
	S RSD=$P($$REF^cAFA10(.Q,RSDMS,$P(BIN,D)),D,3),RIND2=1  ; via index2
	I '$L(RSD) S RSD=$P($$REF^cAFA10(.Q,RSDMS,$P(BIN,D)),D,2),RIND2=0  ; via index (uitzonderlijk !)
INDZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09