CEURKOV ; Conversie potentieel naar Euro (^KKOV) ;[ 05/17/2001  10:47 AM ]
 Quit
 ;
T1 ;Wenst u alle potentieel naar Euro te converteren?
T2 ;Conversie potentieel naar Euro (^KKOV)
 ;
RUN(TxtPop) 
 New (TxtPop)
 Do
 .New TxtPop
 .Do INIT^vhTERMINA
 Set TxtPop=$G(TxtPop,1),Run=1
 Do:TxtPop
 .Write @F11,@F1
 .Set Txt(1)=$P($T(T1),";",2),Run=$$TXTPOP^CEUR(.Txt)
 Do:Run
 .Write !,$ZN,?10,$P($T(T2),";",2)
 .Kill ^CEURERR($ZN)
 .Set KLNr=0
 .For  Set KLNr=$O(^KKOV(KLNr)) Quit:KLNr=""  Do ONECUST(KLNr)
 .Set Global=$P($P($T(T2),"(",2),")")
 .Do COMPRESS^CEUR(Global)
 Quit
 ;
ONECUST(KLNr) 
 New I,R,HoofdGr,Groep,Verd,Fabr,FromMunt,ToMunt
 Set FromMunt="BEF",ToMunt="EUR"
 Set HoofdGr=""
 For  Set HoofdGr=$O(^KKOV(KLNr,HoofdGr)) Quit:HoofdGr=""  Do
 .Set Groep=""
 .For  Set Groep=$O(^KKOV(KLNr,HoofdGr,Groep)) Quit:Groep=""  Do
 ..Set Verd=""
 ..For  Set Verd=$O(^KKOV(KLNr,HoofdGr,Groep,Verd)) Quit:Verd=""  Do
 ...Set Fabr=""
 ...For  Set Fabr=$O(^KKOV(KLNr,HoofdGr,Groep,Verd,Fabr)) Quit:Fabr=""  Do
 ....Set R=^KKOV(KLNr,HoofdGr,Groep,Verd,Fabr)
 ....For I=6,16 Set $P(R,D,I)=$$BEDRAG^CEUR($P(R,D,I),FromMunt,ToMunt,2)
 ....Set $P(R,D,22)="EUR"
 ....Set ^KKOV(KLNr,HoofdGr,Groep,Verd,Fabr)=R
 Quit
 ;
DOC 
 ;Conversie ^KKOV (Potentieel)
 ;
 ;
 ;Routine: RUN^CEURKOV()
 ;
 ;
 ;Geconverteerde nodes:
 ;
 ;^KKOV(KLNr,HoofdGr,Groep,Verdeler,Fabrikant)
 ;  Velden 6 en 16 in BEF omrekenen naar EUR
 ;  Veld 22 Munt BEF naar EUR
 ;***
 New L,R
 Write !,$ZN,!
 For L=1:1 Set R=$T(DOC+L) Quit:R=""!($P(R,";",2)="***")  Do
 .If $E(R)=" " Write !?5,$P(R,";",2,99)
 .Else  Xecute $P(R,";")_$P(R,";",2,99)
 Quit
 ;