unit ApplicationContext;

// Dit is een klasse bedoeld om data te delen over de applicatie heen.
// Dit kan bijvoorbeeld usernaam, login token, computernaam, ...
// Informatie die elk component/klasse kan gebruiken.

interface

uses
  ObserverPattern,
  System.Generics.Collections, SysUtils, ReadOnlyList;

// SUB CONTEXTS: klassen die overeenkomen met bepaalde sub-context (bv. alles gerelateerd met authenticatie).

// - User
type
  TUserContext = class(TSubject)
  private
    FSessionKey: string;
    FGebruikersNaam: string;

    FIsOK: Boolean;
    FErrorMessage: string;
    FInternalErrorMessage: string;
  public
    procedure NotifyChanged();
    property SessionKey: string read FSessionKey write FSessionKey;
    property GebruikersNaam: string read FGebruikersNaam write FGebruikersNaam;
    property IsOK: Boolean read FIsOK write FIsOK;
    property ErrorMessage: string read FErrorMessage write FErrorMessage;
    property InternalErrorMessage: string read FInternalErrorMessage write FInternalErrorMessage;
  end;

  // - UI instellingen
  TUiInstellingenContext = class(TSubject)
  private
    FPositieByKey: TDictionary<String, String>;
    FPositieByValue: TDictionary<String, String>;
    FPlaatsingByKey: TDictionary<String, String>;
    FPlaatsingByValue: TDictionary<String, String>;
    FRichtingByKey: TDictionary<String, String>;
    FRichtingByValue: TDictionary<String, String>;
    FOptiTypeByKey: TDictionary<String, String>;
    FOptiTypeByValue: TDictionary<String, String>;

    FIsOK: Boolean;
    FErrorMessage: string;
    FInternalErrorMessage: string;
  public
    constructor Create();
    procedure NotifyChanged();
    property Posities: TDictionary<String, String> read FPositieByKey;
    property PositiesByValue: TDictionary<String, String> read FPositieByValue;
    property Plaatsing: TDictionary<String, String> read FPlaatsingByKey;
    property PlaatsingByValue: TDictionary<String, String> read FPlaatsingByValue;
    property Richtingen: TDictionary<String, String> read FRichtingByKey;
    property RichtingenByValue: TDictionary<String, String> read FRichtingByValue;
    property OptiTypes: TDictionary<String, String> read FOptiTypeByKey;
    property OptiTypesByValue: TDictionary<String, String> read FOptiTypeByValue;

    property IsOK: Boolean read FIsOK write FIsOK;
    property ErrorMessage: string read FErrorMessage write FErrorMessage;
    property InternalErrorMessage: string read FInternalErrorMessage write FInternalErrorMessage;
  end;

  // - Product Selection
  TProductInformatie = class
  private
    FProductNr: Integer;
    FTekst: string;
    FKol1: string;
    FKol2: string;
    FKol3: string;
    FKol4: string;
    function GetOmschrijving1(): string;
    function GetOmschrijving2(): string;
  public
    property ProductNr: Integer read FProductNr write FProductNr;
    property Tekst: string read FTekst write FTekst;
    property Kol1: string read FKol1 write FKol1;
    property Kol2: string read FKol2 write FKol2;
    property Kol3: string read FKol3 write FKol3;
    property Kol4: string read FKol4 write FKol4;

    property Omschrijving1: string read GetOmschrijving1;
    property Omschrijving2: string read GetOmschrijving2;
  end;

  TProductsContext = class(TSubject)
  private
    FProducten: TList<TProductInformatie>;
    FGeselecteerdProduct: TProductInformatie;

    FIsOK: Boolean;
    FErrorMessage: string;
    FInternalErrorMessage: string;

    procedure SetGeselecteerdProduct(ProductInformatie: TProductInformatie);
    function GetProductenLijst: TReadOnlyList<TProductInformatie>;
  public
    constructor Create();
    procedure NotifyChanged();
    procedure Reset(Notify: Boolean = True);

    property Producten: TReadOnlyList<TProductInformatie> read GetProductenLijst;
    procedure SetProducten(Collection: TEnumerable<TProductInformatie>);
    property GeselecteerdProduct: TProductInformatie read FGeselecteerdProduct write SetGeselecteerdProduct;

    property IsOK: Boolean read FIsOK write FIsOK;
    property ErrorMessage: string read FErrorMessage write FErrorMessage;
    property InternalErrorMessage: string read FInternalErrorMessage write FInternalErrorMessage;
  end;

  // - Product Detail
  TProductVerpakkingParameter = class
  private
    FID: string;
    FProgLabel: string;
    FToolTip: string;
    FWaarde: string;
    FDefaultWaarde: string;
  public
    property ID: string read FID write FID;
    property ProgLabel: string read FProgLabel write FProgLabel;
    property ToolTip: string read FToolTip write FToolTip;
    property Waarde: string read FWaarde write FWaarde;
    property DefaultWaarde: string read FDefaultWaarde write FDefaultWaarde;
  end;

  TProductVerpakking = class
  private
    FRawData: TObject;

    FID: string;
    FCutOrder: Integer;

    FVolumeVanCaption: string;
    FBreedte: Integer;
    FDefaultBreedte: Integer;
    FDiepte: Integer;
    FDefaultDiepte: Integer;
    FHoogte: Integer;
    FDefaultHoogte: Integer;
    FAantal: string;
    FMaxCombinAantal: string;
    FPlaatsing: string;
    FDefaultPlaatsing: string;
    FOptiType: string;
    FDefaultOptiType: string;

    FPosities: TList<string>;
    FDefaultPosities: TList<string>;
    FRichtingen: TList<string>;
    FDefaultRichtingen: TList<string>;

    FParameters: TList<TProductVerpakkingParameter>;

    FDeelVanID: string;
    FDeelVanCaption: string;
    FDeelVan: TProductVerpakking;

    FMetaCaption: string;

    function GetMetaCaptionDisplay(): string;
  public
    property RawData: TObject read FRawData write FRawData;

    property ID: string read FID write FID;
    property CutOrder: Integer read FCutOrder write FCutOrder;

    property VolumeVanCaption: string read FVolumeVanCaption write FVolumeVanCaption;
    property Breedte: Integer read FBreedte write FBreedte;
    property DefaultBreedte: Integer read FDefaultBreedte write FDefaultBreedte;
    property Diepte: Integer read FDiepte write FDiepte;
    property DefaultDiepte: Integer read FDefaultDiepte write FDefaultDiepte;
    property Hoogte: Integer read FHoogte write FHoogte;
    property DefaultHoogte: Integer read FDefaultHoogte write FDefaultHoogte;
    property Aantal: string read FAantal write FAantal;
    property MaxCombinAantal: string read FMaxCombinAantal write FMaxCombinAantal;
    property Plaatsing: string read FPlaatsing write FPlaatsing;
    property DefaultPlaatsing: string read FDefaultPlaatsing write FDefaultPlaatsing;
    property OptiType: string read FOptiType write FOptiType;
    property DefaultOptiType: string read FDefaultOptiType write FDefaultOptiType;

    property Posities: TList<string> read FPosities;
    property DefaultPosities: TList<string> read FDefaultPosities;
    property Richtingen: TList<string> read FRichtingen;
    property DefaultRichtingen: TList<string> read FDefaultRichtingen;

    property Parameters: TList<TProductVerpakkingParameter> read FParameters;
    { TODO : Immutable list }

    property DeelVanID: string read FDeelVanID write FDeelVanID;
    property DeelVanCaption: string read FDeelVanCaption write FDeelVanCaption;
    property DeelVan: TProductVerpakking read FDeelVan write FDeelVan;

    property MetaCaption: string write FMetaCaption;
    property MetaCaptionDisplay: string read GetMetaCaptionDisplay;

    function Equals(Obj: TObject): Boolean; override;
    constructor Create();
  end;

  TProductVerpakkingenContext = class(TSubject)
  private
    FProductVerpakkingen: TList<TProductVerpakking>;
    FGeselecteerdeVerpakking: TProductVerpakking;

    FIsOK: Boolean;
    FErrorMessage: string;
    FInternalErrorMessage: string;

    function GetProductVerpakkingenLijst: TReadOnlyList<TProductVerpakking>;
    procedure SetGeselecteerdeVerpakking(ProductVerpakking: TProductVerpakking);
  public
    constructor Create();
    procedure NotifyChanged();
    procedure Reset(Notify: Boolean = True);

    property ProductVerpakkingen: TReadOnlyList<TProductVerpakking> read GetProductVerpakkingenLijst;
    procedure SetProductVerpakkingen(Collection: TEnumerable<TProductVerpakking>);
    procedure AddProductVerpakking(ProductVerpakking: TProductVerpakking);
    function GetDeelVanOpties(ProductVerpakking: TProductVerpakking): TList<String>;
    property GeselecteerdeVerpakking: TProductVerpakking read FGeselecteerdeVerpakking write SetGeselecteerdeVerpakking;

    property IsOK: Boolean read FIsOK write FIsOK;
    property ErrorMessage: string read FErrorMessage write FErrorMessage;
    property InternalErrorMessage: string read FInternalErrorMessage write FInternalErrorMessage;
  end;

  // APPLICATION CONTEXT
  // Application context bevat alle sub-contexts
  TApplicationContext = class
  private
    FUserContext: TUserContext;
    FUiInstellingenContext: TUiInstellingenContext;
    FProductsContext: TProductsContext;
    FProductDetailContext: TProductVerpakkingenContext;
  public
    constructor Create();
    property UserContext: TUserContext read FUserContext write FUserContext;
    property UiInstellingenContext: TUiInstellingenContext read FUiInstellingenContext write FUiInstellingenContext;
    property ProductsContext: TProductsContext read FProductsContext write FProductsContext;
    property ProductVerpakkingContext: TProductVerpakkingenContext read FProductDetailContext write FProductDetailContext;
  end;

