STATDEL ;Verwijderen van statistieken, historieken en fakturen [ 05/21/2003  9:26 AM ]
 Do:'$D(Q)
 .Set Q="K"
 .D ^cA604,INIT^vhTERMINA
 Set %J=$$%J^vhRtn1()
 Set Terug=31
 Do PRIO^vhINITML("L")
 ; Defaulting
 Set $P(Default,D,1)=$$CALCDATE^vhDTyp($H,"M",-10*12-1,"MD") ; Statistiek
 Set $P(Default,D,2)=$$CALCDATE^vhDTyp($H,"M",-10*12-1,"MD") ; Gesommeerde klant statistiek
 Set $P(Default,D,3)=$$CALCDATE^vhDTyp($H,"M",-5*12-1,"MD") ; Produkt Weekverkoop
 Set $P(Default,D,4)=$$CALCDATE^vhDTyp($H,"M",-5*12-1,"MD") ; Produkt historiek
 Set $P(Default,D,5)=$$CALCDATE^vhDTyp($H,"M",-6*12-1,"MD") ; Deaktiveren Fakturen
 Set $P(Default,D,6)=$$CALCDATE^vhDTyp($H,"M",-10*12-1,"MD") ; Verwijderen Fakturen
 Set $P(Default,D,7)=$$CALCDATE^vhDTyp($H,"M",-6*12-1,"MD") ; Proforma
 Set $P(Default,D,9)=$$CALCDATE^vhDTyp($H,"M",-12-1,"MD") ; Bons "G","M" en "T"
 Set $P(Default,D,10)=$$CALCDATE^vhDTyp($H,"M",-24-1,"MD") ; Offertes
 Set $P(Default,D,11)=$$CALCDATE^vhDTyp($H,"M",-12-1,"MD") ; Toeleveringen
 ;
 Do NIEUW^vhScherm("STATDEL")
 Quit:'$D(StatDel)
 Set Go=""
 If '$P(StatDel,D,1),'$P(StatDel,D,2),'$P(StatDel,D,3),'$P(StatDel,D,4),'$P(StatDel,D,5) Quit
 Set Go=$$ASK^vhINP("Bent u zeker dat u de statistiek wenst te verwijderen : ",9,"","VERWIJDER[] = Verwijderen van de statistiek","","","","","U")
 Quit:Go'="VERWIJDER"
 Set DispDef=1
 If $P(StatDel,D,1) Do DELSTAT("",$P(StatDel,D,1),$P(StatDel,D,2))
 If $P(StatDel,D,3) Do DELWVK("",$P(StatDel,D,3))
 If $P(StatDel,D,4) Do DELHIS("",$P(StatDel,D,4))
 If $P(StatDel,D,5) Do MOVEFAK("",$P(StatDel,D,5))
 If $P(StatDel,D,6) Read !,"Gelieve DELFAK^STATDEL na te zien [] = ok",r ;Do DELFAK("",$P(StatDel,D,6))
 If $P(StatDel,D,7) Do DELFAKP("",$P(StatDel,D,7))
 If $P(StatDel,D,9) Do DELBON("",$P(StatDel,D,9))
 If $P(StatDel,D,10) Do DELOFF("",$P(StatDel,D,10))
 If $P(StatDel,D,11) Do DELTO("",$P(StatDel,D,11))
 Quit
 
