cA704 ;Bestand inlezen ;%A703 ;do naar %A708 ; [ 01/04/01  3:16 PM ]
 G YZ
 ;
T0 ;Bestand inlezen ;
T1 ;Foutieve bestandslocatie ;
T2 ;Het opgegeven formaat klopt niet ;
T3 ;Fout bij het lezen van de schijf ;
T4 ;De ingelezen records zijn te groot ;
T5 ;Werkwijze :;1. druk op [ F6 ];2. file is ;
T6 ;Het ingelezen bestand is onvolledig ;
T7 ;Even geduld;
 ;
T0F ;Importation d'un fichier ;
T1F ;Lieu du fichier fautif ;
T2F ;Le format spécifié n'est pas correcte ;
T3F ;Erreur à la lecture de la disquette ;
T4F ;Les records sont trop larges ;
T5F ;Mode d'emploi :;1. appuyez la touche [ F6 ];2. le fichier est ;
T6F ;Le fichier importé est incomplet ;
T7F ;Un instant;
 ;
T0E ;Import file ;
T1E ;Inaccurate location ;
T2E ;The file type is not correct ;
T3E ;Error reading disk ;
T4E ;Imported records are to long ;
T5E ;Procedure :;1. press [ F6 ];2. file is ;
T6E ;The imported file is incomplete ;
T7E ;One moment;
 ;
S1 S S=$L(RS)-1 U HFS R A#S S ZA=$ZA,ZB=$ZB,ZC=$ZC U 0
S1Z K S Q
 ;
 ; OL/OM/OC + NT
1 D:$G(QW) QW
 I $ZV'["MSM" G 100
 ; MSM
 S HFS=$$HFS^cQ9 I HFS<51!(HFS>54) G Y
10 O HFS:(B:"R") U HFS S ZA=$ZA U 0 I ZA=-1 C HFS D E1 G YZ
11 I RS'="" O HFS:(B:"R"::::$E(RS)) U HFS S ZA=$ZA U 0 I ZA=-1 C HFS D E2 G YZ
12 S K="" I 'RL S RL=511
13 U HFS R A#RL S ZA=$ZA,ZB=$ZB,ZC=$ZC U 0 I ZC=-1 C HFS G YZ
15 I ZA=-1!ZC C HFS D E3 G YZ
17 S K=K_A G 25:$L(RS)<2 D S1 I ZC=-1 C HFS G YZ
19 I ZA=-1!ZC C HFS D E3 G YZ
21 G 25:$E(RS)_A=RS I $L(K)+$L(A)-$L(RS)>511 C HFS D E4 G YZ
23 S K=K_$E(RS)_A G 17:A="",13
25 I $L(K)=RL!$L(RS) S TVG=TVG+1,^HULP("RC",Q,TNR,TVG)=$$NT2D^cQCV($E(K,1,511)),$P(^(0),D,4)=TVG-9,FP=2203 W @F,TVG-9,@F1 I $L(K)-$L(RS)>511 C HFS D E4 G YZ
27 G 12:ZC=0,YZ
 ;
 ; Caché