implementation

// USER
procedure TUserContext.NotifyChanged();
begin
  self.Change();
end;

// UiInstellingen
constructor TUiInstellingenContext.Create();
begin
  inherited Create();
  FPositieByKey := TDictionary<String, String>.Create();
  FPositieByValue := TDictionary<String, String>.Create();
  FPlaatsingByKey := TDictionary<String, String>.Create();
  FPlaatsingByValue := TDictionary<String, String>.Create();
  FRichtingByKey := TDictionary<String, String>.Create();
  FRichtingByValue := TDictionary<String, String>.Create();
  FOptiTypeByKey := TDictionary<String, String>.Create();
  FOptiTypeByValue := TDictionary<String, String>.Create();
end;

procedure TUiInstellingenContext.NotifyChanged();
begin
  self.Change();
end;

// PRODUCT
constructor TProductsContext.Create();
begin
  inherited Create();
  FProducten := TList<TProductInformatie>.Create();
end;

procedure TProductsContext.NotifyChanged();
begin
  self.Change();
end;

function TProductsContext.GetProductenLijst: TReadOnlyList<TProductInformatie>;
begin
  Result := TReadOnlyList<TProductInformatie>.Create(FProducten);
end;

procedure TProductsContext.SetProducten(Collection: TEnumerable<TProductInformatie>);
begin
  FProducten.Clear();
  FProducten.AddRange(Collection);
  self.NotifyChanged();
