cQ13 ;Functions ;cQ13; [ 02/12/01  9:48 AM ]
 G YZ
 ;
T0 ;Functions ;
T1 ;Programma niet gevonden!;
 ;
T0F ;Functions ;
T1F ;Programme pas trouvé!;
 ;
SWNS N I,NSPC
 ;ZN "%SYS" S NSPC=$G(^cLOG(0,"NAMESPACE",0)) I $ZU(90,10,NSPC) ZN NSPC
 D MASTER^cQ5 S io=$G(io,$$IOS^cQ5)
 F I=io,0 S NSPC=$G(^cLOG(boot,"NAMESPACE",I)) Q:$L(NSPC)
 I $L(NSPC),$ZU(90,10,NSPC) ZN NSPC D MASTER^cQ5 S io=$G(io,$$IOS^cQ5)
SWNSZ Q
 ;
TL(R,S,L) N I,K
 S R=$G(R),S=$G(S),QT=$G(QT),L=$G(L),K=$P($T(@("T1"_QT)),";",2)
 I $L(R) D
 . S SO=$ZU(5) S:$E(R)="%" S="" I $L(S) ZN S
 . I $D(^$|S|ROUTINE(R)) D
 .. S K="" S L=$P($TR(L,":()[]","|||||"),"|")
 .. I $L(L) X "ZL @R S K=$P($T("_L_"),"";"",2)" I $L(K)>5 Q
 .. X "ZL @R S K=$P($T(@(""T0""_QT)),"";"",2) S:$L(K)<5 K=$P($T(+1),"";"",2) S:$L(K)<5 K=$P($T(+1),"";"",3)"
 .. S:K["[" K=$P(K,"[") F I=1:1 Q:$E(K)'=" "  S K=$E(K,2,$L(K))
 . I SO'=$ZU(5) ZN SO
 Q K
 ;
WX I $G(^cLOG(cs,"ZWINTERM",0))=1 D W^cA612 Q   ; activeren ZWINTERM
 E  D X^cA612                                 ; activeren ANSI
 Q
 ;
BX I $G(^cLOG(cs,"ZWINTERM",0))=1 D B^cA612 Q   ; starten ZWINTERM
 E  D X^cA612                                 ; activeren ANSI
 Q
 ;
STUSSD(X) ;Add entry to ^cLOG(boot,"STUSSD")
 N LOG S X=$G(X,"???"),LOG="^cLOG(boot,""STUSSD"")"
 D ^cA106,^cA105,MASTER^cQ5,CLEAN(LOG,45)
 S @LOG@($P($H,","),$P($H,",",2))=X_"\"_DD_"."_DM_"."_DJ_"\"_TD_"\"_$H
 I X="STU",$D(^$R("cANEM0")) D
 . N I,J,L
 . S (I,J)="",L=0
 . F  S I=$O(@LOG@(I),-1) Q:I=""!(L>2)  D
 .. F  S J=$O(@LOG@(I,J),-1) Q:J=""!(L>2)  D
 ... S L=L+1 I L=2,$P(^(J),"\")=X D D1001^cANEM0($T(+0),"STUSSD")
 Q
 ;
CLEAN(LOG,X) ;Clean-up entry in LOG
 N I,DAG,UUR S (DAG,UUR)="",X=$G(X,45)
 F I=2:1 S DAG=$O(@LOG@(DAG),-1) Q:DAG=""  D
 . F I=I-1:1 S UUR=$O(@LOG@(DAG,UUR),-1) Q:UUR=""  I I>X K ^(UUR)
 Q
 ;
LAST(LOG) ;Get last entry from LOG
 N I,J,K S K=""
 S I=$O(@LOG@(""),-1) I I'="" S J=$O(@LOG@(I,""),-1) I J'="" S K=@LOG@(I,J)
 Q K
 ;
ALLN(S) ; get all namespaces for same roepnaam into S
 K S N I,K,L,SYS
 D MASTER^cQ5,NSPC^cQ21(.SYS,1) S (K,L)=""
 F  S K=$O(SYS(K)) Q:K=""  D
 . I $TR(K,"0123456789")'=$TR(cs,"0123456789") K SYS(K)
 . I $TR(K,"0123456789")=$TR(cs,"0123456789") S L=L_$P(K,$TR(cs,"0123456789"),2)_" "
 S:$E(L,$L(L))=" " $E(L,$L(L))=""
 F I=1:1:$L(L," ") S S($TR(cs,"0123456789")_$P(L," ",I))=""
 Q L
 ;
YZ Q
 ;
ZZ ; 24.08.01 -  9 u 19 * Cache-r3.1.8