SYNCCOPY ; Copieren van de klantgegevens [ 09/11/2002  9:46 AM ]
 
TIJD(IPNr,sRemVol) 
 Set D="\",U=";"
 Set $ZT="TRAP^SYNC"
 Quit:'$D(^|sRemVol|TIJD)
 ;Write !,"Nakijken agenda"
 Lock +^SYNC("C")
 Set Datum=+$H-1
 Set EndDat=$$CALCDATE^vhDTyp($H,"A",+10)
 Set Uur=""
 For  Set Datum=$O(^TIJD("D",IPNr,Datum)) Quit:Datum=""  Do
 .For  Set Uur=$O(^TIJD("D",IPNr,Datum,Uur)) Quit:Uur=""  Do
 ..Set Rec=^TIJD("D",IPNr,Datum,Uur)
 ..If $P(Rec,D,4)=105&(+$H<Datum)!(Datum>EndDat) Set (Datum,Uur)=999999  Quit  ; Eerst volgend firma bezoek van de VTW of een max. een werkweek. Let wel op de portable zitten de verlofdagen niet!
 ..If $E($P(Rec,D,3))="K" Do
 ...Set CopyRef($P($P(Rec,D,3),";",2))=""
 ;Write !,"Verwijderen oude geg."
 Merge CopyRef=^|sRemVol|SYNC("KV",IPNr)
 Do REMALL(+$H)
 ;Write !,"Copieren nieuwe geg."
 Do COPYALL($NA(CopyRef))
 Lock -^SYNC("C")
 Quit
 
 ; Copy mag pas lopen nadat Update klaar is
REMALL(Datum) 
 New KLNr,KLId
 Set KLNr=""
 For  Set KLNr=$O(^SYNC("C",KLNr)) Quit:KLNr=""  Do
 .If Datum Quit:+^SYNC("C",KLNr)'<Datum  ; Klanten vandaag opgeladen worden niet verwijderd
 .Set KLId=$G(^KK1(KLNr))
 .Do:KLId'="" REMBOEK(KLId)
 .Do REMOFF(KLNr)
 .Do REMORD(KLNr)
 .Do REMUL(KLNr)
 .Do REMFAK(KLNr)
 .Do REMPRO(KLNr)
 .Do REMKAAP(KLNr)
 .Kill ^SYNC("C",KLNr)
 Quit
 
COPYALL(sRef) 
 ; Ref wordt doorgegeven via $NA(Global/Local-reference)
 New KLNr
 Set KLNr=""
 For  Set KLNr=$O(@sRef@(KLNr)) Quit:KLNr=""  Do KLANT(KLNr)
 Do REBUILD^PAKKET ; Opbouw van alle pakket indexen
 Quit
 
KLANT(KLNr) 
 Write !,"  Klant:",^KK1(KLNr)
 Quit:$D(^SYNC("C",KLNr))  ; Bestaat reeds
 New KLId,sV
 Set sV=sRemVol
 Set LocKLId=$G(^KK1(KLNr))
 Set KLId=$G(^[sRemVol]KK1(KLNr))
 Quit:KLId=""
 If LocKLId'=KLId Do  ; Klantnaam is gewijzigd
 .Kill:LocKLId'="" ^KKL(LocKLId)
 .Kill ^KK1(KLNr)
 .For I=0:1:6 Do
 ..Set ^KKL(KLId,I)=$G(^[sRemVol]KKL(KLId,I))
 .Set ^KK1(KLNr)=KLId
 Do COPYOFF(KLNr)
 Do COPYORD(KLNr)
 Do COPYUL(KLNr)
 Do COPYFAK(KLNr)
 Do COPYPRO(KLNr)
 Do COPYBOEK(KLId)
 Do COPYKAAP(KLNr)
 Set ^SYNC("C",KLNr)=$H
 Write " klaar"
 Quit
 
 ; Offerte
REMOFF(KLNr) New Node,OFFNr
 Set (Node,OFFNr)=""
 For  Set Node=$O(^KOFKL(KLNr,Node)) Quit:Node=""  Do
 .Kill ^KOFKL2(Node,KLNr)
 .For  Set OFFNr=$O(^KOFKL(KLNr,Node,OFFNr)) Quit:OFFNr=""  Do
 ..Kill ^KOFKL1(OFFNr,Node)
 Kill ^KOFKL(KLNr)
 Quit
 
COPYOFF(KLNr) 
 New OffNr
 Set OffNr=""
 For  Set OffNr=$O(^|sV|KOFKL(KLNr,"F",OffNr)) Quit:OffNr=""  Do
 .Quit:$$INTDATE^vhDTyp($P(^|sV|KOFKL(KLNr,"F",OffNr,1),D,2),"DK")<($H-365)
 .Merge ^KOFKL(KLNr,"F",OffNr)=^|sV|KOFKL(KLNr,"F",OffNr)
 .Set ^KOFKL1(OffNr,"F")=KLNr_D
 .Set ^KOFKL2("F",KLNr,OffNr)=""
 Quit
 
 ; Order