100 S HFS=$TR(B,"/","\") C HFS O HFS:("RS"):1 I '$T U 0 C HFS D E1 G YZ
 S $ZT="CERR"
120 U HFS R A U 0 I $L(A)>511 C HFS D E4 G YZ
 S TVG=TVG+1,^HULP("RC",Q,TNR,TVG)=A,$P(^(0),D,4)=TVG-9,FP=2203 W @F,TVG-9,@F1
 G 120
 ;
S2 S S=$L(RS)-1 R A#S:10
S2Z K S Q
 ;
 ; XT/XU/XX
3 S FP=501 W @F,@F1,! F K=2:1:5 W !!?2,$P($T(@("T5"_QT)),U,K) I K=4 W B
31 S FP=1023 W @FS S FP=2203 W @F I $L(RS) S $ZT="ER" U 0:(::::::::$E(RS)) S $ZT="^cA405"
33 S K="",TMO=0 I 'RL S RL=511
35 R A#RL:10 W $$CR^cA334
37 S K=K_A S TMO=$S($L(A)!$T:0,1:TMO+1) I TMO G 35:TMO<6&(TVG=9),Y:TMO
39 G 45:$L(RS)<2 D S2
41 G 45:$E(RS)_A=RS I $L(K)+$L(A)>510 D E4 G Y
43 S K=K_$E(RS)_A G 35
45 I $L(K)=RL!$L(RS) S TVG=TVG+1,^HULP("RC",Q,TNR,TVG)=$$NT2D^cQCV($E(K,1,511)),$P(^(0),D,4)=TVG-9 I $L(K)>511 D E4 G Y
47 G 35:TMO,33
 ;
 ; PR/PS/PT/PU/RF/RG/RW
5 G:'$D(^cZKRX) 4^cA703 D KRGL^cZKRUM
51 S FP=2203 W @F,@F1,$P($T(@("T7"_QT)),U,2) I $E(B,2)'=":" D E1 G YZ
53 S R=$E(B,3,99),R1=$L(R,D) I R1 S R=$P(R,D,R1)
55 S RFN=$P(R,"."),REX=$P(R,".",2),SWREX="" I '$L(RFN) D E1 G YZ
57 D S5:'$L(REX) L +@KRGL@(RFN,REX):5 E  S R=14 D F2 G YZ
59 K @KRGL@(RFN,REX)
 ;
6 I SCR=3!(SCR=4) W ESC,"SENDFILE KERMIT """,B,"""",$$CR^cA334
61 I SCR=5 W ESC,"KSEND ",B,$$CR^cA334
 ;
7 D ^cA338 K  D INITPAR^cZKR S B="\",S=";",TTY=0 U 0:(::::4096:16384)
71 D TTYON^cZKR I 'E D ^cZKRR,TTYOFF^cZKR
73 ; F I=1:1:10 R K:1 W "."
75 U 0:(0::::4+4096+262144:1+16384+524288+8388608:::$C(13)) F I=1:1:3 R K:1 W "."
77 D ^cA339 I $L(SWREX) W:SCR=3!(SCR=4) ESC,"DOS ""REN "_B_" "_RFN_"""",$$CR^cA334 W:SCR=5 ESC,"REN "_B_" "_$P(B,"."),$$CR^cA334
78 D:$G(QW) QW S MSDOS=B D ^cA708 I 'OK S K=$P($T(@("T6"_QT)),U,2) D F1
79 G YZ
 ;
Y S TMO=0
YA R A#511:1 W $$CR^cA334 S TMO=$S($L(A)!$T:0,1:TMO+1) I TMO<3 G YA
YB D:$G(QW) QW U 0:(::::::::$C(13)) S FP=124 W @FS
YZ L -^HULP("RC",Q,TNR) Q
 ;
QW W /CUP(22,1),/ED(0) D W^cA612 Q
 ;
S5 I SCR=3!(SCR=4) W ESC,"DOS ""DEL "_B_".REN""",$$CR^cA334 H 3 W ESC,"DOS ""REN "_B_" "_RFN_".REN""",$$CR^cA334 H 3
S5A I SCR=5 W ESC,"DEL "_B_".REN",$$CR^cA334 H 1 W ESC,"REN "_B_" "_B_".REN",$$CR^cA334 H 1
S5B S (REX,SWREX)="REN",B=B_"."_REX
S5Z Q
 ;
E1 S K=$P($T(@("T1"_QT)),U,2) D F1 Q
E2 S K=$P($T(@("T2"_QT)),U,2) D F1 Q
E3 S K=$P($T(@("T3"_QT)),U,2) D F1 Q
E4 S K=$P($T(@("T4"_QT)),U,2) D F1 Q
 ;
 ; Error-trapping Caché
CERR C HFS U 0
 I $ZE["<TOOMANYFILE>" D E3 G YZ
 I $ZE["<READ>" D E3 G YZ
 I $ZE["<ENDOFFILE>" G YZ
 ZQ 1 I $ZT'="" G @$ZT
 Q
 ;
F1 S R=250
F2 D:$G(QW) QW D TXT^cAFA1(R)
FZ K R Q
 ;
ER S $ZT="^cA405" D E2 G Y
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84