cAN2222	;BEHEER VRIJE VELDEN ;%AN222 ; [ 11/29/01  2:07 PM ]
	;
T0	;Beheer vrije velden ;
T1	;Nummer element\"-[] = einde";Rubriek ;
T2	;Wijzigbaar;0[] = neen   1[] = ja;
T3	;Prompt N;
T4	;Prompt F;
T5	;Prompt D; *** wordt voorlopig niet gebruikt ***
T6	;Prompt E;
T7	;Codebestand;
T8	;Data type;[] = tekst   1[] = numeriek   2[] = datum   3[] = ja/neen;tekst;numeriek;datum;ja/neen;
	;
T0F	;Gestion des champs libres ;
T1F	;Numéro d'élément\"-[] = fin";Rubrique ;
T2F	;Modifiable;0[] = non   1[] = oui;
T3F	;Descr. N;
T4F	;Descr. F;
T5F	;Descr. All.;
T6F	;Descr. Ang.;
T7F	;Fichier code;
T8F	;Type donn.;[] = texte   1[] = numérique   2[] = date   3[] = oui/non;texte;numérique;date;oui/non;
	;
T0E	;Free fields ;
T1E	;Number element\"-[] = end";Element ;
T2E	;Can be modified;0[] = no   1[] = yes;
T3E	;Prompt D;
T4E	;Prompt F;
T5E	;Prompt G;
T6E	;Prompt E;
T7E	;Codefile;
T8E	;Data type;[] = text   1[] = numeric   2[] = date   3[] = yes/no;text;numeric;date;yes/no;
	;
	; Window & Titel
1	D P^cA612(16,1,6,80,1,0,0,0,$P($T(@("T1"_QT)),U,3)_U1,0,0,1,0,0)
	; wijzigbaar als prompt is ingevuld
11	S U2(0)=$L($$S2(1,1))+$L($$S2(1,2))+$L($$S2(1,4)),U2(0)=''U2(0)
	;
	; Tonen gegevens + controle
2	W /CUP(1,1),@F1
	; niet wijzigbaar -> alles wissen
	I '$$S2(0,1) D
	. S U2(4)="",U2(18)="" F J=1:1:4 S I="" D S4(1,J)
	; codebestand -> data type + prompten
	S K=$$S2(18,1) I $L(K) D
	. S U2(4)=""
	. F J=1:1:4 I $$S2(1,J)="" S I=$E($$OMS^cAFA1(K,J,2,1),1,10) D S4(1,J)
	; data type -> geen codebestand
	I $$S2(4,1) S U2(18)=""
	; links
	W /CUP(1,1)," 1",@F6,$$S1(2),@F9,/CUP(1,16),": ",$$JN^cAFO1($$S2(0,1))
	W /CUP(2,1)," 2",@F6,$$S1(7),@F9,/CUP(2,16),": "
	S K=$$S2(18,1) I $L(K) W $$COM^cAFO3("CODE.VV",$P(K,"CODE.",2))
	W /CUP(3,1)," 3",@F6,$$S1(8),@F9,/CUP(3,16),": ",$P($T(@("T8"_QT)),U,$$S2(4,1)+4)
	; rechts
	W /CUP(1,41)," 4",@F6,$$S1(3),@F9,/CUP(1,56),": ",$$S2(1,1)
	W /CUP(2,41)," 5",@F6,$$S1(4),@F9,/CUP(2,56),": ",$$S2(1,2)
	W /CUP(3,41)," 6",@F6,$$S1(6),@F9,/CUP(3,56),": ",$$S2(1,4)
	W /CUP(4,41)," 7",@F6,$$S1(5),@F9,/CUP(4,56),": ",$$S2(1,3)
	;
	; Nummer element
6	S R="UV\22\3\"_$P($T(@("T1"_QT)),U,2)_"\1\\$L(K)" D R0 I K="-"!(K=",") G Y
	I K>7!'K G 6
	;
	; Wijzigen veld
