BLCSBFAK ;Blum Vervoer-Faktuurlijst [ 09/06/2002  1:00 PM ]
 If '$D(Q) Set Q="K" Do ^cA604
 Write @F11,@F1,@FMTI," Vervoerslijst factuur : ",QN," ",@FMTi
 ; Select klant
 Set LC="",SoDo="SO"
 Do MULTI^VERVID Kill ^HULP($J)
 Do PRINT(LC,VRF)
 Do Factureren(LC,VRF)
 Quit
 
PRINT(LC,VRFL) 
 New FAKNr,Cnt,Totaal,VRF,FAKNr,LijnNr,%J,BLCSBFAK,DL,PRNr,IDNr,Rec
 Quit:'$L(VRFL)
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set FAKNr="",Cnt=0
 Kill Totaal
 For I=1:1:$L(VRFL,";") Do
 .Set VRF=$P(VRFL,";",I)
 .Quit:'VRF  Quit:'$D(^Verv(LC,"D",VRF))
 .For  Set FAKNr=$O(^Verv(LC,"D",VRF,FAKNr)) Quit:FAKNr=""  Do
 ..Set Rec=^(FAKNr)
 ..Set Cnt=Cnt+1
 ..Set ^HULP(%J,(9999999-FAKNr)_D_$J(Cnt,3)_D_"   ")=FAKNr_D_Rec
 ..Set Totaal($P(Rec,D,4))=$G(Totaal($P(Rec,D,4)))+$P(Rec,D,5)
 ..Set LijnNr=""
 ..If $P(Rec,D,7) For  Set LijnNr=$O(^Verv(LC,"D",VRF,FAKNr,LijnNr)) Quit:LijnNr=""  Do
 ...Set Rec=^(LijnNr)
 ...Quit:'$L($P(Rec,D,17))
 ...Set PRNr=$P(Rec,D,7)
 ...If PRNr,$D(^KPR(PRNr)) Do
 ....Set $P(Rec,D,6)=$P(^KPR(PRNr,0),D,1)
 ....Set $P(Rec,D,8)=$P(^KPR(PRNr,2),D,25)
 ...Else  Do
 ....Set $P(Rec,D,6)="*** Onbekend ***"
 ....Set IDNr=$P(Rec,D,8)
 ....Set:$L(IDNr)=7 IDNr="0"_IDNr
 ....Set $P(Rec,D,8)="*."_$E(IDNr,2,4)_"."_$E(IDNr,5,7)_"."_$E(IDNr,8)
 ...Set ^HULP(%J,(9999999-FAKNr)_D_$J(Cnt,3)_D_$J(LijnNr,3))=D_Rec
 ..Set ^HULP(%J,(9999999-FAKNr)_D_$J(Cnt,3)_D_"999")=""
 Set Munt=""
 ;Set Cnt=Cnt+1,^HULP(%J,9999999_D_$J(Cnt,3))=""
 For  Set Munt=$O(Totaal(Munt)) Quit:Munt=""  Do
 .Set Cnt=Cnt+1
 .Set ^HULP(%J,9999999_D_$J(Cnt,3))="Totaal"_D_D_D_D_Munt_D_Totaal(Munt)_D
 ; Afdrukken
 Do INIT^PROC("BLCSBFAK")
 Set BLCSBFAK(11)="Vervoerslijst\"_LC_" "_$P(^KLE(^KL1(LC),0),D,2)_"\Facturen"
 Set BLCSBFAK(2,"P")=^LD("L","BLCSBFAKP")
 Do PRINT^OUTPUT(.BLCSBFAK,"P","S;L;B")
 Kill ^HULP(%J)
 Quit
 
CB(Ref) New Rec
 If Ref?1A Do  Quit "" ; Hoofding, Titel,...
 .If '$G(VoorBlad),$P($G(Print("PRINTER")),";")="P" Do VOORBLAD(LC,VRFL)
 .Set VoorBlad=1
 Set Rec=@Ref
 If $L(Rec),'$L($P(Rec,D,1)) Quit ";P" ; Produktlijn
 If $P(Rec,D,1)="Totaal" Quit "BR;\;" ; Totaal
 Set LvhFANr=$P(Rec,D,10)
 Quit "" ; Faktuurlijn
 
