ATKMENU ; Afstand-toegang voor klanten [ 03/26/97  10:08 AM ]
 ;
ITRANSL(Input,Taal,Invers) 
 New I,R,Quit,MenuTyp
 Set Invers=$S($G(Invers):2,1:0),R=Menu Set:R="" R=D
 New Menu
 Set Menu=R_$$MAKTIE($G(DL(1))),Quit=0
 For MenuTyp="ATKSCREENS","ATKAKTIES" Do  Quit:Quit
 .For I=1:1 Quit:'$D(^MN("D",MenuTyp,"F",I))  Do  Quit:Quit
 ..Set R=^MN("D",MenuTyp,"F",I)
 ..If $P(R,"`",2+Invers)=Input Do
 ...If $L($P(R,"`",5)) Xecute "Set $P(R,""`"",5)="_$P(R,"`",5) Quit:'$P(R,"`",5)
 ...Set Input=$P(R,"`",4-Invers),Quit=1
 Set:'Quit Input=""
 Quit Input
 ;
MENU(MenuTyp) 
 New R,IsProd,AutoSel,sRTemp
 Set MenuTyp=$G(MenuTyp),AutoSel=$$AUTOSEL("ATKSCREENS",Taal),IsProd=$$ISPROD^ATKPROD() Set:IsProd AutoSel=0
 If MenuTyp Do
 .Quit:Menu="\K\"&AutoSel
 .Set R=$$GETTXT^ATK("ATK","MEXIT",Taal)
 .If 'AutoSel,$L($TR(Menu,D,"")) Do
 ..Set R=R_"   "_$$GETTXT^ATK("ATK","MSCREENS",Taal)
 ..Set:$L($$MAKTIE($G(DL(1)))) R=R_"   "_$$GETTXT^ATK("ATK","MAKTIE",Taal)
 .If $D(DL(1)),$O(@("^LD(""L"",""ATK"_$$LDGLOB^ATK($$LDINPUT^ATK(DL(1)))_""",""H"",Taal,"""")")) Do
 ..Set R=R_"   "_$$GETTXT^ATK("ATK","MLEGEND",Taal)
 .Set FP=2401
 .Write @F,R,@F2
 Else  Do
 .Quit:$TR(Menu,D,"")=""
 .Set R=Menu Set:R="" R=D
 .New Menu,MenuPos,Tabel
 .Set Tabel=$G(DL(1))
 .Set Menu=R_$$MAKTIE($G(DL(1)))
 .Set MenuPos=$$MENUPOS(Menu,MenuTyp)
 .Set sRTemp=sRT
 .Do POP^MN($S(MenuTyp="+":"ATKAKTIES",1:"ATKSCREENS"),MenuPos,Taal,AutoSel)
 .Set:sRT>sRTemp sRT=sRTemp
 .If $L(R) Set Input=R
 .Else  If '$D(DL(1)) Set Input="-"
 .If 'AutoSel Do
 ..Do ADD^vhScherm(MenuPos-1,24)
 ..Set FP=MenuPos-1*100+1
 ..Write @F,@F1
 Quit
 ;
AUTOSEL(MenuId,Taal) 
 New Y
 Do FETCH^MN(MenuId,Taal)
 Quit Y(0)=1
 ;
CHKMENU(Menu) 
 Set Menu=$G(Menu) Set:Menu="" Menu=D
 Quit Menu_$$MAKTIE($G(DL(1)))[(D_Input_D)
 ;
MAKTIE(Tabel) 
 New Menu,IsProd,FaxList
 Set IsProd=$$ISPROD^ATKPROD(),FaxList=$$FAXLIST^ATK()
 Set Menu="" If IsProd Set Menu="P\" Set:$G(Tabel)'="OFFERTE" Menu=Menu_"U\"
 Set Menu=Menu_$S(FaxList:">\",1:"")
 Set:$G(Tabel)="MOEDERB" Menu=Menu_"ENTER\D\N\X\Z\"
 Set:$G(Tabel)="OFFERTE" Menu=Menu_"ENTER\N\X\Z\"
 Set:Menu="" Menu=$$WISSEL^ATKPROD()
 If $D(DL(1)),$D(@DL(1)@(1)),$G(@DL(1)@(9)) Set Menu=Menu_"=\"
 Quit Menu
 ;
MOEDERB(Type) 
 New Test,PRNr
 If $G(Tabel,$G(DL(1)))="MOEDERB" Do
 .Set Type=$G(Type),PRNr=$P($G(^HULP(%J,"MOEDERB",MOEDERB(6))),D,15)
 .If PRNr Do
 ..If Type="W",$P($G(^HULP(%J,"MBINPUT","D",PRNr)),D) Set Test=1
 ..If Type="X",$P($G(^HULP(%J,"MBINPUT","D",PRNr)),D) Set Test=1
 ..If Type="I",'$G(^HULP(%J,"MBINPUT","D",PRNr)) Set Test=1
 .If Type="N" Set Test=1
 .If Type="Z",$D(^HULP(%J,"MBINPUT","D")) Set Test=1
 Quit $G(Test)
 ;
OFFERTE(Type) 
 New Test,PRNr
 If $G(Tabel,$G(DL(1)))="OFFERTE" Do
 .Set Type=$G(Type),PRNr=$P($G(^HULP(%J,"OFFERTE",OFFERTE(6))),D,15)
 .If PRNr Do
 ..If Type="W",$P($G(^HULP(%J,"OFFINPUT","D",PRNr)),D) Set Test=1
 ..If Type="X",$P($G(^HULP(%J,"OFFINPUT","D",PRNr)),D) Set Test=1
 .If Type="N" Set Test=1
 Quit $G(Test)
 ;
KLREF(Type) 
 New Test
 If Type="U" Do
 .If '$L($G(Tabel)) Set Test=1
 .Else  New DL Set DL(1)=Tabel,Test=$$MODNAME^ATKPROD()
 Quit $G(Test)
 ;
MENUPOS(Menu,MenuTyp) 
 New I,MenuTemp
 Set MenuTemp=""
 For I=1:1 Quit:'$D(^MN("D",$S(MenuTyp="+":"ATKAKTIES",1:"ATKSCREENS"),"F",I))  Do
 .Set R=^MN("D",$S(MenuTyp="+":"ATKAKTIES",1:"ATKSCREENS"),"F",I)
 .If Menu[(D_$P(R,"`",4)_D) Do
 ..If $L($P(R,"`",5)) Xecute "Set $P(R,""`"",5)="_$P(R,"`",5) Quit:'$P(R,"`",5)
 ..Set MenuTemp=MenuTemp_D_$P(R,"`",4)
 Set:$L(MenuTemp) MenuTemp=MenuTemp_D
 Quit 26-$L(MenuTemp,D)
 ;