DELSTAT(VanMnd,TotMnd,TotKLMnd,Display) 
 Set Display=$G(Display,DispDef)
 Set:'VanMnd VanM=0
 Set:VanMnd VanM=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp(VanMnd,"M"-1),"DM4")_" "
 Set TotM=$$EXTDATE^vhDTyp(TotMnd,"DM4")_" "
 Set TotKLM=$$EXTDATE^vhDTyp(TotKLMnd,"DM4")_" "
 Write:Display @FCH
 
 ; KSTKL
 Set FP=2201 Write:Display @F,@F1,"Verwijderen Klant/Produkt KSTKL",!,"Klanten verwerkt : "
 Set (Cnt,KLNr)=0,PRNr=""
 For  Set KLNr=$O(^KSTKL(KLNr)) Quit:KLNr=""  Do
 .For  Lock +^KSTKL(KLNr):2 Quit:$T  Do:Display LDISP^vhLock($NA(^KSTKL(KLNr)))
 .If '$D(^KK1(KLNr)) Kill ^KSTKL(KLNr) ; Klant bestaat niet
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2321 Write:Display @F,Cnt 
 .For  Set PRNr=$O(^KSTKL(KLNr,PRNr)) Quit:PRNr=""  Do
 ..If '$D(^KPR(PRNr)) Kill ^KSTKL(KLNr,PRNr) ; Produkt bestaat niet
 ..Set Mnd=VanM
 ..For  Set Mnd=$O(^KSTKL(KLNr,PRNr,Mnd)) Quit:Mnd=""  Quit:PRNr&(Mnd]TotM)  Quit:'PRNr&(Mnd]TotKLM)  Do
 ...Write:Display=2 !,KLNr," ",PRNr," ",Mnd
 ...Kill ^KSTKL(KLNr,PRNr,Mnd)
 ..Kill:$O(^KSTKL(KLNr,PRNr,0))="" ^(0)
 .Lock -^KSTKL(KLNr)
 Lock
 
 ; KSTPR
 Set FP=2201 Write:Display @F,@F1,"Verwijderen Produkt/Klant KSTPR",!,"Produkten verwerkt : "
 Set (Cnt,PRNr)=0,KLNr=""
 For  Set PRNr=$O(^KSTPR(PRNr)) Quit:PRNr=""  Do
 .For  Lock +^KSTPR(PRNr):2 Quit:$T  Do:Display LDISP^vhLock($NA(^KSTPR(PRNr)))
 .If '$D(^KPR(PRNr)) Kill ^KSTPR(PRNr) ; Produkt bestaat niet
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2323 Write:Display @F,Cnt 
 .For  Set KLNr=$O(^KSTPR(PRNr,KLNr)) Quit:KLNr=""  Do
 ..If KLNr,'$D(^KK1(KLNr)) Kill ^KSTPR(PRNr,KLNr) ; Klant bestaat niet
 ..Set Mnd=VanM
 ..For  Set Mnd=$O(^KSTPR(PRNr,KLNr,Mnd)) Quit:Mnd=""  Quit:Mnd]TotM  Do
 ...Write:Display=2 !,KLNr," ",PRNr," ",Mnd
 ...Kill ^KSTPR(PRNr,KLNr,Mnd)
 ..Kill:$O(^KSTPR(PRNr,KLNr,0))="" ^(0)
 .Lock -^KSTPR(PRNr)
 Lock
 
 ; KLKAN
 Set:'VanMnd VanM=0
 Set:VanMnd VanM=$$CALCDATE^vhDTyp(VanMnd,"M"-1,"MD")
 Set TotM=$$CALCDATE^vhDTyp(TotMnd,"M","MD")
 Set FP=2201 Write:Display @F,@F1,"Verwijderen Klant verkoop per kodex KLKAN",!,"Klanten verwerkt : "
 Set (Cnt,KLNr)=0,PRNr=""
 For  Set KLNr=$O(^KLKAN(KLNr)) Quit:KLNr=""  Do
 .For  Lock +^KLKAN(KLNr):2 Quit:$T  Do:Display LDISP^vhLock($NA(^KLKAN(KLNr)))
 .If '$D(^KK1(KLNr)) Kill ^KLKAN(KLNr) ; Klant bestaat niet
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2321 Write:Display @F,Cnt 
 .For  Set PRNr=$O(^KLKAN(KLNr,PRNr)) Quit:PRNr=""  Do
 ..If '$D(^KPR(PRNr)) Kill ^KLKAN(KLNr,PRNr) ; Produkt bestaat niet
 ..Set Mnd=VanM
 ..For  Set Mnd=$O(^KLKAN(KLNr,PRNr,Mnd)) Quit:Mnd=""  Quit:PRNr&(Mnd>TotM)  Quit:'PRNr&(Mnd>TotKLM)  Do
 ...Write:Display=2 !,KLNr," ",PRNr," ",Mnd
 ...Kill ^KLKAN(KLNr,PRNr,Mnd)
 ..Kill:$O(^KLKAN(KLNr,PRNr,0))="" ^(0)
 .Lock -^KLKAN(KLNr)
 Write:Display @FCS
 Lock
 Quit
 
