DCPROD ;AFDRUKKEN DOKUMENTEN (Detail produktlijn) [ 08/25/2003  11:42 AM ]
 ;
 ; Ophalen omschrijving produkt
FETCHPR(PRNr,Taal) 
 New Global,I
 Set (KortText,IdentNr)=""
 Set Global="^KPR" If '$D(^KPR(PRNr)) Set Global="^KPRO" If '$D(^KPRO(PRNr)) Quit
 Set R=$$FETCHPN(0),KortText=$P(R,D)
 Set R=$$FETCHPN(2),IdentNr=$P(R,D,25)
 If $D(Taal) Do  Quit
 .Set Kleur="" For I=1:1:23 Set @("Omschr"_I)=""
 .Set Kleur=$E(KortText,$L(KortText)-3,$l(KortText))_" "
 .If $D(^KCOL(Kleur,Taal)) Set Kleur=^KCOL(Kleur,Taal)
 .Else  Set Kleur=""
 .Set R=$$FETCHPN($P("0\1\2\2",D,$F("NFDE",Taal)-1))
 .Set Omschr1=$P(R,D,$P("2\22\2\1",D,$F("NFDE",Taal)-1))
 .Set R=$$FETCHPN($P("0\3\3\3",D,$F("NFDE",Taal)-1))
 .Set Omschr2=$P(R,D,$P("11\21\23\22",D,$F("NFDE",Taal)-1))
 .Set R=$$FETCHPN($P("6\8\10\12",D,$F("NFDE",Taal)-1))
 .For I=1:1:10 Set @("Omschr"_(I+2))=$P(R,D,I)
 .Set R=$$FETCHPN($P("7\9\11\13",D,$F("NFDE",Taal)-1))
 .For I=1:1:10 Set @("Omschr"_(I+12))=$P(R,D,I)
 .If Taal'="N" Do
 ..For I=1:1 Quit:'$D(@("Omschr"_I))  Quit:$L(@("Omschr"_I))
 .Do:'$D(@("Omschr"_I)) FETCHPR(PRNr,"N")
 Set R=$$FETCHPN(1),IsStock=$P(R,D,20)
 Set LevRef="" For I=1:1:20 Set @("Omschr"_I)=""
 Set R=$$FETCHPN(4)
 For I=1:1:3 Set @("Omschr"_I)=$P(R,D,I)
 For I=4:1:10 Set @("Omschr"_(I+3))=$P(R,D,I)
 Set R=$$FETCHPN(5)
 For I=1:1:3 Set @("Omschr"_(I+3))=$P(R,D,I)
 For I=4:1:10 Set @("Omschr"_(I+10))=$P(R,D,I)
 Set R=$$FETCHPN("J"_LEVNr),LevRef=$P(R,D,3)
 If $$TRIMN^vhRtn1(LevRef)=$$TRIMN^vhRtn1($E(IdentNr,2,99)) Set LevRef=""
 Quit
 ;
 ; Ophalen van een bepaalde node van het produktenbestand
FETCHPN(Node) 
 Quit $G(@(Global_"(PRNr,Node)"))
 ;
FN(Number,Fraction,Format) 
 Quit $$FN^DCALG(Number,Fraction,$G(Format))
 ;
BLOCK(R) 
 Do BLOCK^DCALG(R)
 Quit
 ;
 ; Verwerking produktlijn
 ; Faktuur
