FLOWTOE4 ;Selecteren van een toelevering en het afdrukken van de palletlabels [ 04/26/2002  2:33 PM ]
 
 Set K="AFDRUKKEN PALLETETIKETTEN "_QN_" ",FP=203+$L(K)
 Write @F61,@F11,@F1,@F,@F5
 Set FP=202
 Write @F,@F4,K,@F5
 Do INIT^vhPRINTER("","","UB")
 Set Dev=$G(Print("DEV"))
 Do:$L(Dev)
 .New C,Derde,LEVNr,TOENr
 .Set LEVNr=$$SELECT^LEVER(1,6092)
 .If LEVNr Do
 ..Set Derde("L")=LEVNr,Derde("N")=1
 ..For  Set TOENr=$$SELECT^FLOW("KTO","KTO1",1,,.Derde) Quit:TOENr="-"  Do PRINT(TOENr)
 Quit
 
FETCHTOE(TOENr,C) 
 New R,LEVNr,KLNr,ORDNr,Adr
 Set LEVNr=$P(^KTO1(TOENr),D)
 Set R=^KTO(LEVNr,TOENr,1)
 Set C("LEVREF")=$P(R,D,10),ORDNr=$P(R,D,7),KLNr=$P(R,D,8)
 Quit:ORDNr=""
 Set C("ORDNR")=ORDNr
 Quit:KLNr=""
 Set C("ORDREF")=$P($G(^KOD(KLNr,"F",ORDNr,1)),D,3)
 Set Adr=$G(^KOD(KLNr,"F",ORDNr,3))
 Set:$L($TR(Adr,"\",""))<5 Adr=^KKL(^KK1(KLNr),0)
 Set C("KLNM")=$P(Adr,D,2)
 Set C("TOENM")=$P(Adr,D,3)
 Set C("STRAAT")=$P(Adr,D,5)
 Set C("POSTKODE")=$P(Adr,D,6)
 Set C("GEMEENTE")=$E($P(Adr,D,7),1,18)
 Set C("TAAL")=$P(^KKL(^KK1(KLNr),0),D,9)
 Quit
 
WLABEL(Dev,C) 
 For I=1:1 Set Lijn=$T(@("L"_$G(C("TAAL"),"N")_I)) Quit:Lijn=""  Do
 .Write @$P(Lijn,";",2),!
 Quit
 
PRINT(TOENr,Extern) 
 New C
 Set Extern=$G(Extern)
 If 'Extern Do STORE^vhTERMINA() Set FP=2001 Write @F,@F1,!?2,"Printing ..."
 Open Dev
 Use Dev
 For  Do  Quit:TOENr=""
 .If $P(TOENr,D) Do
 ..Do FETCHTOE($P(TOENr,D),.C)
 ..Do WLABEL(Dev,.C)
 .Set TOENr=$P(TOENr,D,2,99)
 Close:$L(Dev) Dev
 Do:'Extern REFRESH^vhTERMINA()
 Quit
 
EXTERN(TOENr,Dev) 
 New C
 Set:'$L($G(Dev)) Dev=$$DEV^vhPRINTER("lbl Uitvoer EWMS") ; Device labelprinter : \\REQ DATKON\Generic / Text Only 
 Do PRINT(TOENr,1)
 Quit
 
 ; Label definitie NEDERLANDS
LN1 ;"ON"
LN2 ;"ZT"
LN3 ;"N"
LN4 ;"R100,0"
LN5 ;"A640,50,1,2,2,2,N,""KLANT"""
LN6 ;"A525,50,1,3,2,2,N,""",$G(C("KLNM")),""""
LN7 ;"A465,50,1,2,2,2,N,""",$G(C("TOENM")),""""
LN8 ;"A410,50,1,2,2,2,N,""",$G(C("STRAAT")),""""
LN9 ;"A355,50,1,2,2,2,N,""",$G(C("POSTKODE")),""""
LN10 ;"A355,325,1,2,2,2,N,""",$G(C("GEMEENTE")),""""
LN11 ;"A215,50,1,1,2,2,N,""Ordernr:"""
LN12 ;"A215,260,1,1,2,2,N,""",$S($L($G(C("ORDNR"))):$E(C("ORDNR"),1,3)_"."_$E(C("ORDNR"),4,6),1:""),$S($L($G(C("LEVREF"))):" ("_C("LEVREF")_")",1:""),""""
LN13 ;"A160,50,1,1,2,2,N,""Uw ref:"""
LN14 ;"A160,260,1,1,2,2,N,""",$G(C("ORDREF")),""""
LN15 ;"A100,50,1,5,2,2,N,""",$E($G(C("KLNM")),1,10),""""
LN16 ;"P1"
 ; Label definitie FRANS
LF1 ;"ON"
LF2 ;"ZT"
LF3 ;"N"
LF4 ;"R100,0"
LF5 ;"A640,50,1,2,2,2,N,""CLIENT"""
LF6 ;"A525,50,1,3,2,2,N,""",$G(C("KLNM")),"""" ; Klantnaam
LF7 ;"A465,50,1,2,2,2,N,""",$G(C("TOENM")),""""
LF8 ;"A410,50,1,2,2,2,N,""",$G(C("STRAAT")),""""
LF9 ;"A355,50,1,2,2,2,N,""",$G(C("POSTKODE")),""""
LF10 ;"A355,325,1,2,2,2,N,""",$G(C("GEMEENTE")),""""
LF11 ;"A215,50,1,1,2,2,N,""No d'ordre:"""
LF12 ;"A215,300,1,1,2,2,N,""",$S($L($G(C("ORDNR"))):$E(C("ORDNR"),1,3)_"."_$E(C("ORDNR"),4,6),1:""),$S($L($G(C("LEVREF"))):" ("_C("LEVREF")_")",1:""),""""
LF13 ;"A160,50,1,1,2,2,N,""Votre ref:"""
LF14 ;"A160,300,1,1,2,2,N,""",$G(C("ORDREF")),""""
LF15 ;"A100,50,1,5,2,2,N,""",$E($G(C("KLNM")),1,10),""""
LF16 ;"P1"