cAFO3 ;OUTPUT FORMATEN ;%AFO3 ; [ 01/04/01  7:57 AM ]
 ;
T0 ;Outputformaten ;
T1 ;Stock;Bestelling;Orders;
T2 ;aankoop      ;verkoop      ;correctie in ;correctie uit;transfert in ;transfert uit;productie    ;samenstelling;9;10;neg. aankoop ;neg. verkoop ;
 ;
T0F ;Formats externes ;
T1F ;Stock;Com.frn.;Ordres;
T2F ;achat        ;vente        ;corr. entrée ;corr. sortie ;transf.entrée;transf.sortie;production   ;composition  ;9;10;achat nég.   ;vente nég.   ;
 ;
T0E ;Outputformats ;
T1E ;Stock;Delivery;Orders;
T2E ;purchase     ;sales        ;corr. in     ;corr. out    ;transfert in ;transfert out;production   ;composition  ;9;10;neg. purchase;neg. sales   ;
 ;
BEW(K) ; beweging
 N R
 S R=$$Z^cAFO1 I K S R=$P($T(@("T2"_QT)),U,K+1) I R="" S R=$$Z^cAFO1
 Q R
 ;
COM(DMS,UI1)       ; code + oms. taalcode gebruiker
 N R,RQ2,UDD,UREF,UQC,USC
 D DMS^cAN000("UQC","USC",DMS)
 S R="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC,"DATA")) D
 . S UDD=^("DATA"),UREF=^("DATA","REF"),RQ2=$G(^("OUD"))
 . I UI1="" S R=$$Z^cAFO1
 . I $L(UI1) S R=UI1_" ?" D
 .. I UDD=1 S UI1=$G(@RQ2@(UI1))
 .. I UDD=2 S UI1=UI1_" "
 .. I $L(UI1),$D(@UREF) D
 ... I UDD<5 S R=$P(@UREF@(0),D)_" "_$P(^(0),D,QTU*10-8)
 ... I UDD=5 S R=$P(@UREF,D)_" "_$P(^(UI1),D,QTU*10-8)
 Q R
 ;
DET(UI1,UPRDMS) ; detailgegevens bij B,O,S,V
 N R,R0
 S UPRDMS=$G(UPRDMS,"PR")
 D TOP^cAN210 F R0=1:1:3 D
 . S R=$O(UTOP(""),-1)\1+1
 . S UTOP(R)=R0_D_59_D_$P($T(@("T1"_QT)),U,R0+1)_D_4
 . S UTOP(R+.1)=R0_D_69_D_": "_$$SIG^cAFA1(UPRDMS,UI1,$P("114\117\309",D,R0))_D_0
 S OK=0 Q
 ;
IPL(K,LEN,DEC,OPL) ; decimalen + oplijnen
 N R S R=K
 I '$G(ZONDERIP) S R=$TR($J(K,LEN,DEC),".",",") I DEC,OPL D
 . N R0 S R0=$E($TR(1E6,"1",","),1,DEC+1)
 . I R[R0 S R=$P(R,R0)_$J("",$L(R0))
 Q R
 ;
KO(UQC,USC,UI1)    ; code + omschrijving code
 N R,UREF
 S R=$$Z^cAFO1 I $L(UI1) D
 . S R=UI1 I $E(UI1,$L(UI1))'=" " S R=R_" "
 . I $L(UQC),$L(USC),$D(^DMC(UQC,USC,"DATA","REF")) S UREF=^("REF") D
 .. I $D(@UREF) S R=R_$P(@UREF,D)
 .. E  S R=R_"?"
 Q R
 ;
PCMKOM(DMS,UI1,TAAL) ; productcode + merk + oms. taalcode gebruiker
 N R,R0,R1,RT,UDD,UREF,UQC,USC
 D DMS^cAN000("UQC","USC",DMS)
 S R="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC,"DATA","REF")) D
 . S UREF=^("REF")
 . I UI1="" S R=$$Z^cAFO1
 . I $L(UI1) S R=UI1_" ?" D
 .. I $L(UI1),$D(@UREF@(0)) D
 ... S R0=+$P(@("^"_Q_"PR(0,19)"),D,36),RT=^(90) I 'R0 S R0=10
 ... S R=$P(@UREF@(0),D),R0=$E(R_$J("",R0),1,R0),R1=$P($G(^(1)),D,25)
 ... S R=$P(RT,D,$G(TAAL,QTU)),R=$P($G(^(R\100-1)),D,R#100)
 ... I R1 S R0=R0_" "_$$SIG^cAFA1("PR.MK",R1,QTU*10-8+100)
 ... S R=R0_" "_R
 Q R
 ;
PCOM(DMS,UI1,TAAL) ; productcode + oms. taalcode gebruiker
 N R,R0,RT,UDD,UREF,UQC,USC
 D DMS^cAN000("UQC","USC",DMS)
 S R="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC,"DATA","REF")) D
 . S UREF=^("REF")
 . I UI1="" S R=$$Z^cAFO1
 . I $L(UI1) S R=UI1_" ?" D
 .. I $L(UI1),$D(@UREF@(0)) D
 ... S R0=+$P(@("^"_Q_"PR(0,19)"),D,36),RT=^(90) I 'R0 S R0=10
 ... S R=$P(@UREF@(0),D),R0=$E(R_$J("",R0),1,R0)
 ... S R=$P(RT,D,$G(TAAL,QTU)),R=R0_" "_$P($G(^(R\100-1)),D,R#100)
 Q R
 ;
POMS(DMS,UI1,TAAL) ; productoms. taalcode gebruiker
 N R,RT,UDD,UREF,UQC,USC
 D DMS^cAN000("UQC","USC",DMS)
 S R="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC,"DATA","REF")) D
 . S UREF=^("REF")
 . I UI1="" S R=$$Z^cAFO1
 . I $L(UI1) S R=UI1_" ?" D
 .. I $L(UI1),$D(@UREF@(0)) D
 ... S RT=@("^"_Q_"PR(0,90)")
 ... S R=$P(@UREF@(0),D)
 ... S R=$P(RT,D,$G(TAAL,QTU)),R=$P($G(^(R\100-1)),D,R#100)
 Q R
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84