cAFO2	;OUTPUT FORMATEN ;%AFO2 ; [ 01/11/01  2:08 PM ]
	;
T0	;Outputformaten ;
T1	;Nederlands;Frans;Engels;Duits;Spaans;
T2	;lineair;pro rata temporis;degressief;
T3	;Van datum;Tot datum;
	;
T0F	;Formats externes ;
T1F	;Néerlandais;Français;English;Deutsch;Espagnol;
T2F	;linéair;pro rata temporis;dégressif;
T3F	;Date initiale;Date finale;
	;
T0E	;Outputformats ;
T1E	;Dutch;French;English;German;Spanish;
T2E	;linear;pro rata temporis;degressive;
T3E	;From date;Until date;
	;
T0D	;Outputformaten ;
T1D	;Niederländisch;Französisch;Englisch;Deutsch;Spanisch;
T2D	;lineair;pro rata temporis;degressief;
T3D	;Von datum;Bis datum;
	;
JRN(S,N)	; journaalcode
	N R
	S R=$P($G(@("^"_Q_"BA")@("%T",S_$S(N:$E(1000+N,2,4),1:""))),D,2)
	I R="" S R=$S(S="D":$P("DV\OD",D,QTU),1:S)
JRNZ	Q R
	;
MAAND(M,T,S)	      ; naam v/d maand
	N R
	S R=$G(^cBA(2,$E(T_"N"),+M))
	I S<2 S R=$$LC^cAFA1(R) I S=1 S $E(R)=$$UC^cAFA1($E(R))
MAANDZ	Q R
	;
PER(K,DMS)	        ; prompt periodes
	N R S R=K
	I K=1 D
	. I DMS="AR"!(DMS="ARA") S R=$P("sal.\sol.\Ums.\bal.",D,QTU)
	. I DMS'="AR",DMS'="ARA" S R=$P("omz.\c.a.\Ums.\t.o.",D,QTU)
	. S R=R_" "_$E(^cBA(2,$E(QT_"N"),$$RAP),1,3)
	I K=2 S R=$P("beginsal.\s.initial\Beginsal.\init.bal.",D,QTU)
	I K=4 S R=$P("kwart.\trim.\Quart.\quart.",D,QTU)_" 1"
	I K=5 S R=$P("kwart.\trim.\Quart.\quart.",D,QTU)_" 2"
	I K=6 S R=$P("kwart.\trim.\Quart.\quart.",D,QTU)_" 3"
	I K=7 S R=$P("kwart.\trim.\Quart.\quart.",D,QTU)_" 4"
	I K=9 S R=$P("kw. \tr. \Qu.\qt. ",D,QTU)_"1+2"
	I K=10 S R=$P("kw. \tr. \Qu.\qt. ",D,QTU)_"3+4"
	I K=11 S R=$P("kw.\tr.\Qu.\qt.",D,QTU)_"1+2+3"
	I K=13 D
	. I DMS="AR"!(DMS="ARA") S R=$P("tot.sal.\sol.tot.\Tot.Ums.\tot.bal.",D,QTU)
	. I DMS'="AR",DMS'="ARA" S R=$P("tot.omz.\c.a.tot.\Tot.Ums.\tot.t.o.",D,QTU)
	Q R
	;
RAP()	; rapporteringsmaand
	N R
	S R=$G(@("^"_Q_"BA(7)")),R=$G(^(7,0),R)#1*100,R=$P($G(^(1),R),D) I 'R S R=1
	Q R
	;
REGAFS(K)	         ; regime afschrijvingen
	N R
	S R=$T(@("T2"_QT)),R=$P(R,U,K+2)
	Q R
	;
TAAL(K)	; code taal
	N R
	S R=$T(@("T1"_QT)),$P(R,U)="?",R=$P(R,U,$F("NFEDS",K))
	Q R
	;
VAND()	;  Van datum
	N R
	S R=$P($T(@("T3"_QT)),U,2)
	Q R
	;
TOTD()	;  Tot datum
	N R
	S R=$P($T(@("T3"_QT)),U,3)
	Q R
	;
ZZ	; 22.06.04 - 16 u 32 * V8