cAN004(OUT,Q1,DIR) ;VOLGENDE ITEM ;%AN004 ; [ 12/29/00  4:28 PM ]
 ;
T0 ;Volgende item ;
 ;
T0F ;Sujet suivant ;
 ;
T0E ;Next item ;
 ;
1 N R1,R2,UDD,UI01,IREF,Q2,UQC,UREF,USC
11 D DMS^cAN000("UQC","USC",Q1)
13 S UDD=^DMC(UQC,USC,"DATA"),UREF=^("DATA","REF"),IREF=^("INDEX"),Q2=$G(^("OUD"))
15 I $G(DIR)'=-1 S DIR=1
17 S UI01=$G(@OUT) G 3:KEU(Q1),4:$P(KEU(Q1),D)="U"
 ;
 ; enkele specifieke
2 S R1=$G(LIM3(Q1))
21 S R1=$O(^HULP(boot,$J,Q1,R1),DIR)
23 I $L(R1) S UI01=^(R1),LIM3(Q1)=R1 D S1 G Y:$L(UI01),2
25 S UI01="" K LIM3(Q1) G Y
 ;
 ; via ... van ... tot ...
3 S R1=$G(LIM3(Q1)),R2="" I UDD'=5 S R2=$P(^DMC(UQC,USC,"INDEX",$P(KEU(Q1),D)),D)
31 I R1="",$L(LIM1(Q1)) D  I $L(UI01) G Y
 . S R1=LIM1(Q1)
 . I UDD=5 S UI01=R1
 . E  S UI01=$G(@IREF@(R2,R1))
 . S LIM3(Q1)=R1 D S1
33 I UDD=5 S R1=$O(@IREF@(R1),DIR)
 E  S R1=$O(@IREF@(R2,R1),DIR)
35 I $L(R1) S UI01=$S(UDD=5:R1,1:^(R1)),LIM3(Q1)=R1 D  I $L(R1) D S1 G Y:$L(UI01),3
 . I DIR=1,R1]LIM2(Q1) S R1=""
 . I DIR=-1,LIM1(Q1)]R1 S R1=""
37 S UI01="" K LIM3(Q1) G Y
 ;
 ; via utili-data
4 I LIM2(Q1) D INT^cANU11(LIM1(Q1),"X") S LIM2(Q1)=""
41 S R1=$G(LIM3(Q1)),R1=$O(^UTILI(Q,"SEL",LIM1(Q1),R1),DIR)
43 I $L(R1) S UI01=^(R1),LIM3(Q1)=R1 D  D S1 G Y:$L(UI01),41
 . I UDD=1 D  I $L(UI01) S UI01=$G(@Q2@(UI01))
 .. I UI01[" " S UI01=$P(UI01," ",2)
 . I UDD=2 S UI01=$P(UI01," ")_" "
45 S UI01="" K LIM3(Q1) D  G Y
 . N EXTWIJZ S EXTWIJZ=1 D W^cAN220("SEL",0,LIM1(Q1),125,DT)
 ;
Y S @OUT=UI01
YZ Q
 ;
 ; test op geldigheid
S1 N UI1 S UI1=UI01 I $L(UI1),'$D(@UREF) S UI01=""
S1A I $L(UI01),$P(KEU(Q1),D),'$P(KEU(Q1),D,2) D    ; van...tot... overslaan
 . N NIV S NIV=$S(UDD=5:$P(^(UI1),D,30),1:$P(^(UI1,0),D,30)) I $D(@UREF)    ; naked ref. terugzetten
 . I NIV=1 S UI01=""
S1Z Q
 ;
Z X ^cZ Q
ZZ ; 05.02.01 - 16 u 23 * V7.84