7	S UV=+UV
	I UV=1 D S3(2,0,1,1) I K'="-",K'="," D S4(0,1)         ; wijzigbaar
	I U2(0),UV=2,$P($G(^DPAR(0,"SETUP","CODE.VV",0)),D) D    ; codebestand
	. S I=$$S2(18,1) I $L(I) S I=$P(I,"CODE.",2)
	. S I=$$^cANSYN("CODE.VV","",I,1) I I S I="CODE."_I
	. I K'="-",K'="," D S4(18,1)
	I U2(0),UV=3 D S3(7,4,1,1) I K'="-",K'="," D S4(4,1)   ; data type
	I U2(0),UV=4 D S3(3,1,1,10) I K'="-",K'="," D S4(1,1)  ; prompt N
	I U2(0),UV=5 D S3(4,1,2,10) I K'="-",K'="," D S4(1,2)  ; prompt F
	I U2(0),UV=6 D S3(6,1,4,10) I K'="-",K'="," D S4(1,4)  ; prompt E
	I U2(0),UV=7 D S3(5,1,3,10) I K'="-",K'="," D S4(1,3)  ; prompt D
	G 6:K="-"!(K=","),2
	;
	; Aanpassen rubriek
Y	I 'U2(0) D
	. S U2(9)=U2(13)                        ; lengte input = lengte output
	. S U2(10)="",U2(11)="",U2(8)=""        ; commentaar + input + output
	. S U2(19)="S K=$S(RK=31:""-"",1:K)"    ; X ipv input
	;
	I U2(0),'$L($$S2(1,QTU)) G 2            ; minimale vereiste = prompt
	;
	I U2(0),U2(4)="" D                      ; tekstveld
	. S U2(9)=U2(13)
	. S U2(10)="",U2(11)="",U2(8)=""
	. S U2(19)="" I U2(18)="" Q
	. S U2(19)="D SYN^cAN227(U2(18))"
	. S U2(8)="S U3=$$COM^cAFO3(U2(18),K)"
	;
	I U2(0),U2(4)=1 D                       ; numeriek
	. S U2(9)=U2(13)
	. S I="nnnn.nn[] = positief getal   nnnn.nn-[] = negatief getal" D S4(10,1)
	. S I="nnnn.nn[] = nombre positif   nnnn.nn-[] = nombre négatif" D S4(10,2)
	. S I="nnnn.nn[] = positive value   nnnn.nn-[] = negative value" D S4(10,4)
	. S U2(11)="$$W^cAFI2(K,99,1)",U2(8)=""
	. S U2(19)=""
	;
	I U2(0),U2(4)=2 D                       ; datum
	. S U2(9)=8
	. S I="dd.mm.jj[] = bepaalde datum" D S4(10,1)
	. S I="jj.mm.aa[] = date spécifique" D S4(10,2)
	. S I="dd.mm.yy[] = specific date" D S4(10,4)
	. S U2(11)="$$DCTR^cAFI1(K)",U2(8)=""
	. S U2(19)=""
	;
	I U2(0),U2(4)=3 D                       ; ja/neen
	. S U2(9)=1
	. S I="0[] = neen   1[] = ja" D S4(10,1)
	. S I="0[] = non   1[] = oui" D S4(10,2)
	. S I="0[] = no   1[] = yes" D S4(10,4)
	. S U2(11)="K=0!(K=1)",U2(8)="S U3=$$JN^cAFO1(K)"
	. S U2(19)=""
	;
YZ	K U2(0) D C^cA612 Q
	;
	; Prompt
S1(R)	S R=$P($T(@("T"_R_QT)),U,2)
S1Z	Q R
	;
	; Data
S2(V,P)	S R=$P($G(U2(V)),D,P)
S2Z	Q R
	;
	; Vraagstelling
S3(T,V,P,L)	
S3A	S I=$$S2(V,P)     ; input voorstellen
	S R="I\22\3\"_$$S1(T)_"\\"_L_"\\\\\\\1"
	I UV=1 S $P(R,D,5)=""""_$P($T(@("T2"_QT)),U,3)_""""
	I UV=3 S $P(R,D,5)=""""_$P($T(@("T8"_QT)),U,3)_""""
	D R0
	I UV=1,"-,01"'[K G S3A
	I UV=3,"-,123"'[K G S3A
S3Z	Q
	;
	; Update
S4(V,P)	S $P(U2(V),D,P)=I
S4Z	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 18.05.04 - 15 u 48 * V8