STPORTEF ;Statistiek portefeuille [ 05/24/2002  3:35 PM ]
 Set LEVNr=""
 Do DISPLAY^vhScherm("STPORTEF")
 Do FIELD^vhScherm("STPORTEF","LEVNR")
 Quit:'LEVNr
 Set FP=2101
 Write @F,@F1
 Do DISPLAY^vhScherm("STPORTEF",,,,"LEVNR")
 Set PRNr=""
 Kill Som
 Set Som("TOT")=""
 For  Set PRNr=$O(^ORD("IP",PRNr)) Quit:PRNr=""  Do
 .Quit:'$D(^KPR(PRNr,"J"_LEVNr))
 .Set ORDNr="",OLUNr=""
 .For  Set ORDNr=$O(^ORD("IP",PRNr,ORDNr)) Quit:ORDNr=""  Do
 ..For  Set OLUNr=$O(^ORD("IP",PRNr,ORDNr,OLUNr)) Quit:OLUNr=""  Do
 ...Set OLNr=^(OLUNr)
 ...Set KLNr=$P(^KO1(ORDNr,"F"),D)
 ...Set Rec=^KOD(KLNr,"F",ORDNr,OLNr)
 ...Set Qty=$P(Rec,D,3)
 ...Set Tot=$P(Rec,D,16)
 ...Set:'Tot NulOrd(ORDNr)=KLNr
 ...Set Munt=$$MUNTPAR^vhRtn1($P(Rec,D,22))
 ...Set LevWk=$P(Rec,D,25)
 ...Set:'$D(Som(LevWk)) Som(LevWk)=""
 ...Set $P(Som(LevWk),D,1)=$P(Som(LevWk),D,1)+Qty
 ...Set $P(Som(LevWk),D,2)=$P(Som(LevWk),D,2)+(Tot/Munt)
 ...Set $P(Som("TOT"),D,1)=$P(Som("TOT"),D,1)+Qty
 ...Set $P(Som("TOT"),D,2)=$P(Som("TOT"),D,2)+(Tot/Munt)
 ; Leveringsbons
 Set KLNr=""
 For  Set KLNr=$O(^KUL(KLNr)) Quit:KLNr=""  Do
 .Set BONNr="",OLNr=""
 .For  Set BONNr=$O(^KUL(KLNr,"F",BONNr)) Quit:BONNr=""  Do
 ..For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:'OLNr  Do
 ...Set Rec=^KUL(KLNr,"F",BONNr,OLNr)
 ...Set PRNr=$P(Rec,D,2)
 ...Quit:'PRNr
 ...Quit:'$D(^KPR(PRNr,"J"_LEVNr))
 ...Set Qty=$P(Rec,D,3)
 ...Set Tot=$P(Rec,D,16)
 ...Set Munt=$$MUNTPAR^vhRtn1($P(Rec,D,22))
 ...Set LevWk=$P(Rec,D,25)
 ...Set:'$D(Som(LevWk)) Som(LevWk)=""
 ...Set:'Tot NulOrd(BONNr)=KLNr
 ...Set $P(Som(LevWk),D,3)=$P(Som(LevWk),D,3)+Qty
 ...Set $P(Som(LevWk),D,4)=$P(Som(LevWk),D,4)+(Tot/Munt)
 ...Set $P(Som("TOT"),D,3)=$P(Som("TOT"),D,3)+Qty
 ...Set $P(Som("TOT"),D,4)=$P(Som("TOT"),D,4)+(Tot/Munt)
 Set Count=0,LevWk=""
 For  Set LevWk=$O(Som(LevWk)) Quit:LevWk=""  Set Count=Count+1,Som(Count)=LevWk_D_Som(LevWk) Kill Som(LevWk)
 Do INIT^PROC("STPORTEF","LD")
 Do ^OUTPUT("SPT","-","S")
 Quit