KOKO1 ;OVERZICHT KONTRACTORDERS ;[ 02/20/97  4:05 PM ]
 ;
 Write @F61,@F11,@F1
 Set FP=202
 Write @F,@F4,$P($T(+1),";",2),@F5
 Set SELK=0
 Do KP^KSEL
 Quit:K="-"
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set (Count,vCount,sCount)=0,FP=2001
 Write @F,@F1
 For  Set KL=$O(^KKL(KL)) Quit:KL=""  Quit:KL]KLX  Do
 .Set KLNr=$P(^KKL(KL,0),D),(ORDNr,Contr)="",vCount=vCount+1
 .Do:'(vCount#100) VERWERKT^KLANT(vCount,sCount)
 .For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:'ORDNr  Do  Quit:Contr="C"
 ..Set Contr=$P(^KOD(KLNr,"F",ORDNr,1),D,25)
 .Quit:Contr'="C"
 .Set ORDNr="",sCount=sCount+1
 .For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:'ORDNr  Do
 ..Set Contr=$P(^KOD(KLNr,"F",ORDNr,1),D,25),OLNr=100
 ..For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:'OLNr  Do
 ...Set R=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(R,D,2)
 ...Quit:'PRNr
 ...Set Aantal=$P(R,D,3),LevTerm=$P(R,D,25),TOENr=$P(R,D,27),R=$G(^HULP(%J,"CUMUL","PRNR",PRNr))
 ...Set:LevTerm LevTerm=$$INTDATE^vhDTyp(LevTerm,"DW")
 ...Set Verval=0 Set:Contr="C" Verval=$$CALCDATE^vhDTyp(LevTerm,"W","FD")<$H
 ...Set $P(R,D,Contr'="C"+1)=$P(R,D,Contr'="C"+1)+Aantal,$P(R,D,3)=$P(R,D,3)+$S(TOENr:Aantal,1:0)
 ...Set $P(R,D,4)=$P(R,D,4) Set:Verval $P(R,D,4)=1 Set ^HULP(%J,"CUMUL","PRNR",PRNr)=R
 .Set PRNr=""
 .For  Set PRNr=$O(^HULP(%J,"CUMUL","PRNR",PRNr)) Quit:PRNr=""  Do
 ..Set R=^HULP(%J,"CUMUL","PRNR",PRNr)
 ..Quit:'$P(R,D)
 ..Set SortKey=$$SORTKEY^PRODUKT(PRNr)
 ..Set ^HULP(%J,"CUMUL","SORTKEY",SortKey)=PRNr_D_R
 .Set SortKey="",R=D_$P(^KKL(KL,0),D,1,2)
 .For  Set SortKey=$O(^HULP(%J,"CUMUL","SORTKEY",SortKey)) Quit:SortKey=""  Do
 ..Set PRNr=$P(^HULP(%J,"CUMUL","SORTKEY",SortKey),D),$P(R,D,4,99)=""
 ..Set $P(R,D,11)=PRNr,$P(R,D,12)=$P(^KPR(PRNr,0),D),$P(R,D,31,34)=$P(^HULP(%J,"CUMUL","SORTKEY",SortKey),D,2,5)
 ..Set FysStock=$P(^KPR(PRNr,0),D,14),IsStock=$P(^KPR(PRNr,1),D,20)
 ..Set $P(R,D,35,36)=$P($G(^KPBI("D",KLNr,PRNr)),D,1,2),$P(R,D,37)=FysStock
 ..Set $P(R,D,38)=$P(R,D,37)+$P(R,D,33)-($P(R,D,31)+$P(R,D,32))
 ..If IsStock,$P(R,D,38)'=0 Set $P(R,D,38)="Stock "
 ..Set Count=Count+1,^HULP(%J,Count)=R,$P(R,D,1,3)="\\"
 .Set $P(^HULP(%J,Count),D)=1
 .Kill ^HULP(%J,"CUMUL")
 Do:$D(^HULP(%J))
 .Set $P(^HULP(%J,Count),D)=""
 .Do INIT^PROC("KOKO1")
 .Do ^OUTPUT("MTPS")
 Kill ^HULP(%J)
 Quit
 ;
CB(Ref) 
 New Rec
 Quit:$E(Ref,1,5)'="^HULP" ""
 Set Rec=@Ref
 Quit $S($L($P(Rec,D)):"\BR",1:"")
 ;