BURBIDI ;Import van export van de verschillende BURBIDGE tabellen [ 11/22/2003   1:21 PM ]
 ; 1. Reeksen : Lijst met alle reeksen 
REEKS ;Reeks-Kleur;OmschrijfN;OmschrijfF;CodeReeks;AccReeksen;Klas
 ; 2. Lijst met de kodes per groep van reeksen (400, 800, XXX en YYY)
CODE ;Groep;Code;SortNr;LevTrm(*);Korttekst;OmschrijfN;AfmetingN;OmschrijfF;AfmetingF
 ; 3. Lijst met de kleurkodes
KLEUR ;BurbCode;VHCode
 ; 4. Lijst met de produkten 
PROD ;Reeks;Kleur;Kode;Reeks-Kleur-Kode;PrijsLev;Korting;DB%;LevTrm
 
 ; ***** REEKS *****
 
IMPREEKS Kill ^BURBID("R")
 Set FileNm=$$READ^vhDEV(,"*.TXT","D`IMPRECB^"_$ZN,"D;T","P")
 Quit
 
IMPRECB(Rec) ; Callback bij elk ingelezen record
 Set Reeks=$P(Rec,D)
 Quit:Reeks=""
 Quit:$P(Reeks,D)'?3N.E  ; Titel
 Set ^BURBID("R",Reeks)=$TR($P(Rec,D,2,99),"""","")
 Quit
 
EXPREEKS Set Dev=$$OPEN^vhDEV(,"REEKS.TXT","W","A")
 Quit:0[Dev
 Use Dev
 Write $TR($P($T(REEKS),";",2,99),";",$C(9)),!
 Set Reeks=""
 For  Set Reeks=$O(^BURBID("R",Reeks)) Quit:Reeks=""  Do
 .Set Rec=^BURBID("R",Reeks)
 .Write $TR(Reeks_D_Rec,D,$C(9)),!
 Close:0'[Dev Dev
 Quit
 
 ; ***** KLEUR *****
 
IMPKLEUR Kill ^BURBID("K")
 Set FileNm=$$READ^vhDEV(,"*.TXT","D`IMPRECK^"_$ZN,"D;T","P")
 Quit
 
IMPRECK(Rec) ; Callback bij elk ingelezen record
 Set Kleur=$P(Rec,D)
 Quit:Kleur=""
 Quit:$P(Kleur,D)'?2N.E  ; Titel
 Set ^BURBID("K",Kleur)=$TR($P(Rec,D,2,99),"""","")
 Quit
 
EXPKLEUR Set Dev=$$OPEN^vhDEV(,"KLEUR.TXT","W","A")
 Quit:0[Dev
 Use Dev
 Write $TR($P($T(KLEUR),";",2,99),";",$C(9)),!
 Set Kleur=""
 For  Set Kleur=$O(^BURBID("K",Kleur)) Quit:Kleur=""  Do
 .Set Rec=^BURBID("K",Kleur)
 .Write $TR(Kleur_D_Rec,D,$C(9)),!
 Close:0'[Dev Dev
 Quit
 
 ; ***** GROEP CODE *****
 
IMPCODE 
 ;Kill ^BURBID("GC") 
 Kill ^BURBID("GC","400")
 Set FileNm=$$READ^vhDEV(,"*.TXT","D`IMPGCCB^"_$ZN,"D;T","P")
 Quit
 
IMPGCCB(Rec) ; Callback bij elk ingelezen coderecord
 Set Reeks=$P(Rec,D)
 Set Code=$P(Rec,D,2)
 Quit:Reeks=""
 Quit:$P(Reeks,D)'?3E  ; Titel
 Set ^BURBID("GC",Reeks,Code)=$P(Rec,D,3,99)
 Quit
 
EXPCODE Set Dev=$$OPEN^vhDEV(,"GROEPCODE.TXT","W","A")
 Quit:0[Dev
 Use Dev
 Write $TR($P($T(CODE),";",2,99),";",$C(9)),!
 Set (Reeks,Code)=""
 For  Set Reeks=$O(^BURBID("GC",Reeks)) Quit:Reeks=""  Do
 .For  Set Code=$O(^BURBID("GC",Reeks,Code)) Quit:Code=""  Do
 ..Set Rec=^BURBID("GC",Reeks,Code)
 ..Write $TR(Reeks_D_Code_D_Rec,D,$C(9)),!
 Close:0'[Dev Dev
 Quit
 
IMPPROD Kill ^BURBID("B")  ; Basis
 Set VolgNr=0
 Set FileNm=$$READ^vhDEV(,"*.TXT","D`IMPPRCB^"_$ZN,"D;T","P")
 Quit
 
IMPPRCB(Rec) ; Callback bij elk ingelezen produktrecord
 Set VolgNr=VolgNr+1
 Set Reeks=$P(Rec,D)
 Quit:Reeks=""
 Quit:$P(Reeks,D)'?3N  ; Titel
 Set ^BURBID("B",VolgNr)=Rec
 Quit
 
EXPTABLE Set Dev=$$OPEN^vhDEV(,"COMPARE.TXT","W","A")
 Quit:0[Dev
 Use Dev
 Write "PRNr",$C(9),"Status",$C(9),$TR($P($T(PROD),";",2,99),";",$C(9)),$C(9),"VH LevRef",$C(9),"VH KTxt",$C(9),"VH AKP",$C(9),"VH K%",$C(9),"VH DB%",!
 ; Bijvoegen
 Set (VolgNr)=""
 For  Set VolgNr=$O(^BURBID("ADD",VolgNr)) Quit:VolgNr=""  Do
 .Set RecC=^BURBID("B",VolgNr)
 .Write VolgNr,$C(9),"ADD",$C(9),$TR($P(RecC,D,1,8),D,$C(9)),!
 ; Wijzigen
 Set PRNr=0
 For  Set PRNr=$O(^BURBID("MOD",PRNr)) Quit:PRNr=""  Do
 .Do FETCHPR^UTILI(PRNr,"Rec")
 .Set VolgNr=$P(^BURBID("MOD",PRNr),D,1)
 .Set Diff=$P(^BURBID("MOD",PRNr),D,2)
 .Set RecC=^BURBID("B",VolgNr)
 .Write PRNr,$C(9),$S(Diff:"MOD",1:"EQ"),$C(9),$TR($P(RecC,D,1,8),D,$C(9))
 .Write $C(9),$P(Rec("J"),D,3),$C(9),$P(Rec(0),D,1)
 .Write:Diff $C(9),$P(Rec("J"),D,19),$C(9),$P(Rec("J"),D,9),$C(9),$P(Rec("J"),D,24)
 .Write !
 ; Verwijderen
 Set PRNr=0
 For  Set PRNr=$O(^BURBID("DEL",PRNr)) Quit:PRNr=""  Do
 .Set DelStat=^BURBID("DEL",PRNr)
 .Do FETCHPR^UTILI(PRNr,"Rec")
 .Set LevRef=$P(Rec("J"),D,3)
 .Set Reeks=$P(LevRef,"-",1)
 .Set Kleur=$P(LevRef,"-",2)
 .Set Code=$P($P(LevRef,"-",3),"(")
 .Set AltRks=$P($P(LevRef,"(",2),")")
 .Write PRNr,$C(9),"DEL",$C(9),Reeks,$C(9),Kleur,$C(9),Code,$C(9),AltRks,$C(9),$P(DelStat,D),$C(9),$P(DelStat,D,2),$C(9),$C(9),$C(9),LevRef,$C(9),$P(Rec(0),D,1),!
 Close:0'[Dev Dev