DELWVK(VanMnd,TotMnd,Display) 
 Set Display=$G(Display,DispDef)
 Set:'VanMnd VanWT="",VanWS=" "
 Set:VanMnd VanWT=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp(VanMnd,"M"-1,"LD")-6,"DW4"),VanWT=+($P(VanWT,"/",1)_$P(VanWT,"/",2))
 Set:VanMnd VanWS=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp(VanMnd,"M"-1,"LD")-6,"DW4"),VanWS=$TR(VanWS,"/",".")_" "
 Set TotWT=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp(TotMnd,"M","LD")-6,"DW4"),TotWT=+($P(TotWT,"/",1)_$P(TotWT,"/",2))
 Set TotWS=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp(TotMnd,"M","LD")-6,"DW4"),TotWS=$TR(TotWS,"/",".")_" "
 Write:Display @FCH
 
 ; KSPW
 Set FP=2201 Write:Display @F,@F1,"Verwijderen Produkt weekverkoop KSPW",!,"Produkten verwerkt : "
 Set (Cnt,KLNr)=0,PRNr=0
 For  Set PRNr=$O(^KSPW(PRNr)) Quit:PRNr=""  Do
 .For  Lock +^KSPW(PRNr):2 Quit:$T  Do:Display LDISP^vhLock($NA(^KSPW(KPRNr)))
 .If '$D(^KPR(PRNr)) Kill ^KSPW(PRNr)
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2323 Write:Display @F,Cnt 
 .Set Wk=VanWT
 .For  Set Wk=$O(^KSPW(PRNr,Wk)) Quit:Wk=""  Quit:Wk'?.N!(Wk>TotWT)  Do
 ..Write:Display=2 !,PRNr," ",Wk," ",$$EXTDATE^vhDTyp($$INTDATE^vhDTyp($E(Wk,1,4)_"/"_$E(Wk,5,6),"DW"),"DM"),"T"
 ..Kill ^KSPW(PRNr,Wk)
 .Set Wk=VanWS
 .For  Set Wk=$O(^KSPW(PRNr,Wk)) Quit:Wk=""  Quit:(Wk]TotWS)  Do
 ..Write:Display=2 !,PRNr," ",Wk," ",$$EXTDATE^vhDTyp($$INTDATE^vhDTyp($TR(Wk,". ","/"),"DW"),"DM"),"S"
 ..Kill ^KSPW(PRNr,Wk)
 .Lock -^KSPW(PRNr)
 Write:Display @FCS
 Lock
 Quit
 
DELHIS(VanMnd,TotMnd,Display) 
 Set Display=$G(Display,DispDef)
 Set TotD=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp(TotMnd,"M","LD"),"DKP")
 Set TotD=$P(TotD,".",3)_$P(TotD,".",2)_$P(TotD,".",1)
 Set TotD=$S($E(TotD,1,2)>50:19,1:20)_TotD
 Write:Display @FCH
 
 ; KPR("H")
 Set FP=2201 Write:Display @F,@F1,"Verwijderen Produkt historieken (Stockverloop) KPR(,H...)",!,"Produkten verwerkt : "
 Set (PRNr,Cnt)=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 .For  Lock +^KPR(PRNr):2 Quit:$T  Do:Display LDISP^vhLock($NA(^KPR(PRNr)),"Produkt "_$P(^KPR(PRNr,0),D,1))
 .Kill ^HULP(%J)
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2323 Write:Display @F,Cnt 
 .Set BeginSt=$P(^KPR(PRNr,0),D,12)
 .Set NodeCnt=0
 .Write:Display=2 !!,PRNr," ",BeginSt
 .Set Node=$O(^KPR(PRNr,"H")) Quit:Node=""
 .Set Node="H"
 .For  Set Node=$O(^KPR(PRNr,Node)) Quit:$E(Node)'="H"  Do
 ..Set Rec=^KPR(PRNr,Node)
 ..Kill ^KPR(PRNr,Node)
 ..For Piece=1:1 Set HElem=$P(Rec,D,Piece) Quit:HElem=""  Do
 ...If $S($E(HElem,1,2)>50:19,1:20)_$E(HElem,1,6)<TotD Do  ; Te verwijderen
 ....Set Actie=$E(HElem,7)
 ....Set Aantal=$E($P(HElem,"#"),8,99)
 ....If Actie#2 Set BeginSt=BeginSt+Aantal
 ....Else  Set BeginSt=BeginSt-Aantal
 ....Write:Display=2 !," ",HElem," ",BeginSt
 ...Else  Do  ; Behouden en opslaan in hulp
 ....Set NodeCnt=NodeCnt+1,^HULP(%J,NodeCnt)=HElem
 .Set $P(^KPR(PRNr,0),D,12)=BeginSt
 .Kill ^KPR(PRNr,"H")
 .Set HCnt=0,HNode=""
 .For NodeCnt=1:1:NodeCnt Do
 ..Set HElem=^HULP(%J,NodeCnt)
 ..If $L(HNode)+$L(HElem)+1>256 Set HCnt=HCnt+1,^KPR(PRNr,"H"_$E(10000+HCnt,2,5))=HNode,HNode=""
 ..Set HNode=HNode_HElem_D
 .If HNode'="" Set HCnt=HCnt+1,^KPR(PRNr,"H"_$E(10000+HCnt,2,5))=HNode
 .Set:HCnt ^KPR(PRNr,"H")=HCnt
 .Lock -^KPR(PRNr)
 Write:Display @FCS
 Kill ^HULP(%J)
 Lock
 Quit
 
