cANLOG(G)	;LOGGER nieuwe stijl ;%ANLOG; [ 02/07/02  10:10 AM ]
	;
T0	;LOGGER nieuwe stijl ;
T1	;De computer in ; is niet bereikbaar.;
	;
T0F	;LOGGER nieuwe stijl ;
T1F	;L'Ordinateur à ; n'est pas accesible.;
	;
T0E	;LOGGER new style ;
T1E	;The computer in ; is not accessible.;
	;
RVG(G)	N M S G=$G(G),(QS,QRVG)=""
	I $L(G) S M=$O(^LOGTAB("^"_Q_G,"master","")) I $L(M),M'=$ZU($ZV'["MSM"*5) D
	. I $L($ZU($P(M,","),$P(M,",",2))) S QRVG=$ZU($ZV'["MSM"*5) I $ZV["MSM" D IN^cQMSMSW(M) Q
	. S M=$D(^|M|HULP) Q
	Q
	;
	; switch naar RVG - NT
RVGN(G)	N M S G=$G(G),(QS,QRVG)=""
	I $L(G) D
	. S:$E(G)'="^" G="^"_G
	. S M=$O(^LOGTAB(G,"master","")) I $L(M),M'=$ZU($ZV'["MSM"*5) D
	.. I $L($ZU($P(M,","),$P(M,",",2))) S QRVG=$ZU($ZV'["MSM"*5) I $ZV["MSM" D IN^cQMSMSW(M) Q
	.. S M=$D(^|M|HULP) Q
	Q
	;
	; switch uit RVG terug
OUT	I $L($G(QRVG)),QRVG'=$ZU($ZV'["MSM"*5) I $ZV["MSM" D IN^cQMSMSW(QRVG)
	S QRVG="" Q
	;
	; opbouw logger
OPB(G,PRI)	        Q:$O(LOG(""))=""  N I,M,R,T,TSYS S G=$G(G),PRI=+$G(PRI)
	S:$E(G)'="^" G="^"_G
	S TSYS="",M=$O(^LOGTAB(G,"master","")) I '$L(M) S M=$ZU($ZV'["MSM"*5)
	F  S TSYS=$O(^LOGTAB(G,"copy",TSYS)) Q:TSYS=""  D:TSYS'=M
	. L +^|M|DIN(0,TSYS) S T=$G(^|M|DIN(0,TSYS),1),^(TSYS)=T+1 L -^|M|DIN(0,TSYS)
	. L +^|M|LOG(TSYS,PRI,T) S ^|M|LOG(TSYS,PRI,T,0)=D_$ZU($ZV'["MSM"*5)_D_$H_D
	. S R=0 F I=0:1 S R=$O(LOG(R)) Q:R=""  S ^|M|LOG(TSYS,PRI,T,I+1)=LOG(R)
	. S $P(^|M|LOG(TSYS,PRI,T,0),D,4)=$H,$P(^|M|LOG(TSYS,PRI,T,0),D)=I
	. L -^|M|LOG(TSYS,PRI,T)
	K LOG Q
	;
	; MOVE=0->geen copy   MOVE=1->copy   MOVE=2->move(copy+kill in appl.)
MOVE(G)	N M,R,TSYS,MOVE I $E(G)'="^" S G="^"_G
	S M=$O(^LOGTAB(G,"master","")) I '$L(M) S M=$ZU($ZV'["MSM"*5)
	S MOVE=0,TSYS="" F  S TSYS=$O(^LOGTAB(G,"copy",TSYS)) Q:TSYS=""!MOVE  D
	. S R=^(TSYS) I TSYS'=M S MOVE=1 S:R="move" MOVE=2 Q
	Q MOVE
	;
	;
	;--------------- ALGEMEEN BESTAND TOT I9 INDEXEN ----------------------
SET(E,B,T,I,I1,I2,I3,I4,I5,I6,I7,I8,I9)	
	; E = einde transaktie (1=ja   0=neen)
	; B = bestand   T = index ^LOGTAB   I = inhoud   I1...I9 = indexen
	N R S:B'["^" B="^"_B S:'$L(T) T=B S:T'["^" T="^"_T
	S LOG=$O(LOG(""),-1)+1,LOG(LOG)="S "_B_"("
	F R=1:1:9 Q:'$D(@("I"_R))  D
	. S LOG(LOG)=LOG(LOG)_$S(R=1:"",1:",")_""""_@("I"_R)_""""
	I I["""" S I=$$DBLQ^cAFA1(I)
	S LOG(LOG)=LOG(LOG)_")="""_I_""""
	I E D END(T,E-1)
	Q
	;
KIL(E,B,T,I1,I2,I3,I4,I5,I6,I7,I8,I9)	
	; E = einde transaktie (1=ja   0=neen)
	; B = bestand   T = index ^LOGTAB   I1...I9 = indexen
	N R S:B'["^" B="^"_B S:'$L(T) T=B S:T'["^" T="^"_T
	S LOG=$O(LOG(""),-1)+1,LOG(LOG)="K "_B_"("
	F R=1:1:9 Q:'$D(@("I"_R))  D
	. S LOG(LOG)=LOG(LOG)_$S(R=1:"",1:",")_""""_@("I"_R)_""""
	S LOG(LOG)=LOG(LOG)_")"
	I E D END(T,E-1)
	Q
	;
END(T,PRI)	        I T'["^" S T="^"_T
	D OPB(T,+$G(PRI)) Q
	;----------------------------------------------------------------------
ZZ	; 07.02.02 - 11 u 22 * V7.91