PAKKETI ;Importeren van PAKKET gegevens; [ 08/07/2002   3:45 PM ]
 ;
 Do STORE^vhTERMINA()
 If $P(^cLOG(boot,"DEV",$$IO^cQ5),D)="MC" Do
 .Set FP=2301 Write @F,@F1
 .Set FP=2401 Write @F,"H: HostFileSystem, [] : File transfer"
 .Set FP=2301 Write @F,*7,*7,"Transfer via HostFileSystem (floppy) of via FileTransfer (Mac240)"
 .Kill IK Do IK^PROC1 Quit:R="-"
 .Set TransW=$S(R="H":"H",1:"")
 Else  Do
 .Set FP=2301 Write @F,@F1
 .Set FP=2401 Write @F,"- : Exit"
 .Set FP=2301 Write @F,*7,"De transfer dient te geschieden via floppy (Druk een toets in)"
 .Kill IK Do IK^PROC1 Quit:R="-"
 .Set TransW="H"
 If R'="-" Do
 .If '$D(^HULP(%J)) Set R="B" Quit
 .Set FP=2301 Write @F,@F1
 .Set FP=2401 Write @F,"V : Verwijderen, B of [] : Behouden"
 .Set FP=2301 Write @F,"De reeds geimporteerde records bewaren of verwijderen :"
 .Kill IK Do IK^PROC1 Quit:R="-"
 Set:R="ENTER" R="B"
 Do REFRESH^vhTERMINA()
 If R'="V",R'="B" Quit
 Set VB=R
 If R="V" Do
 .Kill ^HULP(%J)
 .Set sS("MOD")=1,(@DL(1)@(6),@DL(1)@(7))=1,@DL(1)@(9)=0
 .Do WL^PROC
 Do STORE^vhTERMINA()
 Do HFSTR:TransW="H",FILETR:TransW=""
 If '$D(Dev) Do REFRESH^vhTERMINA() Quit
 Set RecNr=0
 Use 0
 Do DISPLAY^vhScherm("PAKKETIMP")
NEXTREC Use Dev Read Inp:30
 Goto:'$TEST!(Inp="") END
 If TransW="" Use 0 Write $C(13)
 Set RecNr=RecNr+1
 Set ^HULP(%J,"IMPORT",RecNr)=Inp
 If TransW="H",$S(RecNr<500:'(RecNr#10),1:'(RecNr#100)) Use 0 Set FP=1518 W @F,RecNr
 Goto NEXTREC
END Close:TransW="H" Dev
 Use 0
 Do DISPLAY^vhScherm("PAKKETIMP","","","","1;2;3;4;5")
 Set Pieces=$$PI^vhPOPUP("15;29","BOSM1-","Definitie van de velden","PAKKET","IMPORT")
 Set Pieces=$TR(Pieces,U,""),PPiece=$F(Pieces,"I") Set:'PPiece PPiece=$F(Pieces,"K")
 Set RPiece=$F(Pieces,"R"),APiece=$F(Pieces,"A")
 Do REFRESH^vhTERMINA()
 If PPiece,RPiece Do
 .Set PPiece=PPiece-1,RPiece=RPiece-1,APiece=$S(APiece:APiece-1,1:$L(Pieces)+1)
 .Set RecNr=0
 .For  Set RecNr=$O(^HULP(%J,"IMPORT",RecNr)) Quit:'RecNr  Do
 ..Set Rec=^HULP(%J,"IMPORT",RecNr)
 ..Quit:$P(Rec,$C(9),PPiece)=""!($P(Rec,$C(9),RPiece)="")
 ..Set PRNr=$$PRNR($P(Rec,$C(9),PPiece))
 ..Quit:'PRNr
 ..Set KlantRef=$P(Rec,$C(9),RPiece),Aantal=$P(Rec,$C(9),APiece) Set:'Aantal Aantal=1
 ..Set PAKNr=$$NEXTID^PAKKET()
 ..Set Rec=KLNr_D_KlantRef_D_"E\\",^HULP(%J,"D",PAKNr)=Rec
 ..Set ^HULP(%J,"IN",$$UPTRIMAN^vhRtn1(KlantRef))=PAKNr
 ..Do NIEUWV^PROC3(PAKNr_D)
 ..Set ^HULP(%J,"D",PAKNr,PRNr)=Aantal_"\\"
 ..Set ^HULP(%J,"IP",PRNr,PAKNr)=""
 ..Do APPENDV^PROC3(PAKNr_D_PRNr)
 .Set sS("MOD")=1
 Kill ^HULP(%J,"IMPORT")
 Do RESET^vhScherm
 Quit
PRNR(KortTxt) 
 New PRNr
 Do STORE^vhTERMINA()
 Set FP=1901
 Write @F,@F1,!,"Produkt : ",KortTxt
 Set PRNr=$$SELECT^PRODUKT6("","",$E(KortTxt,1,11))
 Do REFRESH^vhTERMINA()
 Quit PRNr
HFSTR Set FP=2201 Write @F,@F1,"Ingave het te importeren bestand"
 ;Set FP=2401 Write @F,"Voorbeeld 'A:\IMPORT.TXT'"
 ;Set FP=2301 Write @F,"Pad en filename : "
 ;R K If K="" Goto HFSTR
 ;If K="-" Kill Dev Quit
 ;Set Dev=51 Open Dev:(K):0 Else  K Dev Goto HFSTR
 Set Dev=$$OPEN^vhDEV(,"Pakket.Txt","R","A")
 Quit
FILETR 
 Set FP=1801 Write @F,"Na de boodschap ""Bezig met transfert"", onmiddellijk de file doorsturen"
 Set FP=1901 Write @F,"dit door middel van ""Send File"" van het Session menu"
 Set FP=2301 Write @F,@F1,"Klaar om het bestand te transferen : "
 Set FP=2401 Write @F,"[] voor transfert en - voor annuleer"
 Kill IK Do IK^PROC1 Quit:R="-"
 Write @F11,@F1,@FS132
 Write @FMTI," VAN HOECKE : Importeren van bestand ",@FMTi
 Set FP=801 Write @F,"Tijdens het overstruren van de gegevens verschijnt er een 'Send File' venster"
 Set FP=901 Write @F,"die het verloop aanduidt van het oversturen"
 Set FP=1101 Write @F,"Als het 'Send File' venster is verdwenen en"
 Set FP=1201 Write @F,"de lijst met berichten komt niet op scherm,"
 Set FP=1301 Write @F,"druk dan een of twee keer op de <Enter>-toets"
 Set FP=1524 Write @FSC
 Set Dev=$I 
 Quit