cA5003	;Toegangscontrole; cA5003  ; Compiled December 8, 2011 12:06:15
	;
T1	;Geen toegang op : ;van ;tot ;
T2	;donderdag;vrijdag;zaterdag;zondag;maandag;dinsdag;woensdag;
	;
T1F	;Pas d'accès le : ;apd ;j.à ;
T2F	;jeudi;vendredi;samedi;dimanche;lundi;mardi;mercredi;
	;
T1E	;Acces denied on : ;from ;till ;
T2E	;thursday;friday;saterday;sunday;monday;tuesday;wednesday;
	;
YZ	Q
	;
NOA(QU,QT,JOB)	; test op 'No access'
	N USRID,I1,A,B,BIN,MINVAN,MINTOT,UURVAN,UURTOT,VAN,TOT,OK,QTU,DAY
	S $ZT="TRAP^cAN000"
	S D="\",U=";"
	;
	S USRID=$$UI1^cAFA1("USR",101,QU)
	I '$D(QT) S QT=$P($G(^(0)),D,9)
	S QTU=$S(QT="":1,1:$F("NFDE",QT)-1)
	I '$L(USRID) S OK=1 G NOAZ
	;
	S B(1)=$G(^DPAR(0,"PAR","LOGIN",0)),OK=1
NOAA	; controle geen toegang voor alle gebruikers
	S DAY=$H#7,BIN=DAY+33
	I '$L($P(B(1),D,BIN)) S OK=0 G NOAZ
	S VAN=$P($P(B(1),D,BIN),"-")
	S TOT=$P($P(B(1),D,BIN),"-",2)
	S UURVAN=$P(VAN,":"),UURTOT=$P(TOT,":")
	S MINVAN=$P(VAN,":",2),MINTOT=$P(TOT,":",2)
	I 'UURTOT S UURTOT=23 S:'MINTOT MINTOT=60
	I UURTOT=24 S UURTOT=23,MINTOT=60
	I $P($H,",",2)<((UURVAN*3600)+(MINVAN*60))!($P($H,",",2)>((UURTOT*3600)+(MINTOT*60))) S OK=0 G NOAZ
NOAB	; Indien geen toegang : mag de gebruiker inloggen ? Bv medewerkers van Data-M wel.
	S I1="0",OK=1
	F  S I1=$O(^DPAR(0,"PAR","LOGIN",I1)) Q:I1=""  I $P(^(I1),D)=USRID S:$P(^(I1),D,3) OK=0 Q
	I 'OK G NOAZ
	I $G(JOB) S OK=OK_D_$P($T(@("T1"_QT)),U,2)_$P($T(@("T2"_QT)),U,2+DAY)_" "_$P($T(@("T1"_QT)),U,3)_$TR(VAN,":",$P("u\h\s\h",D,QTU))_" "_$P($T(@("T1"_QT)),U,4)_$TR(TOT,":",$P("u\h\s\h",D,QTU)) G NOAZ
	W !,@F4,$P($T(@("T1"_QT)),U,2),@F5
	W !?3,$P($T(@("T2"_QT)),U,2+DAY)
	W !?3,$P($T(@("T1"_QT)),U,3),$TR(VAN,":",$P("u\h\s\h",D,QTU)),!?3,$P($T(@("T1"_QT)),U,4),$TR(TOT,":",$P("u\h\s\h",D,QTU)),! R K:5
NOAZ	Q OK
	;
TESTSEC(QU)	       ; test op tweede maal Ingelogd : was spec. voor TBK
	N I,J
	D ^cA105,^cA106
	S J="" F  S J=$O(^cJOB(J)) Q:J=""  I J'=$J,$d(^cJOB(J,boot,"job","qu")),^("qu")=QU,$P($G(^("DATE_TIME")),D)'=DT,$P($G(^("date_time")),D)'=DT D  Q
	. N AAN,A,C,CC,TEKST,I
	. S TEKST(1)=$ZU(5)_" : 2X "_QU
	. S TEKST(2)=DT_" - "_TD
	. S TEKST(3)="Job 1 : "_J_", Ref.Port : "_$G(^("IO"))_", Date : "_$TR($P($G(^("DATE_TIME")),D,1,2),"/")
	. S TEKST(4)="      Last menu : "_$P($G(^("menu_line")),D)_" "_$TR($G(^("date_time")),D,"/")
	. S TEKST(5)="Job 2 : "_$J_", Ref.Port : "_$G(io,$$IO^cQ5)_", $I = "_$I
	. S $ZT="TRAP^cAN000"
	. ; S Q="DAM",A="DAM\IP\KU\SU",AAN=""
	. ; F I=1:1 Q:'$L($P(A,D,I))  S C=$$UI1^cAFA1("USR",101,$P(A,D,I)) I $L($$SIG^cAFA1("USR",C,221)) S AAN=AAN_$S($L(AAN):U,1:"")_$P(^(1),D,21)
	. ; I '$L(AAN) Q
	. ; S CC=AAN
	. ; D EMAIL^cA5002
	. ; S I=$D(^cJOB(J,boot,"job","qu"))
	. ; S Q=OQ
	. ; nieuwe alert
	. D ^cANEM1("T1002",$T(+0),$P($T(+1),U,2),.TEKST)
	Q
	;
ZZ	; 24.09.03 - 14 u 21 * V7.96