CEURSPW ; Conversie weekstatistiek naar Euro (^KSPW) ;[ 05/17/2001  10:29 AM ]
 Quit
 ;
T1 ;Wenst u alle weekstatistieken naar Euro te converteren?
T2 ;Conversie weekstatistiek naar Euro (^KSPW)
 ;
RUN(TxtPop) 
 New (TxtPop)
 Do
 .New TxtPop
 .Do INIT^vhTERMINA
 Set TxtPop=$G(TxtPop,1),Run=1
 Do:TxtPop
 .Write @F11,@F1
 .Set Txt(1)=$P($T(T1),";",2),Run=$$TXTPOP^CEUR(.Txt)
 Do:Run
 .Write !,$ZN,?10,$P($T(T2),";",2)
 .Kill ^CEURERR($ZN)
 .Set PRNr=0
 .For  Set PRNr=$O(^KSPW(PRNr)) Quit:PRNr=""  Do ONEPROD(PRNr)
 .Set Global=$P($P($T(T2),"(",2),")")
 .Do COMPRESS^CEUR(Global)
 Quit
 ;
ONEPROD(PRNr) 
 New I,R,WeekNr,FromMunt,ToMunt,TOENr
 Set FromMunt="BEF",ToMunt="EUR"
 Set WeekNr=""
 For  Set WeekNr=$O(^KSPW(PRNr,WeekNr)) Quit:WeekNr=""  Do
 .If WeekNr?.N Do
 ..Set TOENr=""
 ..For  Set TOENr=$O(^KSPW(PRNr,WeekNr,TOENr)) Quit:TOENr=""  Do
 ...Set R=^KSPW(PRNr,WeekNr,TOENr)
 ...Set $P(R,D,2)=$$BEDRAG^CEUR($P(R,D,2),FromMunt,ToMunt)
 ...Set ^KSPW(PRNr,WeekNr,TOENr)=R
 .Else  Do
 ..Set R=^KSPW(PRNr,WeekNr)
 ..For I=2,3,8,10:1:12 Set $P(R,D,I)=$$BEDRAG^CEUR($P(R,D,I),FromMunt,ToMunt)
 ..Set ^KSPW(PRNr,WeekNr)=R
 Quit
 ;
DOC 
 ;Conversie ^KSPW (Weekstatistiek)
 ;
 ;
 ;Routine: RUN^CEURSPW()
 ;
 ;
 ;Geconverteerde nodes:
 ;
 ;^KSPW(PRNr,WeekNr,TOENr)
 ;  Veld 2 in BEF omrekenen naar EUR
 ;
 ;^KSPW(PRNr,WeekNr_" ")
 ;  Velden 2, 3, 8, 10, 11 en 12 in BEF omrekenen naar EUR
 ;***
 New L,R
 Write !,$ZN,!
 For L=1:1 Set R=$T(DOC+L) Quit:R=""!($P(R,";",2)="***")  Do
 .If $E(R)=" " Write !?5,$P(R,";",2,99)
 .Else  Xecute $P(R,";")_$P(R,";",2,99)
 Quit
 ;