VOORBLAD(LEVNr,VervRef) 
 New I,R,VervDat,Waarde,Gewicht,Palet,Collie,BlumFANr
 For I=1:1:$L(VervRef,";") If $L($P(VervRef,";",I)) Set VervRef($P(VervRef,";",I))=""
 Set VervRef=""
 For  Set VervRef=$O(VervRef(VervRef)) Quit:VervRef=""  Do
 .Set:VervRef VervRef(VervRef)=$P(^Verv(LEVNr,"D",VervRef),D,16)
 .Set BlumFANr=""
 .For  Set BlumFANr=$O(^Verv(LEVNr,"D",VervRef,BlumFANr)) Quit:BlumFANr=""  Do
 ..Set R=^Verv(LEVNr,"D",VervRef,BlumFANr),$P(Waarde(VervRef),D,+R)=$P($G(Waarde(VervRef)),D,+R)+$P(R,D,5)
 .Set R=^Verv(LEVNr,"D",VervRef),VervDat($$INTDATE^vhDTyp($P(R,D,3)))=""
 .Set Gewicht(VervRef)=$P(R,D,6)
 .For I=8:1:12 Do
 ..If $P($P(R,D,I),";")="E"!($P($P(R,D,I),";")="B") Set Palet(VervRef)=$G(Palet(VervRef))+$P($P(R,D,I),";",2)
 ..Else  Set Collie(VervRef)=$G(Collie(VervRef))+$P($P(R,D,I),";",2)
 Set (Waarde,Gewicht,Palet,Collie)=""
 Do PRINTVB(LEVNr,.VervRef,.VervDat,.Waarde,.Gewicht,.Palet,.Collie) 
 Quit
 