REMORD(KLNr) New Node,ORDNr
 Set (Node,ORDNr)=""
 For  Set Node=$O(^KOD(KLNr,Node)) Quit:Node=""  Do
 .For  Set ORDNr=$O(^KOD(KLNr,Node,ORDNr)) Quit:ORDNr=""  Do
 ..Kill ^KO1(ORDNr,Node)
 Kill ^KOD(KLNr)
 Quit
 
COPYORD(KLNr) 
 New ORDNr
 Set ORDNr=""
 For  Set ORDNr=$O(^|sV|KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 .Quit:$$INTDATE^vhDTyp($P(^|sV|KOD(KLNr,"F",ORDNr,1),D,2),"DK")<($H-365)
 .Merge ^KOD(KLNr,"F",ORDNr)=^|sV|KOD(KLNr,"F",ORDNr)
 .Set ^KO1(ORDNr,"F")=KLNr_D
 Quit
 
 ;Uitlevering
REMUL(KLNr) New ULNr,Node
 Set (ULNr,Node)=""
 For  Set Node=$O(^KUL(KLNr,Node)) Quit:Node=""  Do
 .For  Set ULNr=$O(^KUL(KLNr,Node,ULNr)) Quit:ULNr=""  Do
 ..Kill ^KU1(ULNr)
 Kill ^KUL(KLNr)
 Quit
 
COPYUL(KLNr) 
 New ULNr
 Set ULNr=""
 For  Set ULNr=$O(^|sV|KUL(KLNr,"F",ULNr)) Quit:ULNr=""  Do
 .Quit:$$INTDATE^vhDTyp($P(^|sV|KUL(KLNr,"F",ULNr,1),D,2),"DK")<($H-365)
 .Merge ^KUL(KLNr,"F",ULNr)=^|sV|KUL(KLNr,"F",ULNr)
 .Set ^KU1(ULNr,"F")=KLNr_D
 Quit
 
 ; Fakturen
REMFAK(KLNr)  New FAKNr,Node,Datum
 Set (FAKNr,Node,Datum)=""
 For  Set Node=$O(^KFA1(Node)) Quit:Node=""  Do
 .For  Set Datum=$O(^KFA1(Node,KLNr,Datum)) Quit:Datum=""  Do
 ..For  Set FAKNr=$O(^KFA1(Node,KLNr,Datum,FAKNr)) Quit:FAKNr=""  Do
 ...Kill ^KFA("F",FAKNr)
 .Kill ^KFA1(Node,KLNr)
 Quit
 Quit
 
COPYFAK(KLNr) 
 New Dat,EndDat,FAKNr
 Set EndDat=-($H-365)
 Set Dat="",FAKNr=""
 For  Set Dat=$O(^|sV|KFA1("F",KLNr,Dat)) Quit:Dat=""  Quit:Dat>EndDat  Do 
 .For  Set FAKNr=$O(^|sV|KFA1("F",KLNr,Dat,FAKNr)) Quit:FAKNr=""  Do 
 ..Merge ^KFA("F",FAKNr)=^|sV|KFA("F",FAKNr) 
 ..Set ^KFA1("F",KLNr,Dat,FAKNr)=""
 Quit
 
 ;Proforma
REMPRO(KLNr) New FAKNr,Noden,Datum
 Set (FAKNr,Node,Datum)=""
 For  Set Node=$O(^KFAP1(Node)) Quit:Node=""  Do
 .For  Set Datum=$O(^KFAP1(Node,KLNr,Datum)) Quit:Datum=""  Do
 ..For  Set FAKNr=$O(^KFAP1(Node,KLNr,Datum,FAKNr)) Quit:FAKNr=""  Do
 ...Kill ^KFAP("F",FAKNr)
 .Kill ^KFAP1(Node,KLNr)
 Quit
 
COPYPRO(KLNr) 
 New Dat,EndDat,PRONr
 Set EndDat=-($H-365)
 Set Dat="",PRONr=""
 For  Set Dat=$O(^|sV|KFAP1("F",KLNr,Dat)) Quit:Dat=""  Quit:Dat>EndDat  Do 
 .For  Set PRONr=$O(^|sV|KFAP1("F",KLNr,Dat,PRONr)) Quit:PRONr=""  Do 
 ..Merge ^KFAP("F",PRONr)=^|sV|KFAP("F",PRONr) 
 ..Set ^KFAP1("F",KLNr,Dat,PRONr)=""
 Quit
 
 ; Klantgegevens : Boekhouding, Openstaandefakturen
REMBOEK(KLId) 
 New I,Temp,Key,Error
 Set Error=0
 For I=0:1:6 Do
 .Set:'$D(^KKL(KLId,I)) Error=1
 .Set Temp(I)=$G(^KKL(KLId,I))
 Set Key="L"
 For  Set Key=$O(^KKL(KLId,Key)) Quit:$E(Key,1)'="L"  Set Temp(Key)=^KKL(KLId,Key)
 Kill ^KKL(KLId)
 Merge:'Error ^KKL(KLId)=Temp
 Quit
 
COPYBOEK(KLId) 
 Kill ^KKL(KLId)
 Merge ^KKL(KLId)=^|sV|KKL(KLId)
 Quit
 
 ;Verkoopanalyze
REMKAAP(KLNr) 
 Kill ^KKAAP(KLNr)
 Kill ^PVSTAT20(KLNr)
 Quit
 
COPYKAAP(KLNr) 
 Merge ^KKAAP(KLNr)=^|sV|KKAAP(KLNr)
 Merge ^PVSTAT20(KLNr)=^|sV|PVSTAT20(KLNr)
 Quit
 
 ; Prijsuitzonderingen
REMPUTZ(KLNr) 
 Do INDPUTZ("N",KLNr,1)
 Kill ^KLPUTZ("N",KLNr)
 Do INDPUTZ("S",KLNr,1)
 Kill ^KLPUTZ("S",KLNr)
 Quit
 
COPYPUTZ(KLNr) 
 Merge ^KLPUTZ("N",KLNr)=^|sV|KLPUTZ("N",KLNr)
 Do INDPUTZ("N",KLNr,0)
 Merge ^KLPUTZ("S",KLNr)=^|sV|KLPUTZ("S",KLNr)
 Do INDPUTZ("S",KLNr,0)
 Quit
 
INDPUTZ(NoSa,KLNr,Remove) 
 New HoofdGr,Groep,SubGroep,PRNr
 Set (HoofdGr,Groep,SubGroep,PRNr)=""
 For  Set HoofdGr=$O(^KLPUTZ(NoSa,KLNr,HoofdGr)) Quit:HoofdGr=""  Do
 .For  Set Groep=$O(^KLPUTZ(NoSa,KLNr,HoofdGr,Groep)) Quit:Groep=""  Do
 ..For  Set SubGroep=$O(^KLPUTZ(NoSa,KLNr,HoofdGr,Groep,SubGroep)) Quit:SubGroep=""  Do
 ...For  Set PRNr=$O(^KLPUTZ(NoSa,KLNr,HoofdGr,Groep,SubGroep,PRNr)) Quit:PRNr=""  Do
 ....Set:'Remove ^KLPUTZ("I"_NoSa,HoofdGr,Groep,SubGroep,PRNr,KLNr)=""
 ....Kill:Remove ^KLPUTZ("I"_NoSa,HoofdGr,Groep,SubGroep,PRNr,KLNr)
 Quit
 
 ;Pakket
REMPAK(KLNr) New PAKRef,PAKNr
 Set (PAKRef,PAKNr)=""
 For  Set PAKRef=$O(^PAKKET("IK",KLNr,PAKRef)) Quit:PAKRef  Do
 .For  Set PAKNr=$O(^PAKKET("IK",KLNr,PAKRef,PAKNr)) Quit:PAKNr Do
 ..Do DELOBJ^PAKKET(PAKNr)
 Quit
 
COPYPAK(KLNr) 
 New PAKNr,Ref
 Set (Ref,PAKNr)=""
 For  Set Ref=$O(^|sV|PAKKET("IK",KLNr,Ref)) Quit:Ref=""  Do
 .Set PAKNr=^|sV|PAKKET("IK",KLNr,Ref)
 .Merge ^PAKKET("D",PAKNr)=^|sV|PAKKET("D",PAKNr)
 ; Indexen worden opgebouwd in COPYALL door REBUILd^PAKKEt
 Quit
 
DISP(OneIPNr) 
 Do INIT^vhPRINTER("S",60,"CA;S")
 Set (KLNr,IPNr)=""
 For  Set IPNr=$O(^SYNC("KV",IPNr)) Quit:'IPNr  Do
 .If $G(OneIPNr),IPNr'=OneIPNr Quit
 .Write !,@FMTB,"  Vaste klanten voor ",$P(^vhUSER("D",IPNr),D,2),@FMTb,!!
 .For  Set KLNr=$O(^SYNC("KV",IPNr,KLNr)) Quit:KLNr=""  Do
 ..If '$D(^KK1(KLNr)) Kill ^SYNC("KV",IPNr,KLNr)  Quit
 ..Set KLNm=$P(^KKL(^KK1(KLNr),0),D,2)
 ..Write "  ",KLNr,"  ",KLNm,!
 .Write #
 If $I=$P Write !,"Druk op een toets om verder te gaan" Read K
 Do CLOSE^vhPRINTER
 Quit