cI7 ;T-LABELS VERVANGEN IN PROGRAMMA'S ;%I7; [ 01/25/96  10:08 AM ]
 ;
1 D QQM^cQ6 W #!,$P($T(+1),";",2),! D ^cRSEL G YZ:$O(^UTILITY($J,""))=""
11 W !!,"N[] = nederlands   F[] = frans    B[] = beide",!!,"TAALKEUZE : " R K G 1:K="-",11:K'?1A,11:"NnFfBb"'[K&$L(K)
12 S K=$TR(K,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ"),TLN=$S(K="B":"N\F",1:K),PRG="" W !! K ^HULP(boot,$J+(100/10000))
 ;
2 S %ZM="ZL @PRG X %ZM(1),%ZM(2) X:'TP %ZM(3) ZS:'$L(%S) @PRG"
21 S %ZM(1)="S %S="""",TP=0,B=1 F %I=1:1 S A=$T(+%I) Q:A=""""  S A=$P(A,"" ;"",1) I (A_TLL)?1""T""1.N1A S:'TP TB=A,B=%I-1 S TP=TP+1,TE=A"
22 S %ZM(2)="Q:'TP  S:TT'=TP %S=""F1"" Q:$L(%S)  ZR @TB:@TE X %ZM(21)"
23 S %ZM(21)="S %I="""" F  S %I=$O(^HULP(boot,$J,%I)) Q:%I=""""  ZI ^(%I):+B S B=B+1"
24 S %ZM(3)="S B=0 X $S(TL=""N"":%ZM(4),1:%ZM(5)),%ZM(6)"
25 S %ZM(4)="F %I=2:1 S A=$T(+%I) Q:A=""""!B  I $P(A,"" ;"",1)?1""T""1.N1A S B=%I-2"
26 S %ZM(5)="F %I=2:1 S A=$T(+%I) Q:A=""""  I $P(A,"" ;"",1)?1""T""1.N S B=%I"
27 S %ZM(6)="S:'B B=2 ZI "" ;"":+B S B=B+1 X %ZM(21)"
 ;
3 F  S PRG=$O(^UTILITY($J,PRG)) Q:PRG=""  W PRG,$J("",10-$L(PRG)) D
 . F I=1:1:$L(TLN,"\") S TL=$P(TLN,"\",I),TLL=$S(TL="N":TL,1:"") D
 .. S TT=0 K A,^HULP(boot,$J)
 .. I '$D(^cTXT(PRG)) S K="NIET aanwezig in global %TXT" D S1 Q
 .. I '$D(^cTXT(PRG,TL)) S K="NIET aanwezig in global %TXT in het "_$P("\Frans\Nederlands","\",$F("FN",TL)) D S1 Q
 .. S J="" F  S J=$O(^cTXT(PRG,TL,J)) Q:J=""  S K=^(J),A="",TT=TT+1,^HULP(boot,$J,J)="T"_J_$S(TL="N":"",1:TL)_" ;"_K
 .. X %ZM I $L(%S) D @%S
 ;
4 G YZ:$O(^HULP(boot,$J+(100/10000),0))="" W !!!,"In de global ^HULP(",boot,",",$J+(100/10000),") vindt U alle programma's waarvoor de omzetting",!,"NIET doorgevoerd werd.",!!
41 F  S PRG=$O(^(PRG)) Q:PRG=""  W !,PRG,?10,^(PRG)
 ;
YZ K ^HULP(boot,$J) K %I,%S,%ZM,A,B,I,K,PRG,TB,TE,TL,TLL,TLN,TM,TP,TT Q
 ;
S1 W !,PRG,?10,K,!?12,"het programma wordt niet aangepast ",! S ^HULP(boot,$J+(100/10000),PRG)=K
S1Z Q
 ;
F1 S K="AANTAL T-labels niet gelijk in global %TXT en in programma" G FZ
FZ D S1 Q
 ;
Z X ^cZ Q
ZZ ; 05.03.96 - 11 u 08 * V6.1.05