SYNCBIDI ; Bidirectioneel: Mail, Tijd en Verslag [ 09/11/2002  9:21 AM ]
 
TRAP If $P($ZERROR,">")="<NOSYS" Quit  ; Niets aan de hand, alleen remote is niet gekend
 ZQuit  ; Ga naar de andere error-handler
 
 ; TIJD wordt continu bijgewerkt, dit in tegenstelling tot Verslag en Mail
ACTREM(IPNr) ; Is de remote actief
 ; Set de local sModif op
 New PortVol,ActRem
 Set ActRem=0
 If $L($G(sRemVol)) Quit 0 ; De gebruiker werkt reeds op een remotevolume
 Set PortVol=$P($G(^vhUSER("D",IPNr,"T")),D,3)
 Quit:'$L(PortVol) 0 ; De gebruiker heeft geen remote volume
 Do 
 .Set $ZT="TRAP^SYNCBIDI" 
 .Set:$D(^|PortVol|TIJD) ActRem=1
 Quit ActRem
 
TIJDDEL(IPNr,Datum,Tijd) 
 Quit:'$D(sRemVol)
 Set $ZT="TRAP^SYNCBIDI" 
 Kill ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)
 Quit
 
TIJDNEW(IPNr,Datum,Tijd,Rec) 
 Quit:'$D(sRemVol)
 Set $ZT="TRAP^SYNCBIDI" 
 Set ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)=Rec
 Quit
 
TIJD(IPNr) 
 New Datum,Tijd,VolId,Rec,RemRec
 Set Datum=$H-32 ;(1 maand in het verleden)
 Set Tijd=""
 ; Update van remote naar ADM
 For  Set Datum=$O(^TIJD("D",IPNr,Datum)) Quit:Datum=""  Do
 .For  Set Tijd=$O(^TIJD("D",IPNr,Datum,Tijd)) Quit:Tijd=""  Do
 ..Set Rec=^TIJD("D",IPNr,Datum,Tijd)
 ..Set RemRec=$G(^|sRemVol|TIJD("D",IPNr,Datum,Tijd))
 ..If $L(RemRec),$P(Rec,D,10)'=$P(RemRec,D,10) Do  ; Verschillend van sIdVol -> Move naar vrije plaats
 ...Set T=Tijd
 ...For  Set T=T+1 Quit:'$D(^|sRemVol|TIJD("D",IPNr,Datum,T))
 ...Set ^|sRemVol|TIJD("D",IPNr,Datum,T)=RemRec
 ..If Rec'=RemRec Do
 ...Set ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)=Rec
 ; Update van ADM naar remote
 For  Set Datum=$O(^|sRemVol|TIJD("D",IPNr,Datum)) Quit:Datum=""  Do
 .For  Set Tijd=$O(^|sRemVol|TIJD("D",IPNr,Datum,Tijd)) Quit:Tijd=""  Do
 ..Set Rec=$G(^TIJD("D",IPNr,Datum,Tijd))
 ..Quit:$L(Rec)  ; Gelijke tijdstippen zijn reeds behandeld
 ..Set RemRec=^|sRemVol|TIJD("D",IPNr,Datum,Tijd)
 ..If $P($P(RemRec,D,10),";",3)=$ZU(5) Do  ; Verwijder !!!
 ...Kill ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)
 ..Else  Do
 ...Set $P(RemRec,D,10)=sIdVol
 ...Set ^TIJD("D",IPNr,Datum,Tijd)=RemRec
 ...Set ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)=RemRec
 Quit
 
VERSLAG(IPNr) 
 Set Datum="",VerslNr=""
 For  Set Datum=$O(^VERSLAG("II",IPNr,Datum)) Quit:Datum=""  Do
 .Set VerslNr=999999
 .For  Set VerslNr=$O(^VERSLAG("II",IPNr,Datum,VerslNr)) Quit:VerslNr=""  Do
 ..Lock +^VERSLAG("D",VerslNr):20
 ..Else  Set (Datum,VerslNr)="9999999" Quit
 ..Job VERSLCOP^SYNCBIDI($ZU(5),VerslNr)|sRemVol|::20
 ..Else  Set (Datum,VerslNr)="9999999" Quit
 ..Set NewNr="",Tijd=$P($H,";",2)
 ..For  Quit:$D(^SYNC("V",VerslNr))  Quit:Tijd+100<$P($H,";",2)  Hang 1
 ..Set NewNr=$G(^SYNC("V",VerslNr)) Quit:NewNr=""
 ..Kill ^SYNC("V",VerslNr)
 ..Do VERSLCOP($ZU(5),VerslNr,NewNr)
 ..Do DELOBJ^VERSLAG(VerslNr)
 ..Lock -^VERSLAG("D",VerslNr)
 Quit
 
VERSLCOP(FromVol,OldNr,NewNr) 
 Kill ^HULP($J)
 Merge ^HULP($J)=^|FromVol|VERSLAG("D",OldNr)
 Set New=0
 Set:'$G(NewNr) New=1,NewNr=$$NEXTID^VERSLAG()
 Merge ^VERSLAG("D",NewNr)=^|FromVol|VERSLAG("D",OldNr)
 Do BLDIND^VERSLAG(NewNr)
 Set:New ^|FromVol|SYNC("V",OldNr)=NewNr
 Quit