PRODFAKT(R) 
 New PRNr,KortText,IdentNr,Kleur,Omschr,Omschr1,Omschr2,Omschr3,KlantRef,ProjRef
 New Aantal,Prijs,Korting,Bedrag,Round,Nr,ContrRef,ChargeTraceID
 Set PRNr=$P(R,D,2),Aantal=$P(R,D,3),Omschr=$P(R,D,5),Prijs=$P(R,D,6)
 Set Korting=$P(R,D,7),Bedrag=$P(R,D,9),ContrRef=$P(R,D,13),ChargeTraceID=$P(R,D,43)
 Set Round=$P(R,D,21),Round=$P("%\/M",D,$F("HM",$E(Round))-1)
 Do FETCHPR(PRNr,Taal)
 Set Omschr1=$E(Omschr1,1,44-$L(Kleur))
 Set R=IdentNr_"`3"_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"_D_$$FN(Aantal,0)_"``51"
 If $L(Round) Set R=R_D_Round_"`63"
 Set R=R_D_$$FN(Prijs,2)_"``63"_D_$$FN(Bedrag,2)_"``78"
 Do BLOCK(R)
 Set R="   "_Omschr1_$J("",45-$L(Omschr1)-$L(Kleur))_Kleur_"`2`41`CT"
 If NetBrutP Set Korting=$$KORTING^DCALG(Korting),R=R_D_Korting_"``63"
 Do BLOCK(R)
 For Nr=2:1:23 Set R=$$OMSCHR^DCALG(Nr) If $L(R) Do BLOCK(R)
 Do KLANTREF("DCFAKT",45),PROJREF("DCFAKT",45)
 If $L(KlantRef) Set R="   "_KlantRef_$J("",45-$L(KlantRef))_"`2`41`CT" Do BLOCK(R)
 If $L(ContrRef) Do
 .Set ContrRef=$$CONTRREF(ContrRef,"DCFAKT",45)
 .Quit:ContrRef=""
 .Set R="   "_ContrRef_$J("",45-$L(ContrRef))_"`2`41`CT"
 .Do BLOCK(R)
 If $L(ProjRef) Set R="   "_ProjRef_$J("",45-$L(ProjRef))_"`2`41`CT" Do BLOCK(R)
 Do:ChargeTraceID ChargeTraceID(ChargeTraceID)
 Quit
 ;
 ; Bon
