PRMAIL ;Nakijken of er nieuwe produkten werden geopend. De nieuwe produkten worden verzameld in één mail bericht. [ 01/09/2003  8:49 AM ]
DAG Goto GET
 
 ; Nachtelijk nakijken
NIGHT Set $ZT="^cA406",Q="K" Do ^cA604
 Goto GET
 
 ; Ophalen nieuwe produkten en sorteren volgens Stock en SortKey
GET 
 New MailId
 Kill List
 Set (CntS,CntNS,CntB)=0
 For PRNr=^KPR(0,"MAILCNT"):1:^KPR(0,1)-1 Do:$D(^KPR(PRNr))
 .Set Stock=$P(^KPR(PRNr,1),D,20)
 .Set Type=$S(Stock:1,1:2)
 .If $D(^KPR(PRNr,"J5810")) Set Type=3 ;Burbidge produkten worden niet gelijst
 .If $P(^KPR(PRNr,0),D,3)?4.7N Set Type=3  ;Afgeleide producten niet
 .Set List(Type)=$G(List(Type))+1
 .Set:Type'=3 List($S(Stock:1,1:2),$$SORTKEY^PRODUKT(PRNr))=PRNr
 Set ^KPR(0,"MAILCNT")=^KPR(0,1) ; Reset
 Quit:'$D(List)  ; Geen produkten gevonden
 ; Omzetten naar tekst
 Set Type="",Sort=""
 Set Cnt=0
 For  Set Type=$O(List(Type)) Quit:Type=""  Do
 .Set:Cnt Cnt=Cnt+1,Txt(Cnt)="~"
 .Set Cnt=Cnt+1,Txt(Cnt)="ŞB"_$S(Type=1:"Stock",Type=2:"NIET-Stock",1:"Afgeleide")_" produktenŞb : "_List(Type)_"~"
 .For  Set Sort=$O(List(Type,Sort)) Quit:Sort=""  Do
 ..Set PRNr=List(Type,Sort)
 ..Set KT=$P(^KPR(PRNr,0),D,1)
 ..Set IdentNr=$P(^KPR(PRNr,2),D,25)
 ..Set LangT1=$P(^KPR(PRNr,0),D,2)
 ..Set LangT2=$P(^KPR(PRNr,0),D,11)
 ..Set Cnt=Cnt+1,Txt(Cnt)=" "_KT_$J("",27-$L(KT))_LangT1_"~"
 ..Set Cnt=Cnt+1,Txt(Cnt)=$J("",28)_LangT2_"~"
 ; Versturen van de mail
 Set MailId=$$SYSTEM^vhMAIL("","","Nieuwe produkten","19",.Txt,"","","A")
 Quit