CEURKL ; Conversie naar Euro (klanten) ;[ 12/21/2001  2:18 PM ]
 Quit
 ;
ONECUST(KLNr,Ord,Off,Mail,NoTxtPop,vhLock) 
 New R,KlRef,KlNaam,KlMunt,Txt,Ref,MailId
 Set Off=$G(Off,1),Ord=$G(Ord,1),Mail=$G(Mail,1),NoTxtPop=$G(NoTxtPop),vhLock=$G(vhLock)
 Set KLNr=$G(KLNr) Set:'KLNr KLNr=$$SELECT^KLANT6()
 Do:KLNr
 .Set KlRef=^KK1(KLNr),R=^KKL(KlRef,0),KlNaam=$P(R,D,2),KlMunt=$P(R,D,11) Set:KlMunt="" KlMunt=$$FADEF^vhRtn1()
 .Do:KlMunt'="EUR"
 ..Set Txt=""
 ..If $D(^KOD(KLNr))!$D(^KOFKL(KLNr)) Do
 ...If 'Ord,'Off Quit
 ...Set Txt="Alle "
 ...If Ord,$D(^KOD(KLNr)) Set Txt=Txt_"orders " Set:$D(^KOFKL(KLNr)) Txt=Txt_"en "
 ...If Off,$D(^KOFKL(KLNr)) Set Txt=Txt_"offertes "
 ...Set Txt=Txt_"worden op EUR gebracht!"
 ..If '$G(NoTxtPop) Quit:'$$^vhTXTPOP("CEUR","KLANT","",KlNaam,KlMunt,Txt)
 ..Set $P(R,D,11)="EUR"
 ..Set ^KKL(KlRef,0)=R
 ..If 'Ord,'Off Quit
 ..Do:Ord ONECUST^CEURORD(KLNr,1,vhLock)
 ..Do:Off ONECUST^CEUROFF(KLNr,1,vhLock)
 ..Quit:'Mail
 ..Set Txt="Deze klant is van "_KlMunt_" naar EUR gebracht."
 ..If $D(^KOD(KLNr))!$D(^KOFKL(KLNr)) Do
 ...If 'Ord,'Off Quit
 ...Set Txt="Alle "
 ...If Ord,$D(^KOD(KLNr)) Set Txt=Txt_"orders " Set:$D(^KOFKL(KLNr)) Txt=Txt_"en "
 ...If Off,$D(^KOFKL(KLNr)) Set Txt=Txt_"offertes "
 ...Set Txt=Txt_"van deze klant zijn van "_KlMunt_" naar EUR gebracht."
 ..Set Ref(1)="KL\"_KLNr_"\R\1"
 ..Set MailId=$$SYSTEM^vhMAIL("KL",KLNr,"Omzetten naar Euro","ORDVW",Txt,.Ref,1,1)
 Quit
 ;
ALL 
 New
 Do INIT^vhTERMINA
 Write @F11,@F1
 Set R=$$^vhTXTPOP("CEUR","KLALL")
 Do:R
 .Set KlantId=0
 .For  Set KlantId=$O(^KKL(KlantId)) Quit:KlantId=""  Do
 ..Set R=^KKL(KlantId,0),Land=$P(R,D,8),Munt=$P(R,D,11)
 ..Quit:Munt="EUR"
 ..Set Land=$$LAND^vhRtn1(Land)
 ..Set KLNr=$P(R,D),KlNaam=$P(R,D,2)
 ..Set ^CEUR(DT,KlantId,0)=R
 ..Set R=^KKL(KlantId,3),LevVw=$P(R,D,3)
 ..If "\51\"[(D_LevVw_D) Set $P(R,D,3)=61,^KKL(KlantId,3)=R,LevVw=LevVw_"->61",Count(61)=$G(Count(61))+1
 ..If "\10\20\40\50\"[(D_LevVw_D) Set $P(R,D,3)=60,^KKL(KlantId,3)=R,LevVw=LevVw_"->60",Count(60)=$G(Count(60))+1
 ..Set $P(R,D,3)=LevVw,^CEUR(DT,KlantId,3)=R
 ..Write !,KLNr,?6,KlNaam,?35,Land,?40,Munt,?45,LevVw
 ..Write:$D(^KOFKL(KLNr)) ?55,"Off" Write:$D(^KOD(KLNr)) ?60,"Ord"
 ..Lock +^KOFKL(KLNr),+^KOD(KLNr)
 ..Do ONECUST(KLNr,,,0,1,) 
 ..Lock -^KOFKL(KLNr),-^KOD(KLNr)
 .Write !!! ZWrite Count
 Quit
 ;