SYNCTIJD ; Syncronisatie bidirectioneel: Tijd [ 12/06/2003  12:27 PM ]
 
TRAP If $P($ZERROR,">")="<NOSYS" Quit  ; Niets aan de hand, alleen remote is niet gekend
 If $P($ZERROR,">")="<NAMESPACE" Quit  ; Niets aan de hand, alleen remote is niet gekend
 If $P($ZERROR,">")="<NETWORK" Quit  ; Niets aan de hand, alleen remote is niet gekend
 ZQuit  ; Ga naar de andere error-handler
 
 ; TIJD wordt continu bijgewerkt, dit in tegenstelling tot Verslag en Mail
ACTREM(IPNr) ; Is de remote actief
 ; Set de local sModif op
 New PortVol,ActRem
 Set ActRem=0
 If $L($G(sRemVol)) Quit 0 ; De gebruiker werkt reeds op een remotevolume
 Set PortVol=$P($G(^vhUSER("D",IPNr,"T")),D,3)
 Quit:'$L(PortVol) 0 ; De gebruiker heeft geen remote volume
 Do 
 .Set $ZT="TRAP^SYNCTIJD" 
 .Set:$D(^|PortVol|TIJD) ActRem=1
 Quit ActRem
 
TIJDDEL(IPNr,Datum,Tijd) 
 Quit:'$D(sRemVol)
 Set $ZT="TRAP^SYNCTIJD" 
 Kill ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)
 Quit
 
TIJDNEW(IPNr,Datum,Tijd,Rec) 
 Quit:'$D(sRemVol)
 Set $ZT="TRAP^SYNCTIJD" 
 Set ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)=Rec
 Quit
 
TIJD(IPNr) 
 New Datum,Tijd,VolId,Rec,RemRec
 Set Datum=$H-32 ;(1 maand in het verleden)
 Set Tijd=""
 ; Update van remote naar ADM
 For  Set Datum=$O(^TIJD("D",IPNr,Datum)) Quit:Datum=""  Do
 .For  Set Tijd=$O(^TIJD("D",IPNr,Datum,Tijd)) Quit:Tijd=""  Do
 ..Set Rec=^TIJD("D",IPNr,Datum,Tijd)
 ..Set RemRec=$G(^|sRemVol|TIJD("D",IPNr,Datum,Tijd))
 ..If $L(RemRec),$P(Rec,D,10)'=$P(RemRec,D,10) Do  ; Verschillend van sIdVol -> Move naar vrije plaats
 ...Set T=Tijd
 ...For  Set T=T+1 Quit:'$D(^|sRemVol|TIJD("D",IPNr,Datum,T))
 ...Set ^|sRemVol|TIJD("D",IPNr,Datum,T)=RemRec
 ..If Rec'=RemRec Do
 ...Set ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)=Rec
 ; Update van ADM naar remote
 For  Set Datum=$O(^|sRemVol|TIJD("D",IPNr,Datum)) Quit:Datum=""  Do
 .For  Set Tijd=$O(^|sRemVol|TIJD("D",IPNr,Datum,Tijd)) Quit:Tijd=""  Do
 ..Set Rec=$G(^TIJD("D",IPNr,Datum,Tijd))
 ..Quit:$L(Rec)  ; Gelijke tijdstippen zijn reeds behandeld
 ..Set RemRec=^|sRemVol|TIJD("D",IPNr,Datum,Tijd)
 ..If $P($P(RemRec,D,10),";",3)=$ZU(5) Do  ; Verwijder !!!
 ...Kill ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)
 ..Else  Do
 ...Set $P(RemRec,D,10)=sIdVol
 ...Set ^TIJD("D",IPNr,Datum,Tijd)=RemRec
 ...Set ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)=RemRec
 Quit
 
CLEAN(IPNr,sRemVol) 
 New Datum,Tijd,VolId,Rec,RemRec
 Set Datum=$H-100 ;(+/- 3 maand in het verleden)
 Set Tijd=""
 ; Update van remote naar ADM
 For  Set Datum=$O(^TIJD("D",IPNr,Datum)) Quit:Datum=""  Do
 .Set MemRec="",MemTijd=""
 .For  Set Tijd=$O(^TIJD("D",IPNr,Datum,Tijd)) Quit:Tijd=""  Do
 ..Set Rec=^TIJD("D",IPNr,Datum,Tijd)
 ..If $P(MemRec,D,1,9)=$P(Rec,D,1,9) Do  ; Dubbel
 ...Kill ^|sRemVol|TIJD("D",IPNr,Datum,Tijd)
 ...Kill ^TIJD("D",IPNr,Datum,Tijd)
 ...Write !,"  ",MemTijd,":",MemRec,!,"KK",Tijd,":",Rec,!
 ..Else  Do
 ...Write !,"**",Tijd,":",MemTijd,!
 ...Set MemRec=Rec,MemTijd=Tijd
 Quit