MOVEFAK(VanMnd,TotMnd,Display) ; Aktieve fakturen overbrengen naar NON-aktief, van ^KFA(""F"") naar ^COPYKFA(""F"")
 Set Display=$G(Display,DispDef)
 Write:Display @FCH
 Set:'VanMnd VanD=0
 Set:VanMnd VanD=-$$CALCDATE^vhDTyp(VanMnd,"M","FD")
 Set TotD=-$$CALCDATE^vhDTyp(TotMnd,"M","LD")-1
 
 ; KFA
 Set FP=2201 Write:Display @F,@F1,"Deaktiveren Fakturen, van ^KFA(""F"") naar ^COPYKFA(""F"")  KFA,KFA1",!,"Klanten verwerkt : "
 Set (Cnt,FAKNr,KLNr,Dat)=0
 For  Set KLNr=$O(^KFA1("F",KLNr)) Quit:KLNr=""  Do
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2321 Write:Display @F,Cnt 
 .Set Dat=TotD
 .For  Set Dat=$O(^KFA1("F",KLNr,Dat)) Quit:Dat=""  Quit:Dat>VanD  Do
 ..For  Set FAKNr=$O(^KFA1("F",KLNr,Dat,FAKNr)) Quit:FAKNr=""  Do
 ...For  Lock +^KFA("F",FAKNr):2 Quit:$T  Do:Display LDISP^vhLock($NA(^KFA("F",FAKNr)))
 ...Write:Display=2 !,KLNr," ",Dat," ",$P(^COPYKFA("F",FAKNr,0,0),D,6)
 ...If $D(^KK1(KLNr)),$D(^KKL(^KK1(KLNr),FAKNr)) Lock -^KFA("F",FAKNr) Quit  ; Nog te betalen
 ...Do DELOBJ^FLOWCOPYKFA(FAKNr) ; Verwijderen indien deze nog zou bestaan van een vorig boekjaar
 ...Merge ^COPYKFA("F",FAKNr)=^KFA("F",FAKNr)
 ...Set ^COPYKFA1("F",KLNr,Dat,FAKNr)=^KFA1("F",KLNr,Dat,FAKNr)
 ...Kill ^KFA1("F",KLNr,Dat,FAKNr)
 ...Kill ^KFA("F",FAKNr)
 ...Lock -^KFA("F",FAKNr)
 ...Do DelFact^KLACHT4(FAKNr) ; Klachten opkuisen
 Write:Display @FCS
 Lock
 Quit
 
DELFAK(VanMnd,TotMnd,Display) ; Fakturen
 Set Display=$G(Display,DispDef)
 Write:Display @FCH
 Set:'VanMnd VanD=0
 Set:VanMnd VanD=-$$CALCDATE^vhDTyp(VanMnd,"M","FD")
 Set TotD=-$$CALCDATE^vhDTyp(TotMnd,"M","LD")-1
 
 ; KFA
 Set FP=2201 Write:Display @F,@F1,"Verwijderen Fakturen KFA,KFA1",!,"Klanten verwerkt : "
 Do DELFAK2("^KFA1","^KFA","G")
 Quit
 