end;

procedure TProductsContext.SetGeselecteerdProduct(ProductInformatie: TProductInformatie);
begin
  FGeselecteerdProduct := ProductInformatie;
  self.NotifyChanged();
end;

// Enkel updaten wanneer nog niet op nil stond.
procedure TProductsContext.Reset(Notify: Boolean = True);
begin
  if (GeselecteerdProduct <> nil) or (FProducten.Count > 0) then
  begin
    FProducten.Clear();
    GeselecteerdProduct := nil;
    if Notify then
      NotifyChanged();
  end;
end;

function TProductInformatie.GetOmschrijving1(): string;
begin
  if FKol4 = '' then
  begin
    Result := '';
  end
  else
  begin
    try
      Result := copy(FKol4, 0, Pos(',', FKol4) - 1);
    except
      Result := '';
    end;

  end;
end;

function TProductInformatie.GetOmschrijving2(): string;
begin
  if FKol4 = '' then
  begin
    Result := '';
  end
  else
  begin
    try
      Result := copy(FKol4, Pos(',', FKol4) + 2);
      Result := copy(Result, 0, Pos(',', Result) - 1); // Tweede deel na de komma
    except
      Result := '';
    end;

  end;
end;

// PRODUCT DETAIL
constructor TProductVerpakkingenContext.Create;
begin
  inherited Create();
  FProductVerpakkingen := TList<TProductVerpakking>.Create();
