CEURKAAR ; Conversie regiostatistiek naar Euro (^KKAAR) ;[ 03/15/2001  9:17 AM ]
 Quit
 ;
T1 ;Wenst u de regiostatistiek naar Euro te converteren?
T2 ;Conversie regiostatistiek naar Euro (^KKAAR)
 ;
RUN(TxtPop) 
 New (TxtPop)
 Do
 .New TxtPop
 .Do INIT^vhTERMINA
 Set TxtPop=$G(TxtPop,1),Run=1
 Do:TxtPop
 .Write @F11,@F1
 .Set Txt(1)=$P($T(T1),";",2),Run=$$TXTPOP^CEUR(.Txt)
 Do:Run
 .Write !,$ZN,?10,$P($T(T2),";",2)
 .Kill ^CEURERR($ZN)
 .Set Date=0
 .For  Set Date=$O(^KKAAR(Date)) Quit:Date=""  Do ONEDAY(Date)
 Quit
 ;
ONEDAY(Date) 
 New I,R,FromMunt,ToMunt,Regio
 Set FromMunt="BEF",ToMunt="EUR"
 Set Regio=""
 For  Set Regio=$O(^KKAAR(Date,Regio)) Quit:Regio=""  Do
 .Set R=^KKAAR(Date,Regio)
 .For I=1,2 Set $P(R,D,I)=$$BEDRAG^CEUR($P(R,D,I),FromMunt,ToMunt)
 .Set ^KKAAR(Date,Regio)=R
 Quit
 ;
DOC 
 ;Conversie ^KKAAR (Regiostatistiek)
 ;
 ;
 ;Routine: RUN^CEURKAAR()
 ;
 ;
 ;Geconverteerde nodes:
 ;
 ;^KKAAR(Date,Regio)
 ;  Velden 1 en 2 in BEF omrekenen naar EUR
 ;***
 New L,R
 Write !,$ZN,!
 For L=1:1 Set R=$T(DOC+L) Quit:R=""!($P(R,";",2)="***")  Do
 .If $E(R)=" " Write !?5,$P(R,";",2,99)
 .Else  Xecute $P(R,";")_$P(R,";",2,99)
 Quit
 ;