cAN209	;Wijzigen in groep; %AN200 [ 02/15/01  5:18 PM ]
	;
	G 1
	;
T0	;Wijzigen in groep;
T1	;Niet wijzigbaar;
T2	;Bevestiging\".[] = doorgaan   ,[] = hernemen";
	;
T0F	;Modification 'en masse';
T1F	;Non modifiable;
T2F	;Confirmation\".[] = continuer   ,[] = reprendre";
	;
T0E	;Modification in group of;
T1E	;Cannot be modified;
T2E	;Confirmation\".[] = continue   ,[] = cancel";
	;
T0D	;Ändern in Gruppe;
T1D	;Nicht änderbar;
T2D	;Bestätigung\".[] = durchgehen   ,[] = wiedernehmen";
	;
	; pagina tonen
1	K A,B F I=1:1:SW3 S B(I)=USL
11	S SW2=1,UI1="",(UQM,USM)=""
13	K C D S1^cAN000(SW2) S SW5=1
15	W /WSCROFF F U1=1:1 Q:'$D(C(U1))  D S2^cAN000(U1)
17	W /WSCRON S SW5=0
19	S (SW1,U1)=0,U1(0)="",U1=$O(C(U1)),RK=28
	;
	; nummer element
2	D ^cAN006("",22,UQM,USM,UFU,SW4,"","")
21	I K="-" G YZ
23	I RK=25,SW2>1 S (K,U1)="."_(SW2-1) G 3
25	I RK=26,SW2<SW4 S (K,U1)="."_(SW2+1) G 3
27	I RK'=28 G 2
29	I 'K S (K,U1)="."_$TR(K,"-",",")
	;
	; Uitvoeren keuze
3	I $E(K)="." S U1=$E(K,2,$L(K)),K="-" G 2:U1>SW4!($E(U1)=0) S:$L(U1) SW2=U1 G 13:$L(U1),2
31	S U1=+K G 2:'$D(C(U1)) D M^cAN000(U1) S U1(0)=U1
33	I $L(U2(15)),@U2(15) D ER^cAN000($P($T(@("T1"_QT)),U,2)) G 2
	;
	; Toekennen waarde rubriek
4	S (BIND,U7)=U2(16),K="" I 'U7 S U2(15)=1 G 33     ; B-index
40	I $L(U2(17)) X U2(17) G 51                        ; X ipv B-index
41	I $L(U2(7)) X U2(7)                               ; X vóór input
43	I $L(U2(19)) X U2(19) I $L(U2(11)),@U2(11) G 51   ; X ipv input
45	I $L(U2(19)),$L(U2(11)) S K="-"
47	I $L(U2(19)) G 51
	;
	; manuele input
5	D ^cAN100
51	I K="-" G 2
53	I K="," G 2
55	S INPUT=K ; onthouden input
	;
	; tonen gekozen rubriek
6	S U3=K I $L(U2(8)) X U2(8)
61	W /CUP(2,2),@F6,$P(U2(1),D,QTU),@F9,": ",U3,@F1
	;
	;  standaard selectie + vraag bevestiging
7	D ^cAN003(4,^DMA(UQA,USA,0,"DMS")) I K="-" G 13
71	S R="K\22\3\"_$P($T(@("T2"_QT)),U,2)_"\1\\"".,-""[K&($L(K))" D R0 G 7:K="-"!(K=",")
73	S UI1=""
75	F  D ^cAN004("UI1",^DMA(UQA,USA,0,"DMS")) Q:UI1=""  D
	. K A,B D R^cAN000 M A=B D S1 W /WDSP
	. I $L($P(UXX,D,3)) S OK=0 X $P(UXX,D,3) I 'OK Q  ; geen toegang
	. S K=$$PLUS^cANLOCK(UREF,"","",2)
	. K A,B D R^cAN000 M A=B D S1 W /WDSP
	. D M^cAN000(U1(0))                               ; rubriek ophalen
	. S U7=U2(16),K="" I U7>100,U7<(SW3+1*100) S K=$P(B(U7\100),D,U7#100)
	. I U7=BIND D
	.. I $L(U2(15)),@U2(15) Q                         ; niet wijzigbaar
	.. I $L(U2(7)) X U2(7) I K="-"!(K=",") Q          ; X vóór input
	.. S K=INPUT
	.. I $L(U2(12)) X U2(12) I K="-"!(K=",") Q        ; X nà input
	.. D B^cAN000(U7,K),S3^cAN000(K)
	.. S OK=0 I $L($P(UXX,D)) X $P(UXX,D) I 'OK Q
	.. I OK'=1 D U^cAN000 M A=B
	.. I $L($P(UXX,D,2)) X $P(UXX,D,2)
	. L -@UREF
	;
YZ	D C^cA612 Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q
	;
	; Pagina tonen
S1	S SW5=1 K C D S1^cAN000(SW2)
S1A	S U1=0 F  S U1=$O(C(U1)) Q:U1=""  D S2^cAN000(U1),S3,S3^cAN000(K)
S1Z	S SW5=0 K REFRESH Q
	;
	; Data per rubriek
S3	S U7=U2(16),K="" I U7>100,U7<(SW3+1*100) S K=$P(B(U7\100),D,U7#100)
S3A	I $L(U2(17)) X U2(17)
S3Z	Q
	;
ZZ	; 04.04.05 - 14 u 29 * V8.03