PRODBON(R) 
 New PRNr,KortText,IdentNr,Kleur,Omschr,Omschr1,Omschr2,Omschr3,KlantRef,ProjRef,StockUpd
 New Aantal,Saldo,Nr,ContrRef,ChargeTraceID
 Set PRNr=$P(R,D,2),Aantal=$P(R,D,3),Omschr=$P(R,D,5),Saldo=0
 If $P(R,D,23) Set Saldo=$P(R,D,23)-Aantal
 Set StockUpd=$P(R,D,14)'["S" Set:StockUpd StockUpd=$P(R,D,14)'["Z"
 Set ContrRef=$P(R,D,13),ChargeTraceID=$P(R,D,43)
 Do FETCHPR(PRNr,Taal)
 Set Omschr1=$E(Omschr1,1,44-$L(Kleur))
 Set R=IdentNr_"`3"_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"_D_$$FN(Aantal,0)_"``63"
 Set:'StockUpd R=R_D_"*`64"
 If Saldo Set R=R_D_$$FN(Saldo,0)_"``78"
 Do BLOCK(R)
 Set R="   "_Omschr1_$J("",45-$L(Omschr1)-$L(Kleur))_Kleur_"`2`41`CT"
 Do BLOCK(R)
 For Nr=2:1:23 Set R=$$OMSCHR^DCALG(Nr) If $L(R) Do BLOCK(R)
 Do KLANTREF("DCBON",45),PROJREF("DCBON",45)
 If $L(KlantRef) Set R="   "_KlantRef_$J("",45-$L(KlantRef))_"`2`41`CT" Do BLOCK(R)
 If $L(ContrRef) Do
 .Set ContrRef=$$CONTRREF(ContrRef,"DCBON",45)
 .Quit:ContrRef=""
 .Set R="   "_ContrRef_$J("",45-$L(ContrRef))_"`2`41`CT"
 .Do BLOCK(R)
 If $L(ProjRef) Set R="   "_ProjRef_$J("",45-$L(ProjRef))_"`2`41`CT" Do BLOCK(R)
 If '$G(IsBlum) For  Set R=##class(BL.Flow.RecuPak.Main).GetQty(PRNr,Aantal,1) Quit:'$LG(R,1)  Quit:$LG(R,1)=PRNr  Do  Quit:'PRNr  ; Vermelden aantal ecopacks
 .Set PRNr=$LG(R,1),Aantal=$LG(R,2)
 .If $D(PRNr(PRNr)) Set PRNr="" Quit
 .Set PRNr(PRNr)=""
 .Do FETCHPR(PRNr,Taal)
 .Set R=KortText_$S(Aantal:" : "_$$FN(Aantal,0)_$$TXT^DCBON("AantEcoPak"_$S(Aantal=1:"",1:"s")),1:"")
 .Set R="   "_R_$J("",45-$L(R))_"`2`41`CT"
 .Do BLOCK(R)
 Do:ChargeTraceID ChargeTraceID(ChargeTraceID)
 Quit
 ;
 ; Samenvattung bon
PRODSBON(R) 
 New PRNr,KortText,IdentNr,Kleur,Omschr1,Omschr2,Omschr3,KlantRef
 New Aantal,Saldo,Nr
 Set PRNr=$P(R,D,2),Aantal=$P(R,D,3),Saldo=0 If $P(R,D,23) Set Saldo=$P(R,D,23)-Aantal
 Do FETCHPR(PRNr,Taal)
 Set R=IdentNr_"`3"_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"_D_$$FN(Aantal,0)_"``63"
 If Saldo Set R=R_D_$$FN(Saldo,0)_"``78"
 Do BLOCK(R)
 Quit
 ;
 ; Order
PRODORD(R) 
 New PRNr,KortText,IdentNr,Kleur,Omschr,Omschr1,Omschr2,Omschr3,KlantRef,ProjRef,StockUpd
 New Aantal,Prijs,Korting,LevWk,Round,SpePrijs,Nr,ContrRef
 Set PRNr=$P(R,D,2),Aantal=$P(R,D,3),Omschr=$P(R,D,5),Prijs=$P(R,D,6),Korting=$P(R,D,7),ContrRef=$P(R,D,13)
 If '$L(Aantal),'Prijs Set Prijs=$P(R,D,16)
 Set StockUpd=$P(R,D,14)'["S" Set:StockUpd StockUpd=$P(R,D,14)'["Z"
 Set Round=$P(R,D,21),LevWk=$P(R,D,25),SpePrijs=$P(R,D,26)
 Set Round=$P("%\/M",D,$F("HM",$E(Round))-1)
 Do FETCHPR(PRNr,Taal)
 Set Omschr1=$E(Omschr1,1,44-$L(Kleur))
 Set R=IdentNr_"`3"_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"_D_$$FN(Aantal,0)_"``57"
 Set:'StockUpd R=R_D_"*`58"
 If $L(Round) Set R=R_D_Round_"`69"
 If $L(SpePrijs) Set R=R_D_SpePrijs_"`70"
 Set R=R_D_$$FN(Prijs,2)_"``69"_D_LevWk_"``77"
 Do BLOCK(R)
 Set R="   "_Omschr1_$J("",45-$L(Omschr1)-$L(Kleur))_Kleur_"`2`41`CT"
 If NetBrutP Set Korting=$$KORTING^DCALG(Korting),R=R_D_Korting_"``69"
 Do BLOCK(R)
 For Nr=2:1:23 Set R=$$OMSCHR^DCALG(Nr) If $L(R) Do BLOCK(R)
 Do KLANTREF("DCORD",45),PROJREF("DCORD",45)
 If $L(KlantRef) Set R="   "_KlantRef_$J("",45-$L(KlantRef))_"`2`41`CT" Do BLOCK(R)
 If $L(ContrRef) Do
 .Set ContrRef=$$CONTRREF(ContrRef,"DCORD",45)
 .Quit:ContrRef=""
 .Set R="   "_ContrRef_$J("",45-$L(ContrRef))_"`2`41`CT"
 .Do BLOCK(R)
 If $L(ProjRef) Set R="   "_ProjRef_$J("",45-$L(ProjRef))_"`2`41`CT" Do BLOCK(R)
 Quit
 ;
 ; Toelevering
PRODTOE(R) 
 New PRNr,KortText,IdentNr,Omschr1,Omschr2,Omschr3,Omschr4,Omschr5,Omschr6,IsStock
 New Aantal,Prijs,Korting,LevWk,Round,SpePrijs
 Set PRNr=$P(R,D,2),Aantal=$P(R,D,3),Prijs=$P(R,D,6),Korting=$P(R,D,7),Round=$P(R,D,21)
 Set LevWk=$P(R,D,25),SpePrijs=$P(R,D,26)
 Set Round=$P("%\/M",D,$F("HM",$E(Round))-1)
 Do FETCHPR(PRNr)
 Set Gentype = $Piece($$GENTYP^HAD(PRNr),D,1)
 If (Gentype?1(1"KAD",1"GLA",1"PRF")) Set $E(KortText,14,21) = $J("",21-14+1) // added by csc 15/10/2010
 Set R=IdentNr_"`3``"_$P("B",D,IsStock)_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"_D_$$FN(Aantal,0)_"``57"
 If $L(Round) Set R=R_D_Round_"`69"
 If $L(SpePrijs),LEVNr'=6332 Set R=R_D_SpePrijs_"`59"
 If LEVNr=6332 Set R=R_D_$$BARCODE^HAD(PRNr,"F")_"`60"
 Else  Set R=R_D_$$FN(Prijs,2)_"``69"
 Set R=R_D_LevWk_"``77"
 Do BLOCK(R)
 If 'ToelTyp Set Korting=""
 Else  Set Korting=$$KORTING^DCALG(Korting)
 If $L(LevRef) Set R=LevRef_"`17"_D_Korting_"``69",Korting="" Do BLOCK(R)
 For Nr=1:1:20 Do
 . Set R=$$OMSCHR^DCALG(Nr)
 . Quit:R=""
 . If R["dubbelwandige boxside" Set R=$P(R,"dubbelwandige boxside")_P("B",1)_"dubbelwandige boxside"_P("B",0)_$P(R,"dubbelwandige boxside",2)
 . Set R=R_"``41"_D_Korting_"``69",Korting=""
 . Do BLOCK(R)
 If $L(Korting) Set R=Korting_"``69",Korting="" Do BLOCK(R)
 Quit
 ;
 ; Offerte type detail
PRODOFFD(R) 
 New PRNr,KortText,IdentNr,Kleur,Omschr1,Omschr2,Omschr3,KlantRef
 New Aantal,Prijs,Korting,Bedrag,Round,LevTerm,Munt,Nr,GrVerp,MinAfn
 Set PRNr=$P(R,D,2),Aantal=$P(R,D,3),Prijs=$P(R,D,6),Korting=$P(R,D,7),Bedrag=$P(R,D,9),Round=$P(R,D,21)
 If '$L(Aantal),'Prijs Set Prijs=$P(R,D,16)
 Set Round=$P("%\/M",D,$F("HM",$E(Round))-1),LevTerm=$P(R,D,25),Munt=$P(R,D,22)
 If LevTerm,LevTerm>MaxWeek Set MaxWeek=LevTerm
 Do FETCHPR(PRNr,Taal)
 Set Omschr1=$E(Omschr1,1,44-$L(Kleur))
 Set GrVerp=0,R=$O(^KPR(PRNr,"J"))
 If $E(R)="J" Set R=^KPR(PRNr,R),GrVerp=$P(R,D,16)
 Set MinAfn=$P($G(^KPBI("D",KLNr,PRNr)),D,2)
 Set R=IdentNr_"`3"_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"_D_$$FN(Aantal,0)_"``51"
 If $L(Round) Do
 .If OffTyp="C",OffMunt="MTL" Quit
 .Set R=R_D_Round_"`63"
 Set R=R_D_$$FN(Prijs,2)_"``63" If OffTyp'="C",Bedrag Set R=R_D_$$FN(Bedrag,2)_"``78"
 If OffTyp="C" Do
 .If $G(^KPBI("D",KLNr,PRNr)) Set R=R_D_$$FN(^KPBI("D",KLNr,PRNr),0,"-.")_"``71"
 .Else  If LevTerm="." Set T=$$TXT^DCOFFD("Stock"),R=R_D_T_"``71",LevTerm=""
 .Set R=R_D_$$FN($S(MinAfn>GrVerp:MinAfn,1:GrVerp),0,"-.")_"``78"
 Do BLOCK(R)
 Set R="   "_Omschr1_$J("",45-$L(Omschr1)-$L(Kleur))_Kleur_"`2`41`CT"
 If OffTyp'="C"!(LevTerm=".") Do
 .Set T=LevTerm,T=$S(T=".":$$TXT^DCOFFD("Stock"),'T:"",1:T_" "_$$TXT^DCOFFD("Week")),R=R_D_T_"``50"
 If NetBrutP,OffMunt'="MTL" Set Korting=$$KORTING^DCALG(Korting),R=R_D_Korting_"``63"
 If OffMunt="MTL" Do
 .If $L(Round),OffTyp="C" Set R=R_D_Round_"`63"
 .Set R=R_D_Munt_"``"_$S(OffTyp="C":62,1:77)
 Do BLOCK(R)
 For Nr=2:1:23 Do
 .Set R=$$OMSCHR^DCALG(Nr)
 .If NetBrutP,OffMunt="MTL" Set Korting=$$KORTING^DCALG(Korting),R=R_D_Korting_"``63"
 .If $L(R) Do BLOCK(R)
 Do KLANTREF("DCOFFD",45)
 If $L(KlantRef) Set R="   "_KlantRef_$J("",45-$L(KlantRef))_"`2`41`CT" Do BLOCK(R)
 Quit
 ;
 ; Offerte type prijslijst
PRODOFFP(PRNr) 
 New KortText,IdentNr,Kleur,Omschr1,Omschr2,Omschr3,KlantRef,KSS
 New Prijs,Korting,Round,StockNSt,MinBestH,LevTerm,Munt,Nr
 Set R=$O(^KPR(PRNr,"I")) Set:$E(R)="I" R=^KPR(PRNr,R)
 If $G(TSubGrp)'=$P(R,D,3) Do
 .Set TSubGrp=$P(R,D,3),KSS=TSubGrp,R=$$FF^DD("oPKSOms"_Taal)
 .If '$L(R) Set R=$$DISPLS^KLASS(TSubGrp)
 .Set R=$C(27)_"-"_$C(1)_R_$C(27)_"-"_$C(0)_$J("",48-$L(R))_"`3`42`BUTC"
 .Do BLOCK(R),BLOCK("")
 Do FETCHPR(PRNr,Taal)
 Set Omschr1=$E(Omschr1,1,44-$L(Kleur))
 Set R=$$KLANTPR^KPRIJS(KLNr,PRNr)
 Set Prijs=$P(R,D),Munt=$P(R,D,2),Round=$P(R,D,3),Korting=$P(R,D,5,6) Set:NetBrutP Prijs=$P(R,D,4)
 Set Round=$P("%\/M",D,$F("HM",$E(Round))-1)
 Set R=^KPR(PRNr,1),StockNSt=$P(R,D,20),R=$O(^KPR(PRNr,"J")) Set:$E(R)="J" R=^KPR(PRNr,R)
 Set MinBestH="",LevTerm="." If 'StockNSt Set MinBestH=$P(R,D,6),LevTerm=$P(R,D,7)+1
 Set R=IdentNr_"`3"_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"
 Set T=LevTerm,T=$S(T=".":$$TXT^DCOFFD("Stock"),'T:"",1:T_" "_$$TXT^DCOFFD("Week")),R=R_D_T_"``51"
 Set R=R_D_$$FN(MinBestH,0)_"``61"
 If $L(Round) Set R=R_D_Round_"`77"
 Set R=R_D_$$FN(Prijs,2) Set:OffMunt="MTL" R=R_Munt_$J("",4-$L(Munt)) Set R=R_"``77"
 Do BLOCK(R)
 Set R="   "_Omschr1_$J("",45-$L(Omschr1)-$L(Kleur))_Kleur_"`2`41`CT"
 If NetBrutP Set Korting=$$KORTING^DCALG(Korting) Set:OffMunt="MTL" Korting=Korting_"   " Set R=R_D_Korting_"``77"
 Do BLOCK(R)
 For Nr=2:1:23 Set R=$$OMSCHR^DCALG(Nr) If $L(R) Do BLOCK(R)
 Do KLANTREF("DCOFFP",45)
 If $L(KlantRef) Set R="   "_KlantRef_$J("",45-$L(KlantRef))_"`2`41`CT" Do BLOCK(R)
 Do PASTEB^DCOFFP(L("B","B"),1)
 Quit
 ;
 ; Prijslijst
PRODPRSL(PRNr,SubGroep) 
 New KortText,IdentNr,Kleur,Omschr1,Omschr2,Omschr3,KlantRef,KSS,IsStock,Verpak,LevTerm,PerStuk,%PrijsV
 New Aantal,Prijs,Korting,Round,NoRound,SaRound,Munt,Pariteit,Nr,Temp,NoPrijs,SaPrijs,NoKort,SaKort,Periode
 If Prefs("SubGroep"),$G(TSubGrp)'=SubGroep Do
 .Set TSubGrp=SubGroep,KSS=TSubGrp,R=$$FF^DD("oPKSOms"_Taal)
 .If '$L(R) Set R=$$DISPLS^KLASS(TSubGrp)
 .Set R=$C(27)_"-"_$C(1)_R_$C(27)_"-"_$C(0)_$J("",48-$L(R))_"`3`42`BUTC"
 .Do BLOCK(R),BLOCK("")
 Do FETCHPR(PRNr,Taal)
 Set Omschr1=$E(Omschr1,1,44-$L(Kleur))
 If Prefs("Verpak") Do
 .Set R=^KPR(PRNr,1),IsStock=$P(R,D,20)
 .Set R="J",R=$O(^KPR(PRNr,R)) Set:$E(R)="J" R=^KPR(PRNr,R) Set PerStuk=$P(R,D,13)
 .Set Verpak=$P(R,D,14) Set:'Verpak Verpak=$P(R,D,15) Set:'Verpak Verpak=$P(R,D,16)
 .If 'Verpak!'IsStock Set Verpak=$P(R,D,6)
 .If PerStuk,IsStock Set Verpak=1
 .Set LevTerm=$P(R,D,7)+1 If IsStock Set LevTerm=1
 Set R=$$KLANTPR^KPRIJS(KLNr,PRNr,$S(Prefs("NoSa")=1:"S",1:"N"))
 Set (Prijs,NoPrijs)=$P(R,D),Munt=$P(R,D,2),Round=$P(R,D,3),NoKort=$P(R,D,5)_"#"_$P(R,D,6)
 Set:NetBrutP Prijs=$P(R,D,4)
 Set NoRound=Round
 Set Round=$P("%\/M",D,$F("HM",$E(Round))-1)
 Set R=IdentNr_"`3"_D_"*`15"_D_KortText_$S($L(KortText)<24:$J("",25-$L(KortText)),1:"")_"``41"
 If $L(Round) Set R=R_D_Round_"`59"
 Set R=R_D_$$FN(Prijs,2) Set:KlMunt="MTL" Munt=$$MUNT^vhRtn1(Munt,1),R=R_Munt_$J("",4-$L(Munt)) Set R=R_"``59"
 If Prefs("NoSa")>1!Prefs("Verpak") Do
 .If Prefs("NoSa")>1 Do  Quit
 ..Set Temp=R,R=$$KLANTPR^KPRIJS(KLNr,PRNr,"S")
 ..Set (Prijs,SaPrijs)=$P(R,D),Munt=$P(R,D,2),Round=$P(R,D,3),SaKort=$P(R,D,5)_"#"_$P(R,D,6)
 ..Set:NetBrutP Prijs=$P(R,D,4)
 ..Set SaRound=Round,Pariteit=$P(R,D,9),R=Temp
 ..Set Round=$P("%\/M",D,$F("HM",$E(Round))-1)
 ..If $L(Round) Set R=R_D_Round_"`77"
 ..Set R=R_D_$$FN(Prijs,2) Set:KlMunt="MTL" Munt=$$MUNT^vhRtn1(Munt,1),R=R_Munt_$J("",4-$L(Munt)) Set R=R_"``77"
 ..Set %PrijsV=SaPrijs/NoPrijs-1
 .Set T="" Set:'IsStock T=$$FN(LevTerm,0) Set T=T_$$TXT^DCPRYSL($S(IsStock:"Stock",1:"Week"))
 .Set R=R_D_T_"``67"
 .Set R=R_D_$$FN(Verpak,0)_"``78"
 Do BLOCK(R)
 Set R="   "_Omschr1_$J("",45-$L(Omschr1)-$L(Kleur))_Kleur_"`2`41`CT"
 If Prefs("NoSa")>1,Prefs("%Met"),%PrijsV,'NetBrutP Set R=R_D_$$FN(%PrijsV,1,"+%")_"%"_"``77"
 If NetBrutP Do
 .Set Korting=$$KORTING^DCALG(NoKort),R=R_D_Korting_"``59"
 .If Prefs("NoSa")>1 Set Korting=$$KORTING^DCALG(SaKort),R=R_D_Korting_"``77"
 Do BLOCK(R)
 For Nr=2:1:23 Do  If $L(R) Do BLOCK(R)
 .Set R=$$OMSCHR^DCALG(Nr)
 .If Nr=2,Prefs("NoSa")>1,Prefs("%Met"),%PrijsV,NetBrutP Set R=R_D_$$FN(%PrijsV,1,"+%")_"%"_"``77"
 Do KLANTREF("DCPRYSL",45)
 If $L(KlantRef) Set R="   "_KlantRef_$J("",45-$L(KlantRef))_"`2`41`CT" Do BLOCK(R)
 If Prefs("NoSa")=3 Do
 .Set NoRound=$P("1\100\1000",D,$F("EHM",$E(NoRound))-1),SaRound=$P("1\100\1000",D,$F("EHM",$E(SaRound))-1)
 .Set R=^KSTKL(KLNr,PRNr,0),Aantal=$P(R,D,9)
 .If 'Aantal Do
 ..Set Periode=$O(^KSTKL(KLNr,PRNr,Prefs("Periode","Begin")),-1)
 ..For  Set Periode=$O(^KSTKL(KLNr,PRNr,Periode)) Quit:Periode=""!(Periode]Prefs("Periode","Einde"))  Do
 ...Set R=^KSTKL(KLNr,PRNr,Periode),Aantal=Aantal+$P(R,D)
 .Set TotOmzH=TotOmzH+$J(NoPrijs*Aantal*Pariteit/NoRound,0,0)
 .Set TotOmzS=TotOmzS+$J(SaPrijs*Aantal*Pariteit/SaRound,0,0)
 Quit
 ;
KLANTREF(Program,Length) 
 New R,PAKNr,Reeks
 Set KlantRef="",PAKNr=""
 For  Set PAKNr=$O(^PAKKET("IP",PRNr,KLNr,PAKNr)) Quit:PAKNr=""  Do
 .Quit:$P($G(^PAKKET("D",PAKNr),D_D_"D"),D,3)="D"
 .Set KlantRef=KlantRef_" & "_$P(^PAKKET("D",PAKNr),D,2)
 If '$L(KlantRef) Do
 .Set R=$O(^KPR(PRNr,"J"))
 .Quit:$E(R)'="J"
 .Set R=^KPR(PRNr,R)
 .If $P(R,D)'=6092,$P(R,D)'=6428 Quit
 .Set Reeks=$P($P(R,D,3),"-")
 .Quit:Reeks=""
 .Set KlantRef=$G(^FOLTEC("R",KLNr,Reeks)) Set:$L(KlantRef) KlantRef="   "_KlantRef
 Quit:'$L(KlantRef)
 Set R="Set R=$$TXT^"_Program_"(""KlRef"")"
 Xecute R
 Set:$L(R) R=R_": " Set KlantRef=$E(R_$E(KlantRef,4,99),1,Length)
 Quit
 ;
CONTRREF(ContrRef,Program,Length) 
 New R,X
 Set X=$$UPCASE^vhRtn1(ContrRef)
 If X'["CONTRACT",X'["CONTRAT"
 Else  Do
 .If X["CONTRACT" Set X=$P(X,"CONTRACT",2)
 .If X["CONTRAT" Set X=$P(X,"CONTRAT",2)
 .Set R="Set R=$$TXT^"_Program_"(""Contr"")"
 .Xecute R
 .Set:$L(R) ContrRef=R_X
 Quit $E(ContrRef,1,Length)
 ;
PROJREF(Program,Length) 
 New R,PAKNr,Reeks
 Set ProjRef=Omschr
 Quit:'$L(ProjRef)
 Set R="Set R=$$TXT^"_Program_"(""ProjRef"")"
 Xecute R
 Set ProjRef=$E(R_": "_ProjRef,1,Length)
 Quit
 ;
 ; Afdrukken van de serienummers via het ChargeTraceID
ChargeTraceID(ChargeTraceID)
 New T,ResultSet,Status,ChargePRNr,ChargeID,ChargeAantal,ChargeName,TCharge
 Set ResultSet=##class(%ResultSet).%New("ProdHist.ChargeTrace:QListChargeIDs")
 Set Status=ResultSet.Execute($LB(ChargeTraceID)),TCharge=""
 For  Quit:('ResultSet.Next())  Do
 .Set ChargePRNr=ResultSet.Data("ProductNr"),ChargeID=ResultSet.Data("ChargeID"),ChargeAantal=ResultSet.Data("Qty")
 .Set ChargeName=$G(^RES("CHARGETRACEID","PI","PRNR","D",ChargePRNr,Taal))
 .Set T=$$TXT("Serie")_$S($L(ChargeName):" ",1:"")_$$LOCASE^vhRtn1(ChargeName)
 .If T=TCharge Set T=""
 .Else  Set TCharge=T
 .Set R=$J($S($L(T):": ",1:"  ")_ChargeID_" - "_$J(ChargeAantal,3)_" "_$$TXT("Stuk"),45)
 .Set $E(R,1,$L(T))=T,R="   "_R_"`2`41`CT"
 .Do BLOCK(R)
 Quit
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TSerie ;Serienr\No de serie\Chargennr\Serial Nbr
TStuk ;st\pc\st\pc