DELFAK2(Index,Bestand,Node) 
 Set (Cnt,FAKNr,KLNr,Dat)=0
 For  Set KLNr=$O(@Index@(Node,KLNr)) Quit:KLNr=""  Do
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2321 Write:Display @F,Cnt 
 .Set Dat=TotD
 .For  Set Dat=$O(@Index@(Node,KLNr,Dat)) Quit:Dat=""  Quit:Dat>VanD  Do
 ..For  Set FAKNr=$O(@Index@(Node,KLNr,Dat,FAKNr)) Quit:FAKNr=""  Do
 ...For  Lock +(@Bestand@(Node,FAKNr)):2 Quit:$T  Do:Display LDISP^vhLock($NA(@Bestand@(Node,FAKNr)))
 ...Write:Display=2 !,KLNr," ",Dat," ",$P(^COPYKFA("F",FAKNr,0,0),D,6)
 ...If Bestand="^KFA",Node="F",$D(^KK1(KLNr)),$D(^KKL(^KK1(KLNr),FAKNr)) Lock -(@Bestand@(Node,FAKNr)) Quit  ; Nog te betalen
 ...Kill @Index@(Node,KLNr,Dat,FAKNr)
 ...Kill @Bestand@(Node,FAKNr)
 ...Lock -(@Bestand@(Node,FAKNr))
 ...Do:Node="F" ; Klachten opkuisen
 ....Do:Bestand="^KFA" DelFact^KLACHT4(FAKNr)
 ....Do:Bestand="^KFAP" DelProf^KLACHT4(FAKNr)
 Write:Display @FCS
 Lock
 Quit
 
DELFAKP(VanMnd,TotMnd,Display)  ; Proforma's
 Set Display=$G(Display,DispDef)
 Write:Display @FCH
 Set:'VanMnd VanD=0
 Set:VanMnd VanD=-$$CALCDATE^vhDTyp(VanMnd,"M","FD")
 Set TotD=-$$CALCDATE^vhDTyp(TotMnd,"M","LD")-1
 
 Set FP=2201 Write:Display @F,@F1,"Verwijderen Proforma KFAP,KFAP1",!,"Klanten verwerkt : "
 Do DELFAK2("^KFAP1","^KFAP","F")
 Quit
 
