BLDIK ;BLUM KLANTEN ;BLDIK; Do naar PROC
 G BEGIN
 ;
T1 ;KLANTNUMMER;4;2;;4;14;;;6;;K?.N&K!(K="-");;;;;
T2 ;KLANTNAAM;5;2;;5;14;;;30;;$L(K);;;;;1
T3 ;WOONPLAATS;6;2;;6;14;;;30;;$L(K);;;;;2
 ;
T10 ;1;.N;R;8;;| \2;C;L;30
T11 ; NUMMER | NAAM
T12 ;VERWIJDEREN KLANT : 
T13 ;V = verwijderen   - = hernemen
T14 ;  [] = ok 
T15 ; Dit klantnummer bestaat reeds
T16 ;BLUM RAADPL DIR KLANT;OVERZICHT
 ;
O1 S K=$P($T(T15),U,2) G OY
OY S FP=2403 W @F,@F1,@FMTI,K,$P($T(T14),U,2),@FMTi,@F0 R *K
OZ Q
 ;
 ; Initialisatie
IN S K=$P($T(+1),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
 F I=1:1 S U2=$P($T(@("T"_I)),U,2,999) Q:U2=""  D RUB
 S BLK(1)="blk",BLK(2)=$P($T(T10),U,2,999),BLK(3)=9,BLK(8)=$P($T(T11),U,2)
 Q
 ;
 ; Help
HLP S HLP(1)=$P($T(T16),U,2),HLP(2)=$P($T(T16),U,3),HLP(3)=9,HLP(6)="" D HLP^HELP
 Q
 ;
 ; Opzetten rubrieken
RUB S FP=$P(U2,U,5)*100+$P(U2,U,6) W @F,@F9,":"
 S FP=$P(U2,U,2)*100+$P(U2,U,3) W @F,@F6,$P(U2,U,1),@F9
 Q
 ;
 ; Ophalen klanten
BLK K DL,BLK(9) S DL(1)="BLK" I $D(U4),U4'="N",U4'="V" G BLK2
 S BLK=$N(^BLBeri("K",0)),BLK=0 K blk
BLK1 S BLK=$N(^(BLK)) I BLK'=-1 S U2=^(BLK),blk($P(U2,D,1)_BLK)=BLK_D_U2 G BLK1
 D RL^PROC1
 S BLK(6)=1 I $D(B) F I=1:1 Q:'$D(blk(I))  I B=blk(I) S BLK(6)=I Q
 D WL^PROC
BLK2 D SL^PROC
 Q
 ;
 ; Show klant
SKL S B=blk(BLK(6)) F I=1:1 S U2=$P($T(@("T"_I)),U,2,999) Q:U2=""  D DISPL
 Q
 ;
 ; Klantinfo
DISPL S K=$P(B,D,$P(U2,U,16)+1) I $L($P(U2,U,8)) X "S K="_$P(U2,U,8)
 S FP=$P(U2,U,5)*100+$P(U2,U,6)+3 W @F,$J("",$P(U2,U,9)),$J("",$P(U2,U,13)),@F,K
 Q
 ;
 ; Clear klant
CLR F I=1:1 S U2=$P($T(@("T"_I)),U,2,999) Q:U2=""  S FP=$P(U2,U,5)*100+$P(U2,U,6)+3 W @F,$J("",$P(U2,U,9)),$J("",$P(U2,U,13))
 Q
 ;
 ; Nieuwe klant
NEW D CLR,CL^PROC1 F I=1:1 D INP Q:U2=""!(K=",")  I K="-" S I=I-2
 I K="-"!(K=",") K B D CLR S R=U4 G NEW1
 S ^BLBeri("K",$P(B,D,1))=$P(B,D,2,99)
NEW1 Q
 ;
 ; Input nieuwe klant
INP S U2=$P($T(@("T"_I)),U,2,999) G INP2:U2=""
INP1 S R="K\22\3\"_$P(U2,U,1)_"\"""_$P(U2,U,10)_"""\"_$P(U2,U,9)_"\\"_$P(U2,U,11) D R0^cA100
 G INP2:K="-"!(K=",") I '$P(U2,U,16),$D(^BLBeri("K",K)) D O1 G INP1
 S $P(B,D,$P(U2,U,16)+1)=K D DISPL
INP2 Q
 ;
 ; Verwijderen klant
VRW G VRW2:'$D(blk) I $D(B),B=blk(BLK(6)) G VRW1
 D SKL
VRW1 D CL^PROC1
 S FP=2303 W @F,$P($T(T12),U,2),$P(B,D,1)," ",$P(B,D,2)
 W !?2,$P($T(T13),U,2) D IK^PROC1
 I R="V" D CLR K ^BLBeri("K",$P(B,D,1)),B
VRW2 Q
 ;
BEGIN D IN
 ;
2 D BLK
21 G END:R="-" S U4=R I U4="" S U4="ENTER"
 I U4="ENTER" D SKL G 2
 I U4="N" D NEW G 21:K=",",2
 I U4="V" D VRW G 2:R'="N",21
 I U4'="?",U4'="HELP" G 2
 D HLP K DL S DL(1)="BLK" I "\-\?\HELP\N\"[(D_R_D) G 21
 D WL^PROC G 21
 ;
END Q
 ;
Z X ^cZ Q
ZZ ; 14.06.91 - 10 u 14