cABR ;Algemene functies voor Routines ;cABR ; [ 25/02/2002 - 11:43:35 - 58860,42215 ]
 Q
 ;
 ; Hoe gebruiken?
 ; -------------
 ; + eerst gewenste routines selecteren via D SELECT^cABR
 ; + achteraf geselecteerde routines opvragen via $$NEXT^cABR(routine.ext)
 ; 
 ; ----------------------------------------------------------------------------
 ; Selecteren
 ; ----------------------------------------------------------------------------
SELECT D ^%RSETN()
SELECTZ Q
 ;
 ; ----------------------------------------------------------------------------
 ; Volgende routine
 ; ----------------------------------------------------------------------------
NEXT(R) S $ZT="TRAP^cAN000"
 N ROU,EXT
 S R=$G(R),ROU=$P(R,"."),EXT=$P(R,".",2)
 I $L(EXT) G NEXTR
NEXTE S EXT=$O(^mtemp(%msub,"@",EXT)) I EXT="" G NEXTY          ; extentie
NEXTR S ROU=$O(^mtemp(%msub,"@",EXT,1,ROU)) I ROU="" G NEXTE    ; routine
NEXTY S R="" I $L(ROU),$L(EXT) S R=ROU_"."_EXT
 I R="" K ^mtemp(%msub,"@")
NEXTZ Q R
 ;
 ; ----------------------------------------------------------------------------
STUDIO W !!,"Routines editeren via Caché Studio",!
 ; ----------------------------------------------------------------------------
 D SELECT
 S $ZT="TRAP^cAN000"
 N K,R I '$D(boot) D MASTER^cQ5
 S R=""
STUDIOA L  S R=$$NEXT(R) I R="" G STUDIOZ
 W !,R L ^ROUTINE($P(R,".")):2 E  W " is in gebruik ..." H 2 G STUDIOA
 S K="cn_iptcp://"_boot_"/"_cs_"/"_R
 D START^cANR0("Cstudio") W K,! D STOP^cANR0
 L  W !,"Waiting for L ^ROUTINE(""",$P(R,"."),""") ... "
 H 3 L ^ROUTINE($P(R,".")) G STUDIOA
STUDIOZ Q
 ;
 ; ----------------------------------------------------------------------------
PRINT W !!,"Routines printen",!
 ; ----------------------------------------------------------------------------
 D SELECT
 S $ZT="TRAP^cAN000"
 N I,J,P,R I '$D(boot) D MASTER^cQ5
 I '$D(F70) D ^cA604
 D ^cA106,^cA105
 S R="",P=0,P("L")="F I=1:1 S J=$T(+I) Q:'$L(J)  W !,$P(J,"" ""),$C(9),$P(J,"" "",2,999)"
PRINTA S R=$$NEXT(R) I R="" G PRINTY
 I 'P D ^cAN3223("",1,">80","") I K="-" G PRINT
 I 'P X F70 W @F80 S P=1
 W !,boot,",",cs,":",R,?100,DT,?120,TD
 X "ZL @$P(R,""."") X P(""L"")"
 W $$FF^cA334
 G PRINTA
PRINTY I P X F71
PRINTZ Q
 ;
ZZ ; 24.01.02 - VJ * V7.91