cAFA2(R0,LN,KL,RL,RC,KEYS)   ;STANDAARD INPUT zonder window en driver;%AFA2 ; [ 06/30/00  3:30 PM ]
 ;
T0 ;STANDAARD INPUT zonder window en driver;
 ;
T0F ;STANDAARD INPUT zonder window en driver;
 ;
T0E ;STANDAARD INPUT zonder window en driver;
 ;
1 N R1,RI,RJ
11 S R1=1,RI=0,RJ=$C(250),$P(RJ,RJ,RL)=RJ
13 S R0=$E(R0_RJ,1,RL),KEYS=D_KEYS_D
19 U 0:(0::::1+4+64+4096+65536:524288+4194304:::$C(13))
 ;
 ; extra input-venster
2 ;  I RL D O^cA612(LN,KL,1,RL,0,1,1,1) W /SGR(RC)
 ;
 ; tonen volledige input
3 I RL W /CUP(LN,KL),/WCSGR(RC,4),$TR(R0,$E(RJ),$C(U("D","RT"))),/WSCRON
 ;
 ; positionering cursor
4 I RL W /CUP(LN,KL+R1-1) I RI W /WCSGR(5,0)
41 R *K S RZA=$ZA,RZB=$ZB\256,RZC=$ZC                   ; lees 1 karakter
43 I RZC W $C(7) G 1                                       ; foutdetektie
45 I K>0&'RZB S:K<27 RZB=K+64 S:K=27!(K=127) RZB=K      ; ^x / Esc / <--
47 I RZB S K="",RK=$G(U("D",RZB),0) G 6
 ;
 ; gewone input
5 S RK=$C(K) I RK?1C!(RK=D)!'RL D S2 G 41
51 I RI,$E(R0,RL)'=$E(RJ) D S2 G 41
53 S R0=$S(R1>1:$E(R0,1,R1-1),1:"")_RK_$E(R0,R1+1-RI,RL-RI)
55 I R1<RL S R1=R1+1
57 G 3:RI W RK G 4
 ;
 ; speciale toetsen
6 I RK=3 S RK=27
600 I RK'=28,KEYS[(D_RK_D) G Y
601 ;                                                    ; F1
620 ;                                                    ; F20
621 I RK=21 D  G 3                                       ; Insert
 . I 'RL D S2
 . E  S RI='RI I 'RI W /WCSGR(25,0)
622 I RK=22 D  G 3                                       ; Delete
 . I RL S R0=$S(R1>1:$E(R0,1,R1-1),1:"")_$E(R0,R1+1,RL)_$E(RJ)
 . E  D S2
623 I RK=23 D  G 3:RI,4                                  ; Home
 . I RL S R1=1
 . E  D S2
624 I RK=24 D  G 3:RI,4                                  ; End
 . I RL S R1=$F(R0_RJ,RJ)-RL I R1>RL S R1=RL
 . I 'RL D S2
625 I RK=25,'RL G Y                                      ; PgUp
626 I RK=26,'RL G Y                                      ; PgDn
627 I RK=27,'RL G Y                                      ; Escape
628 I RK=28 D  G Y                                       ; Enter
 . I RL S K=$P(R0_RJ,RJ),K=$TR(K,$E(RJ)," ")
629 I RK=29,'RL G Y                                      ; Tab     
630 I RK=30 D  G 3                                       ; Backspace
 . I RL,R1>1 S R0=$S(R1>2:$E(R0,1,R1-2),1:"")_$E(R0,R1,RL)_$E(RJ),R1=R1-1
 . E  D S2
631 I RK=31,'RL G Y                                      ; Pijl Omhoog
632 I RK=32,'RL G Y                                      ; Pijl Omlaag
633 I RK=33 D  G 3:RI,4                                  ; Pijl Links
 . I RL,R1>1 S R1=R1-1
 . E  D S2
634 I RK=34 D  G 3:RI,4                                  ; Pijl Rechts
 . I RL,R1<RL S R1=R1+1
 . E  D S2
 ;
7 D S2 G 41
 ;
Y ;  I RL D C^cA612
YZ U 0:(0:::::1+64+2097152+8388608:::$C(13)) Q
 ;
S2 W $C(7) Q
 ;
 ; opladen driver
DRV N R1,R2,R3 D OFF^cMODESET(13),MASTER^cQ5:'$D(boot) S io=$G(io,$$IO^cQ5)
DRVA S R1=$P($G(^cLOG(boot,"DEV",io)," "),D),R2=1
DRVB I $D(^cLOG(0,"DRV",R1)),$L(^(R1)) S R2=^(R1)
DRVC S R1="" F  S R1=$O(^cLOG(0,"DRV",R2,R1)) Q:R1=""  S R3=^(R1) I R3<5!(R3>20) S U("D",R1)=R3
DRVZ Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84