cA518(QU) ;Raadplegen menu ; %A518 [ 01/04/01  3:42 PM ]
 ;
T0 ; Raadplegen menu ;
T1 ;Geen toegang tot dit systeem;
 ;
T0F ; Consultation menu ;
T1F ;Pas d'accès à ce système;
 ;
T0E ; Consultation of menu ;
T1E ;You have no access to this system;
 ;
 ; Initialisatie
1 N QT,QTU,QZ,QL,oQ,oQN,QM,I,J,T,i
 S oQ=Q,oQN=QN,QM=""
 S $ZT="TRAP^cAN000"
 ;
 ; initialen & taalcode
11 S I=QU,QL=""
 I QU'?1.N S I=$$UI1^cAFA1("USR",101,QU) 
 I '$L(I) G 4
 S K=$$SIGN^cAFA1("USR",I,0)
 S QU=$P(K,D),QU(1)=I,QU(2)=$P(K,D,2),QT=$TR($P(K,D,9),"N"),QTU=$S($L(QT):$F("FDE",QT),1:1)
 S i=$P(^(1),D,26) I i S QZ=i
 ;
 ; login afh. van systeem
2 S J=I_" ",(Q,QM,QN)=""
21 S J=$O(^DATA(0,"USR_SYS.QQM",J)) G 4:$P(J," ")'=I,21:'$D(^(J,0)),21:$P(^(0),D,30)
 S T=$P(^(0),D,2) G 21:T="",21:'$D(^DATA(0,"SYS.QQM",T,0)),21:$P(^(0),D,30)
 S Q=$P(^(0),D,2),QM=$P(^(0),D,3) G 21:Q="",21:QM=""
 S T=$P(^(0),D) G 21:T="",21:'$D(^DATA(0,"SYS",T,0)),21:$P(^(0),D,30)
29 G 21:$P(^(0),D)'=$ZU($ZV'["MSM"*5),21:'$D(@("^"_Q_"BA(""MENU"",QM,0)")),21:'$D(@("^"_Q_"BA(99,1)")) S QN=^(1)
 ;
 ; prioriteiten
3 S J=I_" ",QL=""
31 S J=$O(^DATA(0,"USR_PRI",J)) G 39:$P(J," ")'=I,31:'$D(^(J,0)),31:$P(^(0),D,30)
 S T=$P(^(0),D,2) G 31:T="",31:'$D(^DATA(0,"PRI",T,0)),31:$P(^(0),D,30)
 S QL=QL_T_" " G 31
39 D  S K=0 G 4
 . S J=I_" "                   ; alle profielen per initialen
 . F  S J=$O(^DATA(0,"USR_PRO",J)) Q:$P(J," ")'=I  I $D(^(J,0)) D
 .. I $P(^(0),D,30) Q
 .. N II S II=$P(^(0),D,2) I II="" Q
 .. I '$D(^DATA(0,"PRO",II,0)) Q
 .. I $P(^(0),D,30) Q
 .. N JJ S JJ=II_" "           ; alle prioriteiten per profiel
 .. F  S JJ=$O(^DATA(0,"PRO_PRI",JJ)) Q:$P(JJ," ")'=II  I $D(^(JJ,0)) D
 ... I $P(^(0),D,30) Q
 ... S T=$P(^(0),D,2) I T="" Q
 ... I '$D(^DATA(0,"PRI",T,0)) Q
 ... I $P(^(0),D,30) Q
 ... I " "_QL'[(" "_T_" ") S QL=QL_T_" "
 ;
4 I '$L(Q)!'$L(QM) S K=$P($T(@("T1"_QT)),U,2) D TXT^cAFA1(250) G YZ
 D ^cA5181
 ;
YZ S Q=oQ,QN=oQN
 Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84