RapJoDM ;NEW PROGRAM [ 12/02/2003  9:12 AM ]
 
 ;INIT 
 Set KlantKey=0
 Set Dev=0
 
 ;CALCDATE voor 1 jaar terug 
 Set VB=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp($H,"M",-24),"DM4")_" "
 Set VE=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp($H,"M",-13),"DM4")_" "
 Set HB=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp($H,"M",-12),"DM4")_" "
 Set HE=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp($H,"M",-1),"DM4")_" "
 
 Set Regios="A"
 Do DISPLAY^vhScherm("RAPJODM"),FIELD^vhScherm("RAPJODM","REGIOS"),DISPLAY^vhScherm("RAPJODM",,,,"REGIOS")
 Quit:'$L(Regios)
 
 If Regios=29 Do
 . Set Formaat(1)="TXT`Text"
 . Set Formaat(2)="PDFG`PDF globaal"
 . Set Formaat(3)="PDFI`PDF individueel"
 . Set Formaat=$$WILD^vhPOPUP("C;C","O1-","Formaat",.Formaat)
 If $E($G(Formaat),1,3)="PDF" Do ##Class(CHUI.Derde.Klant.FicheDoc).Regio(Regios,$E(Formaat,4)) Quit ; Klantenfische in PDF-formaat
 Set DevName=$E(HE_$S($L(Regios,";")=1:"Regio",1:"R")_$TR(Regios,";","&"),1,26)
 Set DevName=DevName_".txt",Dev=$$OPEN^vhDEV(,DevName,"W","A")
 Quit:0[Dev
 
 Write !,"Saving..."
 Use:0'[Dev Dev
 
 ;WRITE HEADER
 Write "Klant",$C(9),"Naam",$C(9),"Straat,Postcode,Gemeente",$C(9),"PostNr",$C(9),"Tel 1",$C(9),"Tel 2",$C(9),"GSM",$C(9),"Klant Van",$C(9),"Prijsklasse",$C(9),"Omzet vorig",$C(9),"Omzet huidig",$C(9),"Regio",$C(9),"ContaktPers.",$C(9),"E-Mail",$C(9),"Aktiviteit",$C(9),"vHisie",!
 ;FETCH DATA
 For  Set KlantKey=$O(^KKL(KlantKey)) Quit:KlantKey=""  Do
 . Set rec=^KKL(KlantKey,0) 
 . Quit:'$D(^KK1($P(rec,D)))
 . Set Regio=$P(rec,D,20)
 . If Regios'="A",";"_Regios_";"'[(";"_Regio_";") Quit
 . Set KlantNm=$P(rec,D,2) 
 . Set KlantNr=$P(rec,D,1)
 . Set Kontakt=$G(^PERS("K",KlantNr,1),"")
 . Set:Kontakt'="" Kontakt=$P(Kontakt,D,4)_" "_$P(Kontakt,D,3)_" "_$P(Kontakt,D,2) 
 . Set tRec=rec
 . Set StrtNrBs=$P(rec,D,5)
 . ;Indien postbus leveringsadres gebruiken
 . If ($$UPTRIMAN^vhRtn1(StrtNrBs)["POSTBUS")  Do
 .. Set tKey=$O(^KKL(KlantKey,"L"))
 .. Set:$E(tKey)="L" tRec=^KKL(KlantKey,tKey)
 . Set StrtNrBs=$P(tRec,D,5)
 . Set PostNr=$P(tRec,D,6) 
 . Set WoonPlts=$P(tRec,D,7)
 . Set Tel1=$P(tRec,D,13)
 . Set Tel2=$P(rec,D,14)
 . Set rec=^KKL(KlantKey,1) 
 . Set Aktiviteit=$P(rec,D,11)
 . Set Fase=$P(rec,D,4)
 . Set BezCode=$P(rec,D,8)
 . Set KlantVan=$$FetchKlantVan(KlantNr)
 . Set rec=^KKL(KlantKey,2)
 . Set PrsKls=$$KODEX^KLANT(KlantNr)
 . Set KodeComm=$S($P(rec,D,10):"NON",1:"AKT"),EMailAdr=$P(rec,D,19)
 . Set GSMNr=$P(rec,D,20)         ;kijken naar ^PERS ?
 . Set rec=^KKL(KlantKey,4)
 . Set Opmerk1=$P(rec,D,1)
 . Set Opmerk2=$P(rec,D,2)
 . Set Opmerk3=$P(rec,D,3)
 . Set rec=^KKL(KlantKey,5)
 . Set Opmerk9=$P(rec,D,2)
 . Set Adres=$$FetchAdres(KlantNr)
 . Set VOmzet=$$KLANT^STAT(KlantNr,,VB,VE,3) 
 . Set HOmzet=$$KLANT^STAT(KlantNr,,HB,HE,3)
 . Set vHisie=$$ATKUSERS^KLANT(KlantNr),vHisie=$S($L(vHisie):"Ja ("_$L(vHisie,D)_")",1:"")
 . ;WRITE DATA
 . Write KlantNr,$C(9),KlantNm,$C(9),Adres,$C(9),PostNr,$C(9),Tel1,$C(9),Tel2,$C(9),GSMNr,$C(9),KlantVan,$C(9),PrsKls,$C(9),$J(VOmzet,0,0),$C(9),$J(HOmzet,0,0),$C(9),Regio,$C(9),Kontakt,$C(9),EMailAdr,$C(9),Aktiviteit,$C(9),vHisie,! 
 close:0'[Dev Dev
 Quit
 
FetchAdres(KLNr)
 New Adres,Rec,KlKey,LevAdr,StrtNrBs,PostNr,WoonPl
 Set KlKey=^KK1(KLNr),Rec=^KKL(KlKey,0),StrtNrBs=$P(Rec,D,5)
 Set LevAdr="L"
 Do:$$UPTRIMAN^vhRtn1(StrtNrBs)["POSTBUS"
 . Set LevAdr=$O(^KKL(KlKey,LevAdr))
 . If $E(LevAdr)="L" Set Rec=^KKL(KlKey,LevAdr)
 . Else  Set LevAdr="L"
 Set StrtNrBs=$ZSTRIP($P(Rec,D,5),"<>W"),PostNr=$ZSTRIP($P(Rec,D,6),"<>W"),WoonPl=$ZSTRIP($P(Rec,D,7),"<>W")
 Set Adres=StrtNrBs_", "_PostNr_", "_WoonPl
 Set Cnt=0
 For  Set LevAdr=$O(^KKL(KlKey,LevAdr)) Quit:$E(LevAdr)'="L"  Do  Quit:Cnt>5
 . Set Rec=^KKL(KlKey,LevAdr)
 . Set StrtNrBs=$ZSTRIP($P(Rec,D,5),"<>W"),PostNr=$ZSTRIP($P(Rec,D,6),"<>W"),WoonPl=$ZSTRIP($P(Rec,D,7),"<>W")
 . Quit:$TR(StrtNrBs_PostNr_WoonPl," ","")=""
 . Set Adres=Adres_">CR<"_StrtNrBs_", "_PostNr_", "_WoonPl
 . Set Cnt=Cnt+1
 
 Quit Adres
 
FetchKlantVan(KLNr)
 New I,KlantVan
 Set KlantVan=##Class(BL.Derde.Klant.Relaties).KlantVan(KLNr)
 Set KlantVan=$$ListToPieces^vhLib(KlantVan)
 If $L(KlantVan) For I=1:1:$L(KlantVan,",") Set $P(KlantVan,",",I)=" "_$P(^KKL(^KK1($P(KlantVan,",",I)),0),D,2)
 Quit KlantVan