PRINTVB(LEVNr,VervRef,VervDat,Waarde,Gewicht,Palet,Collie) 
 New I,V,Next,LvhNaam,LvhAdres,LvhWoorp,LevNaam,Length,RCPNr,RCPNrs,RCPDate,RCPDates
 Set V=10,LvhNaam=^KBA(99,1),LvhAdres=^KBA(99,2),LvhWoonp=^KBA(99,3)
 Set LevNaam=$P(^KLE(^KL1(LEVNr),0),D,2),VervRef=$G(VervRef),(Next,RCPNrs,RCPDates)=""
 For  Set Next=$O(VervRef(Next)) Quit:Next=""  Do
 .Set:$L(VervRef) VervRef=VervRef_"  - "
 .Set VervRef=VervRef_$J($S(Next'?.N:Next,1:$$EXTNUM^vhDTyp(Next,0,".",0)),7)
 .Set:$L(RCPNrs) RCPNrs=RCPNrs_"  - "
 .Set RCPNrs=RCPNrs_$J($S(Next'?.N:VervRef(Next),1:$$EXTNUM^vhDTyp(VervRef(Next),0,".",0)),7),RCPDate=""
 .Do:Next?.N
 ..Set RCPNr=VervRef(Next)
 ..Quit:'RCPNr  Quit:'$D(^RCP("D",RCPNr))
 ..Set RCPDate=$P($G(^RCP("D",RCPNr)),D,4) Set:RCPDate RCPDate=$$EXTDATE^vhDTyp(RCPDate)
 .Set:$L(RCPDates) RCPDates=RCPDates_" - "
 .Set RCPDates=RCPDates_$J(RCPDate,8)
 Set:$E(RCPNrs,$L(RCPNrs)-9,$L(RCPNrs))=" -        " $E(RCPNrs,$L(RCPNrs)-9,$L(RCPNrs))=""
 Set VervDat=$G(VervDat)
 For  Set Next=$O(VervRef(Next)) Quit:Next=""  Do
 .Set:$L(VervDat) VervDat=VervDat_" - "
 .Set VervDat=VervDat_$P(^Verv(LEVNr,"D",Next),D,3)
 Set Waarde=$G(Waarde)
 For  Set Next=$O(Waarde(Next)) Quit:Next=""  For I=1:1:7 Set $P(Waarde,D,I)=$P(Waarde,D,I)+$P(Waarde(Next),D,I)
 Set Gewicht=$G(Gewicht)
 For  Set Next=$O(Gewicht(Next)) Quit:Next=""  Set Gewicht=Gewicht+Gewicht(Next)
 Set Palet=$G(Palet)
 For  Set Next=$O(Palet(Next)) Quit:Next=""  Set Palet=Palet+Palet(Next)
 Set Collie=$G(Collie)
 For  Set Next=$O(Collie(Next)) Quit:Next=""  Set Collie=Collie+Collie(Next)
 Set Length=$L($$EXTNUM^vhDTyp($P(Waarde,D),0,".T",2))
 Write !,"Vervoerslijst facturen - overzicht",?69-$L(LvhNaam),LvhNaam
 Write !?75-$L(LvhAdres),LvhAdres
 Write !?75-$L(LvhWoonp),LvhWoonp
 Write !!!!!!!!!!!!!?75-V-$L(LevNaam)/2,@FMTB,LevNaam,@FMTb
 Write !!?V,"Zending nr.  : ",@FMTB
 For I=1:5 Write ?V+15,$P(VervRef,"  - ",I,I+4),! Quit:$P(VervRef,"  - ",I+5,I+8)=""
 Write @FMTb
 Write $C(13),?V,"Factuurdatum : "
 For I=1:5 Write ?V+15,$P(VervDat," - ",I,I+4),! Quit:$P(VervDat," - ",I+5,I+8)=""
 Write !?V,"Receptie nr. : "
 For I=1:5 Write ?V+15,$P(RCPNrs,"  - ",I,I+4),! Quit:$P(RCPNrs,"  - ",I+5,I+8)=""
 Write ?V,"Receptiedatum: "
 For I=1:5 Write ?V+15,$P(RCPDates," - ",I,I+4),! Quit:$P(RCPDates," - ",I+5,I+8)=""
 Write !?V,"(Aanmaakdatum receptie -> inboekdatum)"
 Write !!!!!!?V,*27,"-",*1,"Goederen ingeschreven",*27,"-",*0,?V+30,": "
 Write !!!!!?V,*27,"-",*1,"Waarde EUR",*27,"-",*0,?V+30,": ",$$EXTNUM^vhDTyp($P(Waarde,D),Length,".T",2)
 If $P(Waarde,D,5) Write !!?V,*27,"-",*1,"Proforma EUR",*27,"-",*0,?V+30,": ",$$EXTNUM^vhDTyp($P(Waarde,D,5),Length,".T",2)
 Write !!?V,*27,"-",*1,"Gewicht kg",*27,"-",*0,?V+30,": ",$$EXTNUM^vhDTyp(Gewicht,Length-3,".T",0)
 Write !!?V,*27,"-",*1,"# Paletten",*27,"-",*0,?V+30,": ",$$EXTNUM^vhDTyp(Palet,Length-3,".T",0)
 Write !!?V,*27,"-",*1,"# Pakken",*27,"-",*0,?V+30,": ",$$EXTNUM^vhDTyp(Collie,Length-3,".T",0)
 Write #
 Quit
 
 ; De geselecteerde vervoersreferenties een voor een factureren
Factureren(LEVNr,VervRef)
 For  Do  Quit:VervRef=""
 . Quit:$P(VervRef,";")=""
 . If $$BevatFactuur^VERVID(LEVNr,$P(VervRef,";")),$$ASK^vhWACHTW("BOEKHOUD.") Do VervRef^BLCSBAF($P(VervRef,";"))
 . Set VervRef=$P(VervRef,";",2,99)
 Quit