end;

procedure TProductVerpakkingenContext.NotifyChanged();
begin
  self.Change();
end;

procedure TProductVerpakkingenContext.Reset(Notify: Boolean = True);
begin
  if (FGeselecteerdeVerpakking <> nil) or (FProductVerpakkingen.Count > 0) then
  begin
    FProductVerpakkingen.Clear();
    FGeselecteerdeVerpakking := nil;
    if Notify then
      NotifyChanged();
  end;
end;

function TProductVerpakkingenContext.GetProductVerpakkingenLijst: TReadOnlyList<TProductVerpakking>;
begin
  Result := TReadOnlyList<TProductVerpakking>.Create(FProductVerpakkingen);
end;

procedure TProductVerpakkingenContext.SetProductVerpakkingen(Collection: TEnumerable<TProductVerpakking>);
begin
  FProductVerpakkingen.Clear();
  FProductVerpakkingen.AddRange(Collection);
  self.NotifyChanged();
end;

procedure TProductVerpakkingenContext.AddProductVerpakking(ProductVerpakking: TProductVerpakking);
begin
  if ProductVerpakking = nil then
    exit;

  FProductVerpakkingen.Add(ProductVerpakking);
  FGeselecteerdeVerpakking := ProductVerpakking;
  self.NotifyChanged();
end;

procedure TProductVerpakkingenContext.SetGeselecteerdeVerpakking(ProductVerpakking: TProductVerpakking);
begin
  FGeselecteerdeVerpakking := ProductVerpakking;
  self.NotifyChanged();
end;

function TProductVerpakkingenContext.GetDeelVanOpties(ProductVerpakking: TProductVerpakking): TList<string>;
var
  ProductVerpakkingTeZoeken: TProductVerpakking;
  Namen: TList<String>;
begin
  Namen := TList<String>.Create();
  for ProductVerpakkingTeZoeken in FProductVerpakkingen do
  begin
    if not ProductVerpakkingTeZoeken.Equals(ProductVerpakking) then
      Namen.Add(intToStr(ProductVerpakkingTeZoeken.CutOrder) + ': ' + ProductVerpakkingTeZoeken.MetaCaptionDisplay)
  end;

  Result := Namen;
end;

// Product verpakking
constructor TProductVerpakking.Create();
begin
  inherited Create();

  FPosities := TList<string>.Create();
  FDefaultPosities := TList<string>.Create();
  FRichtingen := TList<string>.Create();
  FDefaultRichtingen := TList<string>.Create();

  FParameters := TList<TProductVerpakkingParameter>.Create();
end;

function TProductVerpakking.Equals(Obj: TObject): Boolean;
begin
  if Obj = nil then
    Result := False
  else if not(Obj is TProductVerpakking) then
    Result := False
  else if (Obj as TProductVerpakking).ID = self.ID then
    Result := True
  else
    Result := False;
end;

function TProductVerpakking.GetMetaCaptionDisplay(): string;
begin
  if FMetaCaption <> '' then
    Result := copy(FMetaCaption, Pos(':', FMetaCaption) + 2)
  else
    Result := '';
end;

// APPLICATION CONTEXT
constructor TApplicationContext.Create();
begin
  FUserContext := TUserContext.Create();
  FUiInstellingenContext := TUiInstellingenContext.Create();
  FProductsContext := TProductsContext.Create();
  FProductDetailContext := TProductVerpakkingenContext.Create();
end;

end.