cI531	;Controle R- en T-lijnen ;%I531 ; [ 10/31/00  12:03 PM ]
	G YZ ; afgeleide versie van %I530, kan ook worden gejobd !
	;
T1	;Controle R-lijnen tov OD;Controle T-lijnen tov TO;
T2	;Controle veld 309 tov R-lijnen;Controle veld 117 tov T-lijnen;
T3	;Controle OD tov R-lijnen;Controle TO tov T-lijnen;
	;
OD(Q,UPRDMS,VELD)	 ;Controle R-lijnen met OD
	S UGL="OD",IR="R",BI=309
	G 1
	;
TO(Q,UPRDMS,VELD)	 ;Controle T-lijnen met TO
	S UGL="TO",IR="T",BI=117
	G 1
	;
	; Initialisatie
1	S $ZT="^cA407" I $G(Q)'?1.3U G YZ
	I '$D(@("^"_Q_"BA(99,1)")) G YZ
	S QN=^(1),D="\",U=";" D ^cA106,^cA105,QT^cQ5
	S TEMP=$NA(^TEMPC($T(+0),UGL)) K @TEMP
	S @TEMP@(0,"Begin")=DT_D_TD_D_$H,ER=0
	F I=1:1:3 S @TEMP@(I)=$P($T(@("T"_I)),U,IR="T"+2)
	I $G(UPRDMS)="" S UPRDMS="PR"
	S UPRREF=$$REF^cANP000(UPRDMS)
	I $G(VELD)="" S VELD=2
	S @TEMP@(0,"PR")=UPRDMS_D_UPRREF_D_BI_D_IR_D
	S @TEMP@(0,"UGL")=UGL_D_VELD_D
	;
	; R-lijnen tov OD
	; T-lijnen tov TO
2	S PR=0 F  S PR=$O(@UPRREF@(PR)) Q:PR=""  D
	. S I2=IR,TOT=0,TOTR=$P($G(^(PR,BI\100-1)),D,BI#100)
	. F  S I2=$O(@UPRREF@(PR,I2)) Q:$E(I2)'=IR  D
	.. S UR=+$TR($E(I2,10,15)," ",0),UVN=$TR($E(I2,16,$L(I2))," ",0)+100
	.. S X=^(I2),KC=$P(X,D,2),US=$P(X,D,3),TOT=TOT+$P(X,D,5)
	.. I KC="" S KC=0
	.. I US="" S US="F"
	.. I $D(@("^"_Q_UGL_"(KC,US,UR,UVN)")) Q
	.. S @TEMP@(1,PR,I2)=X,ER=1
	. I TOTR-TOT'=0 S @TEMP@(2,PR)=TOTR_D_TOT,ER=1
	;
	; OD tov R-lijnen
	; TO tov T-lijnen
3	S KC=0 F  S KC=$O(@("^"_Q_UGL_"(KC)")) Q:KC=""  D
	. F US="F","D" D
	.. S UR="" F  S UR=$O(@("^"_Q_UGL_"(KC,US,UR)")) Q:UR=""  D
	... S U5=^(UR,1),DAT=$P(U5,D,2),UVN=100
	... F  S UVN=$O(@("^"_Q_UGL_"(KC,US,UR,UVN)")) Q:UVN=""  D
	.... S B(1)=^(UVN),PR=$P(B(1),D,VELD) Q:'PR       ; product of nuance
	.... S X=IR_$$DC^cAFD1(DAT)_$J(UR,6)_$J(UVN-100,3)
	.... I $D(@UPRREF@(PR,X)) Q
	.... S @TEMP@(3,KC,US,UR,UVN)=PR,ER=1
	;
Y	D ^cA105 S @TEMP@(0,"Einde")=DT_D_TD_D_$H
	I ER D
	. I UGL="OD" D D1008^cANEM0($T(+0),$P($T(T1),U,2))
	. I UGL="TO" D D1009^cANEM0($T(+0),$P($T(T1),U,3))
YZ	Q
	;
ZZ	; 23.06.05 - 17 u 03 * V8.04