KLOPV ;KLANTENOPVOLGING [ 02/27/2003  4:53 PM ]
 ;
OFFERTE 
 Do REGIO^OFFOPV
 Quit
 ;
ORDER 
 Do REGIO^RPLKOM
 Quit
 ;
KLACHT(KLNr) 
 Do KLANT^KLACHTO($G(KLNr))
 Quit
 ;
REGIO(UserId,Titel) 
 New I,R,Labels,Regios,Regio,AllRegio,Count,CB,zb,HalType
 Set Titel=$G(Titel)
 Set R=$G(^vhUSER("D",UserId,"M")),Labels=$P(R,D),(Regio,Regios)=""
 For  Set Regio=$O(^RES("KLANT","PI","REGIO","D",Regio)) Quit:Regio=""  Do
 .Set R=^RES("KLANT","PI","REGIO","D",Regio),Count=$P(R,"`")+2,Regio(Count)=Regio_"`"_$P(R,"`",2,9)
 .If $L($P(R,"`",5)),";"_Labels_";"[(";"_$P(R,"`",5)_";") Set Regios=Regios_";"_Regio
 Set Regio(1)="A`Alles",Regio(2)="&S"
 Set AllRegio=""
 For Count=3:1 Quit:'$D(Regio(Count))  Set AllRegio=AllRegio_";"_$P(Regio(Count),"`")
 Set Count=Count+1,Regio(Count)="&S"
 Set Count=Count+1,Regio(Count)="D`Deuren"
 Set HalType=""
 For  Set HalType=$O(^RES("KLOPV","PI","HALUX","D",HalType)) Quit:HalType=""  Do
 .Set R=^RES("KLOPV","PI","HALUX","D",HalType),HalType($P(R,"`"))=HalType_"`"_$P(R,"`",2)
 For I=1:1 Quit:'$D(HalType(I))  Set Count=Count+1,Regio(Count)=HalType(I)
 Set $E(Regios)="",$E(AllRegio)=""
 If Regios="",UserId=54 Set Regios="H"
 Set:Regios="" Regios="A"
 Set CB("S")="D`CB^KLOPV"
 Set Regios=$$WILD^vhPOPUP("C;C","-KOM1",Titel,.Regio,Regios,.CB)
 Set:Regios[AllRegio Regios="A"
 Set:zb="CANC" Regios=""
 For I=1:1:$L(Regios,";") If $P(Regios,";",I)="A" Set Regios="A" Quit         
 Quit Regios
 ;
CB(Select,Old,New,Rec) 
 If New,$P(Rec,"`")="A" Set zb="ENTER"
 If New,$P(Rec,"`")'="A" Kill sX(1)
 If New,$P(Rec,"`")="H" For sY=1:1:sY If $E(sY(sY))="H",$L($P(sY(sY),"`"))>1 Kill sX(sY)
 If New,$E($P(Rec,"`"))="H",$L($P(Rec,"`"))>1 For sY=1:1:sY If $P(sY(sY),"`")="H" Kill sX(sY)
 Quit
 ;
 ; Vertaald, zie USERNAME^vhUSER
INTVW(KLNr,IntVw,Vertaald) 
 New R,KlKey,IntKey,Regio,UserId
 If KLNr,$D(^KK1(KLNr)) Do
 .Set KlKey=^KK1(KLNr),R=^KKL(KlKey,0),Regio=$P(R,D,20),IntVw=$G(IntVw,$P(R,D,22))
 .If 'IntVw,$L(Regio) Do
 ..Set R=$G(^RES("KLANT","PI","REGIO","D",Regio)),IntKey=$P(R,"`",5)
 ..Quit:IntKey=""
 ..Set UserId=""
 ..For  Set UserId=$O(^vhUSER("D",UserId)) Quit:UserId=""  Do
 ...Set R=$G(^vhUSER("D",UserId,"M"))
 ...Quit:";"_$P(R,D)_";"'[(";"_IntKey_";")
 ...Set IntVw=IntVw_";"_UserId
 ..Set $E(IntVw)=""
 If $L($G(IntVw)),$L($G(Vertaald)) Set IntVw=$$USERNAME^vhUSER(IntVw,Vertaald)
 Quit $G(IntVw)
 ;
 ; Vertaald, zie USERNAME^vhUSER
 ; IntExt - "I" = intern (default), "E" = extern
REGIOVW(Regio,RegioVw,Vertaald,IntExt) 
 New R,IntKey,UserId
 Set Regio=$G(Regio),RegioVw=$G(RegioVw),IntExt=$G(IntExt,"I")
 If 'RegioVw,$L(Regio) Do
 .Set R=$G(^RES("KLANT","PI","REGIO","D",Regio))
 .If IntExt'="I" Set RegioVw=$P(R,"`",15) Quit
 .Set IntKey=$P(R,"`",5)
 .Quit:IntKey=""
 .Set UserId=""
 .For  Set UserId=$O(^vhUSER("D",UserId)) Quit:UserId=""  Do
 ..Set R=$G(^vhUSER("D",UserId,"M"))
 ..Quit:";"_$P(R,D)_";"'[(";"_IntKey_";")
 ..Set RegioVw=RegioVw_";"_UserId
 .Set $E(RegioVw)=""
 If $L($G(RegioVw)),$L($G(Vertaald)) Set RegioVw=$$USERNAME^vhUSER(RegioVw,Vertaald)
 Quit $G(RegioVw)
 ;
 ; Vertaald, zie USERNAME^vhUSER
EXTVW(KLNr,ExtVw,Vertaald) 
 New R,KlKey,Regio
 If KLNr,$D(^KK1(KLNr)) Do
 .Set KlKey=^KK1(KLNr),R=^KKL(KlKey,0),Regio=$P(R,D,20),ExtVw=$G(ExtVw,$P(R,D,26))
 .If 'ExtVw,$L(Regio) Set R=$G(^RES("KLANT","PI","REGIO","D",Regio)),ExtVw=$P(R,"`",15)
 If $L($G(ExtVw)),$L($G(Vertaald)) Set ExtVw=$$USERNAME^vhUSER(ExtVw,Vertaald)
 Quit $G(ExtVw)
 ;
 ; Vertaald, zie USERNAME^vhUSER
BOEKHVW(KLNr,BoekhVw,Vertaald) 
 New R,KlKey,Regio
 If KLNr,$D(^KK1(KLNr)) Do
 .Set KlKey=^KK1(KLNr),R=^KKL(KlKey,0),Regio=$P(R,D,20),BoekhVw=$G(BoekhVw)
 .If 'BoekhVw,$L(Regio) Set R=$G(^RES("KLANT","PI","REGIO","D",Regio)),BoekhVw=$P(R,"`",19)
 If $L($G(BoekhVw)),$L($G(Vertaald)) Set BoekhVw=$$USERNAME^vhUSER(BoekhVw,Vertaald)
 Quit $G(BoekhVw)
 ;
MailNewCust(KLNr)
 New FromUser,UserNaam,ExtVw,From,To,Status,Subject,Body,Data
 Set FromUser=$$DEVUSER^vhUSER(),ExtVw=$$EXTVW(KLNr)
 Set From=$P($$USERNAME^vhUSER(FromUser,"@"),";"),UserNaam=$P($$USERNAME^vhUSER(FromUser,1),";")
 Set To=$$REPLACE^vhRtn1($$USERNAME^vhUSER(ExtVw,"@"),";",""",""")
 Xecute "Set To=$LB("""_To_""")"
 If From'=To,$ZU(5)'["DEV" Do
 .Do FETCHKL^UTILI(KLNr,"Data")
 .Set Subject="Nieuwe klant "_$P(Data(0),D,2) Set:$L($P(Data(0),D,4)) Subject=Subject_" "_$P(Data(0),D,4)
 .Set Body="Volgende klant werd aangemaakt:"_$C(13)_$C(13)_$P(Data(0),D)_$C(13)
 .Set:$L($P(Data(0),D,4)) Body=Body_$P(Data(0),D,4)_" "
 .Set Body=Body_$P(Data(0),D,2)
 .Set:$L($P(Data(0),D,3)) Body=Body_$C(13)_$P(Data(0),D,3)
 .Set Body=Body_$C(13)_$P(Data(0),D,5)_$C(13)_$P(Data(0),D,6)_"   "_$P(Data(0),D,7)
 .Set Body=Body_$C(13)_$$LAND^vhRtn1($P(Data(0),D,8),2)_$C(13)_$P(Data(0),D,13)
 .Do:$L($P(Data(3),D,15))
 ..Set Body=Body_$C(13)_$C(13)_"Reden: "_$S($D(^RES("KLANT","PI","REDEN","D",$P(Data(3),D,15))):$P(^RES("KLANT","PI","REDEN","D",$P(Data(3),D,15)),"`",2),1:$P(Data(3),D,15))
 .Set Body=Body_$C(13)_$C(13)_$C(13)_UserNaam
 .Set Status=$$SendMiniMail^vhLib(From,To,Subject,Body)
 Quit
 ;
EMailGroep(KLNr,EMailGroep)
 New TUserId,IsHandel
 Set:$G(EMailGroep)="" EMailGroep="EMAILKLOPV"
 Set TUserId=$$INTVW(KLNr,,-1)
 Do:TUserId=""!'$D(^vhUSER("S",EMailGroep_TUserId))
 . Set IsHandel=$$IsHandel^KLANT5(KLNr),TUserId=""
 . Set:IsHandel&&$D(^vhUSER("S",EMailGroep_"KH")) TUserId="KH"
 . If TUserId'="KH",$$ISKLANT^KS(KLNr),$D(^vhUSER("S",EMailGroep_"KH")) Set TUserId="KH"
 Set EMailGroep=EMailGroep_TUserId
 Quit EMailGroep