KLANT6 ;KLANTEN [ 11/26/2003  3:56 PM ]
 ;
SELECT(IsAkt,DefInp,Titel) 
 New X,Y,Tekst,KLNr,Kl,TKl,DefKL,Count,IsVTW,ECToegang,blECToegang,derdeECToegang
 Set IsAkt=$G(IsAkt),IsVTW=$G(sScr("VTW"),$$IsVTWExtern^vhUSER),ECToegang=$$GetECToegang^vhUSER()
 If IsVTW,$LI(ECToegang) Set blECToegang=##Class(BL.EC.Toegang).%New(),derdeECToegang=##Class(Derde.EC.Toegang).%OpenId($LI(ECToegang))
 Set DefInp=$G(DefInp)
 Set:'$L($G(DefKL)) DefKL=$G(sRef("KL"))
 If $L(DefKL),'$D(^KK1(DefKL)) Set DefKL=""
 If DefKL,'$$CHECK(DefKL,IsAkt) Set DefKL=""
 If '$L($G(Titel)) Set Titel="Klant : "
 Do ADD^vhScherm(21,24)
 Set KLNr=""
 Set:$L(DefInp) Kl=DefInp
SEL2 Set:'$L(DefInp) Kl=$$ASK^vhINP(Titel,20,"","Ingave klant dmv. naam of nummer")
 Set DefInp=""
 Quit:Kl="-"!(Kl=".") Kl
 Set Kl=$$UPTRIMAN^vhRtn1(Kl)
 If Kl=""!zb Do LIST("") Goto SEL2:'KLNr,EXIT
 If Kl?4.5N,$D(^KK1(Kl)) Set KLNr=Kl Goto EXIT:$$CHECK(Kl,IsAkt) Set KLNr="" Goto SEL2
 Set TKl=$O(^KKL(Kl))
 If $E(TKl,1,$L(Kl))'=Kl Goto SEL2
 If $E($O(^KKL(TKl)),1,$L(Kl))'=Kl Set KLNr=+^KKL(TKl,0) Goto EXIT:$$CHECK(KLNr,IsAkt) Set KLNr="" Goto SEL2
 Do LIST(Kl)
 Goto SEL2:'KLNr,EXIT
EXIT Quit KLNr
 
CHECK(KLNr,IsAkt) 
 Quit:'$D(^KK1(KLNr)) 0
 Quit:$P(^KKL(^KK1(KLNr),0),"\",30)=2 0
 If $G(IsVTW),$IsObject($G(blECToegang)),$IsObject($G(derdeECToegang)),'blECToegang.CheckKlant(KLNr,derdeECToegang) Quit 0
 Quit:'IsAkt 1
 Quit '$P(^KKL(^KK1(KLNr),2),"\",10) 
 
LIST(Kode)
 New Y,X,Fetch,LD
 Set TKl=Kl
 Do:$L(Kode) FETCH(Kode)
 Set TKl=""
 If '$L(Kl)  Set Kl="ZZZZZ"
 X "Set Y(0)=$$MORE(0,3)"
 Do:Y(0)
 . Do INIT^vhLIST("KLANT","SELECT",.LD),WRITE^vhLIST(.LD)
 . For  Set X=$$SCROLL^vhLIST(.LD) Set:"\ENTER\ \"[(D_X_D) X=LD("SELECT") Quit:X="K"  Quit:X="-"  Quit:X="."  If X,$G(Y(X)) Set KLNr=Y(X) Quit
 Quit
 
FETCH(Kode) 
 New IsComAct,IsDealer
 For  Set TKl=$O(^KKL(TKl)) Quit:TKl=""!($E(TKl,1,$L(Kl))'=Kl)  Do
 . Quit:'$$CHECK($P(TKl," ",2),IsAkt)
 . Set IsComAct=+$P(^KKL(TKl,2),D,10),IsDealer=$P(^KKL(TKl,1),D,11)="DEALER"
 . Set Fetch($P(TKl," ")_IsComAct_IsDealer_" "_$P(TKl," ",2))=TKl
 Quit
 
MORE(Max,Len,Ref) 
 ;If Max>200 w *7 Quit Max
 Set Count=0
 If Max,TKl="" Quit Max
 For  Set TKl=$O(Fetch(TKl)) Quit:TKl=""  Set Count=Count+1,Y(Max+Count)=$P(Fetch(TKl)," ",2) Quit:Count>Len
 Set:$E(TKl,1,$L(Kl))'=Kl TKl=""
 Quit Max+Count