cAN1031 ;SELEKTIE ITEM ;%AN103 ; [ 01/04/01  8:20 AM ]
 G 1
 ;
T0 ;Selectie item ;
 ;
T0F ;Sélection sujet ;
 ;
T0E ;Selection item ;
 ;
 ; volgende (1) of vorige (-1) index
S1(S1,S2)          K J S J=$O(@RSD@(S1),S2) I $L(J) S J(0)=$G(^(J))
S1A I $E(J,1,$L(RSJ(1)))'=RSJ(1) S J=""
S1B I J="",S2<0 S J=0
S1Z Q
 ;
 ; tonen van de lijn
S2 N K,S1,S2,UI1,VAN,LEN,TOT,MAX,ZZ S $ZT="TRAP^cAN000"
S2A S MAX=$P(QW(QW),D,4)-($P(QW(QW),D,5)*2),ZZ=$J("",MAX)
S2B S S1="" F  S S1=$O(RSM("LAY",S1)) Q:S1=""  S S2=RSM("LAY",S1) D
 . S K=$P(RSL(I,0),D,$P(S2,D)#100)
 . S VAN=$P(S2,D,2),LEN=$P(S2,D,3),TOT=VAN+LEN-1
 . I $L($P(S2,D,5)) X $P(S2,D,5) ; wat ipv K
 . I $P(S2,D,4) S K=$J(K,LEN)    ; rechts
 . E  S K=$E(K_$J("",LEN),1,LEN) ; links
 . S ZZ=$S(VAN>1:$E(ZZ,1,VAN-1),1:"")_K_$S(TOT<MAX:$E(ZZ,TOT+1,MAX),1:"")
S2Y W /CUP(I+$S($L(RSZ):2,1:0),1),ZZ S RSL(I,9)=ZZ
S2Z Q
 ;
 ; test op niveau & 2° input
S3() N S1,S2 S S1=1
S3A S S2=+$P(J(0),D,30) I S2'=RSN S S1=0
S3B I S1,$L(RSJ(2)) D
 . S S2=$P(J(0),D,RSM(2,"B")#100)
 . S S2=$$DP^cAFA1($$UC^cAFA1(S2)) I $E(S2,1,$L(RSJ(2)))'=RSJ(2) S S1=0
S3Y I S1,$L($G(UFLT)) X UFLT S S1=$T
S3Z Q S1
 ;
 ; balk aan/af
BALK(C) W /CUP(II+$S($L(RSZ):2,1:0),1),/SGR(C),$G(RSL(II,9),$J("",$P(QW(QW),D,4)-($P(QW(QW),D,5)*2)))
BALKZ W /CUP(II+$S($L(RSZ):2,1:0),1),/WDSP Q
 ;
1 W /WSCROFF,/CUP(1+$S($L(RSZ):2,1:0),1),/WCMD
11 S RSJ(1)="",RSJ(2)="",RSD=RSQ2
13 S II=1,J=$G(RSX),JJ=$P(QW(QW),D,3)-($P(QW(QW),D,5)*2)-$S($L(RSZ):2,1:0),RK=0
15 I $L($G(RSX)) S RSCONF=1 F I=1:1:JJ D S1(J,-1) Q:J=0
17 K RSL S I=0 F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 S RSL(I)=J,RSL(I,0)=J(0) D S2 I J=$G(RSX) S II=I
19 I I=1,'RSCONF S RK=28 G 328
 ;
 ; scroll met balk
2 S RSV=RK D BALK(7)
21 D ^cAFA0(RK,0,0,0,0,"23\24\25\26\31\32"_RSKEYS,0,0,0)
 ;
3 ; speciale funkties
320 I $D(^DMC(RSUQ,RSUS,"SYN",0,0,RK,0)) G Y
323 I RK=23 D  G 2                                              ; Home
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0) S II=1 I '$D(RSL(JJ)) Q
 . K RSL W /CUP(1+$S($L(RSZ):2,1:0),1),/WCMD
 . S I=0,J=0 F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 D
 .. S RSL(I)=J,RSL(I,0)=J(0)
 . F I=JJ:-1:1 I $D(RSL(I)) D S2 S II=I
324 I RK=24 D  G 2                                              ; End
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0) S II=$O(RSL(""),-1) I '$D(RSL(JJ)) Q
 . K RSL W /CUP(1+$S($L(RSZ):2,1:0),1),/WCMD
 . S I=0,J="~" F  Q:I=JJ  D S1(J,-1) Q:J=0  I $$S3 S I=I+1 D
 .. F II=I:-1:2 M RSL(II)=RSL(II-1) K RSL(II-1)
 .. S RSL(1)=J,RSL(1,0)=J(0)
 . F I=1:1:JJ I $D(RSL(I)) D S2 S II=I
325 I RK=25 D  G 2                                              ; PgUp
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0) I II=1 S RSV=RK
 . S II=1 I RK'=RSV!'$D(RSL(JJ)) Q
 . S I=1,J=RSL(1) F  Q:I=JJ  D S1(J,-1) Q:J=0  I $$S3 S I=I+1 D
 .. F II=JJ:-1:2 K RSL(II) M RSL(II)=RSL(II-1)
 .. K RSL(1) S RSL(1)=J,RSL(1,0)=J(0)
 . F I=JJ:-1:1 D S2 S II=I
326 I RK=26 D  G 2                                              ; PgDn
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0) I II=JJ S RSV=RK
 . S II=$O(RSL(""),-1) I RK'=RSV!'$D(RSL(JJ)) Q
 . S I=1,J=RSL(JJ) F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 D
 .. F II=1:1:JJ-1 K RSL(II) M RSL(II)=RSL(II+1)
 .. K RSL(JJ) S RSL(JJ)=J,RSL(JJ,0)=J(0)
 . F I=1:1:JJ D S2 S II=I
327 I RK=27 G Y                                                 ; Esc
328 I RK=28 S K=$G(RSL(II)) S:K="" RK=29 G Y                  ; Enter
329 I RK=29 G Y                                                 ; Tab
331 I RK=31 D  G 2                                              ; Pijl ^
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0)
 . I II>1 S II=II-1 Q
 . S I=0,J=RSL(1) F  Q:I  D S1(J,-1) Q:J=0  I $$S3 D
 .. F II=JJ:-1:2 I $D(RSL(II-1)) M RSL(II)=RSL(II-1)
 .. S RSL(1)=J,RSL(1,0)=J(0)
 .. F I=JJ:-1:1 I $D(RSL(I)) D S2 S II=I
332 I RK=32 D  G 2                                              ; Pijl v
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0)
 . I II<$O(RSL(""),-1) S II=II+1 Q
 . I $D(RSL(JJ)) S I=0,J=RSL(JJ) F  Q:I  D S1(J,1) Q:J=""  I $$S3 D
 .. F II=1:1:JJ-1 M RSL(II)=RSL(II+1)
 .. S RSL(JJ)=J,RSL(JJ,0)=J(0)
 .. F I=1:1:JJ D S2 S II=I
 ;
39 D BEL G 21
 ;
Y D BALK(0) K RSD,RSL
YZ Q
 ;
BEL W $C(7) Q     
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84