DELBON(VanMnd,TotMnd,Display) 
 Set Display=$G(Display,DispDef)
 Write:Display @FCH
 ; KPR(,"H"
 Set FP=2201 Write:Display @F,@F1,"Aanpassen produkthistoriek i.v.m. faktuurnummer",!,"Produkten verwerkt : "
 Do BON2FAKT
 Set:'VanMnd VanD=0
 Set:VanMnd VanD=$$CALCDATE^vhDTyp(VanMnd,"M","FD")
 Set TotD=$$CALCDATE^vhDTyp(TotMnd,"M","LD")
 
 ; KUL(,"G"
 Set FP=2201 Write:Display @F,@F1,"Verwijderen uitleveringen KUL(,""G""",!,"Klanten verwerkt : "
 Do DELBON2("G")
 ; KUL(,"M"
 Set FP=2201 Write:Display @F,@F1,"Verwijderen uitleveringen KUL(,""M","",!,"Klanten verwerkt : "
 Do DELBON2("M")
 ; KUL(,"T"
 Set FP=2201 Write:Display @F,@F1,"Verwijderen uitleveringen KUL(,""T","",!,"Klanten verwerkt : "
 Do DELBON2("T")
 Write:Display @FCS
 Quit
 
DELBON2(Node) ; LowLevel voor het verwijderen van bon's
 Set (Cnt,ULNr,KLNr)=0
 For  Set KLNr=$O(^KUL(KLNr)) Quit:KLNr=""  Do
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2321 Write:Display @F,Cnt 
 .For  Set ULNr=$O(^KUL(KLNr,Node,ULNr)) Quit:ULNr=""  Do
 ..Set Rec=^KUL(KLNr,Node,ULNr,1),Dat=$$INTDATE^vhDTyp($P(Rec,D,2))
 ..If Dat<VanD!(Dat>TotD) Quit
 ..For  Lock +^KUL(KLNr,Node,ULNr):2 Quit:$T  Do:Display LDISP^vhLock($NAME(^KUL(KLNr,Node,ULNr)))
 ..Write:Display=2 !,KLNr," ",Dat," ",$P(^KUL(KLNr,Node,ULNr,1),D,2)
 ..If Node="F" Do
 ...Set OLNr=100
 ...For  Set OLNr=$O(^KUL(KLNr,Node,ULNr,OLNr)) Quit:'OLNr  Do
 ....Do DELBON^FLOWBON3(KLNr,ULNr,OLNr),DELKUP^FLOWBON3(KLNr,ULNr,OLNr)
 ..If $D(^ORDW("D",ULNr)) Do
 ...If Node'="F",$D(^KUL(KLNr,"F",ULNr)) Quit
 ...New KLNr,ORDNr
 ...Set KLNr=$P(^ORDW("D",ULNr),D)
 ...Kill ^ORDW("IK",KLNr,ULNr)
 ...Set ORDNr=""
 ...For  Set ORDNr=$O(^ORDW("D",ULNr,"D",ORDNr)) Quit:ORDNr=""  Kill ^ORDW("IO",ORDNr)
 ...Kill ^ORDW("D",ULNr)
 ..Do KILL^KFVZW(Node,Rec,ULNr)
 ..Kill ^KUL(KLNr,Node,ULNr),^KU1(ULNr)
 ..Lock -^KUL(KLNr,Node,ULNr)
 Lock
 Quit
 
 ; Om sporadisch eens een "G", "M" of "T" bon te verwijderen
DELONEBON(BONNr)
 New Node,Rec,ZR
 If '$G(BONNr) Read !,"BONNr ? ",BONNr
 If BONNr,$D(^KU1(BONNr,"F")) Do
 .Set KLNr=$P(^KU1(BONNr,"F"),D),Node=$$NODE^FLOWBON(BONNr)
 .Set Rec=$G(^KUL(KLNr,Node,BONNr)),ZR=$ZR
 .Write !!
 .ZWrite ^KUL(KLNr,Node,BONNr,1)
 .Write !
 .If Node'="F" Do  ; Enkel indien "G", "M" of "T"
 ..For  Lock +^KUL(KLNr,Node,BONNr):2 Quit:$T  Do:Display LDISP^vhLock($NAME(^KUL(KLNr,Node,BONNr)))
 ..Write !,"Verwijderen ",ZR," ???"
 ..Read !,"VERWIJDER[] ",Verwijder
 ..If Verwijder'="VERWIJDER" Write !,"Bon ",ZR," NIET verwijderd!!!" Quit
 ..Set Rec=^KUL(KLNr,Node,BONNr,1)
 ..If $D(^ORDW("D",BONNr)) Do
 ...If Node'="F",$D(^KUL(KLNr,"F",BONNr)) Quit
 ...New KLNr,ORDNr
 ...Set KLNr=$P(^ORDW("D",BONNr),D)
 ...Kill ^ORDW("IK",KLNr,BONNr)
 ...Set ORDNr=""
 ...For  Set ORDNr=$O(^ORDW("D",BONNr,"D",ORDNr)) Quit:ORDNr=""  Kill ^ORDW("IO",ORDNr)
 ...Kill ^ORDW("D",BONNr)
 ..Do KILL^KFVZW(Node,Rec,BONNr)
 ..Kill ^KUL(KLNr,Node,BONNr),^KU1(BONNr)
 ..Lock -^KUL(KLNr,Node,BONNr)
 ..Write !,"Bon ",ZR," is verwijderd!!!"
 .Else  Write !,"Bon ",ZR," kan NIET verwijderd worden!!! Node = ""F"""
 .Lock
 Else  Write !,"BONNr """,BONNr,""" is onbekend!"
 Quit
 
DELOFF(VanMnd,TotMnd,Display) 
 Set Display=$G(Display,2)
 Write:Display @FCH
 Set:'VanMnd VanD=0
 Set:VanMnd VanD=$$CALCDATE^vhDTyp(VanMnd,"M","FD")
 Set TotD=$$CALCDATE^vhDTyp(TotMnd,"M","LD")
 
 ; OFF
 Set FP=2201 Write:Display @F,@F1,"Verwijderen offertes KOFKL(,""F""",!,"Klanten verwerkt : "
 
 Set (Cnt,OFFNr,KLNr)=0
 Set Node="F"
 For  Set KLNr=$O(^KOFKL(KLNr)) Quit:KLNr=""  Do
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2321 Write:Display @F,Cnt 
 .For  Set OFFNr=$O(^KOFKL(KLNr,Node,OFFNr)) Quit:OFFNr=""  Do
 ..Set Rec=^KOFKL(KLNr,Node,OFFNr,1),Dat=$$INTDATE^vhDTyp($P(Rec,D,2))
 ..If Dat<VanD!(Dat>TotD) Quit
 ..For  Lock +^KOFKL(KLNr,Node,OFFNr):2 Quit:$T  Do:Display LDISP^vhLock($NAME(^KOFKL(KLNr,Node,OFFNr)))
 ..Write:Display=2 !,KLNr," ",Dat," ",$P(^KOFKL(KLNr,Node,OFFNr,1),D,2)
 ..Set OLNr=100
 ..For  Set OLNr=$O(^KOFKL(KLNr,Node,OFFNr,OLNr)) Quit:'OLNr  Quit:OLNr'?.N  Do
 ...Set PRNr=$P(^KOFKL(KLNr,Node,OFFNr,OLNr),D,2)
 ...Quit:'PRNr
 ...Kill ^KOFKLP(PRNr,OFFNr,OLNr)
 ..Kill ^KOFKL1(OFFNr,Node)
 ..Kill ^KOFKLB(OFFNr,Node)
 ..Kill ^KOFKLT(OFFNr,Node)
 ..Kill ^KOFKL2(Node,KLNr,OFFNr)
 ..Kill ^KOFKL(KLNr,Node,OFFNr)
 ..Lock -^KOFKL(KLNr,Node,OFFNr)
 Lock
 Quit
 
DELTO(VanMnd,TotMnd,Display) 
 Set Display=$G(Display,DispDef)
 Write:Display @FCH
 Set:'VanMnd VanD=0
 Set:VanMnd VanD=$$CALCDATE^vhDTyp(VanMnd,"M","FD")
 Set TotD=$$CALCDATE^vhDTyp(TotMnd,"M","LD")
 
 ; KTO5
 Set FP=2201 Write:Display @F,@F1,"Verwijderen toeleveringen KTO5",!,"Leveranciers verwerkt : "
 
 Set (Cnt,TOENr,LEVNr)=0
 For  Set LEVNr=$O(^KTO5(LEVNr)) Quit:LEVNr=""  Do
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2326 Write:Display @F,Cnt 
 .For  Set TOENr=$O(^KTO5(LEVNr,TOENr)) Quit:TOENr=""  Do
 ..Quit:$D(^KTO(LEVNr,TOENr))
 ..Set Rec=^KTO5(LEVNr,TOENr,1),Dat=$$INTDATE^vhDTyp($P(Rec,D,2))
 ..If Dat<VanD!(Dat>TotD) Quit
 ..For  Lock +^KTO5(LEVNr,TOENr):2 Quit:$T  Do:Display LDISP^vhLock($NAME(^KTO5(LEVNr,TOENr)))
 ..Write:Display=2 !,LEVNr," ",Dat," ",$P(^KTO5(LEVNr,TOENr,1),D,2)
 ..Kill ^KTO5(LEVNr,TOENr)
 ..Lock -^KTO5(LEVNr,TOENr)
 Write:Display @FCS
 Lock
 Quit
 
BON2FAKT 
 New PRNr,Cnt
 Set (Cnt,PRNr)=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 .Set Cnt=Cnt+1
 .If '(Cnt#10) Set FP=2323 Write:$G(Display) @F,Cnt 
 .Do BON2FAKT^PRODUKT4(PRNr)
 Quit
 
NIGHT 
 Set $ZT="^cA406"
 Set Q="K"
 Do ^cA604
 If $$EXTDATE^vhDTyp($H,"DMN")=1 Do DELBON("",$$CALCDATE^vhDTyp($H,"M","-13","MD"),1)
 Quit