cQBGJB ;Beheer Background Jobs ;cQBGJB; [ 06/29/01  11:39 AM ]
 ;
T0 ;Beheer van de achtergrond jobs ;
T1 ;Bestand is in gebruik;
T2 ;Nr;Programma;Frequentie;Uur  ;A;Namesp.     Parameters;Last run;Wacht;Systeem;Prioriteit;Q;
T3 ;Elke ;de ;-de;laatste dag;
T4 ; uren ;dag ;werkdag;week;14 dagen;maand; min.;    
T5 ;Donderdag;Vrijdag;Zaterdag;Zondag;Maandag;Dinsdag;Woensdag;
T6 ;Keuze;W[] = wijzigen   A[] = toevoegen   V[] = verwijderen   L[] = logging;.[] = afdrukken  C[] = clear last run   -[] = einde programma   [] = vervolg;
T7 ;Nummer\"xx[] = nummer van de lijn";
T8 ;Dit nummer staat niet op het scherm;
T9 ;Verwijderen\"V[] = verwijderen   ,[] = hernemen";
T10 ;Verwijderen definitief\"V[] = definitief verwijderen   ,[] = hernemen";
T11 ;xx[] = dag van de maand   99[] = laatste dag van de maand;
T12 ;Actief\"0[] = neen   1[] = ja";
T13 ;N;J;
T14 ;Namespace;*[] = alle   ; is niet bereikbaar;
T15 ;Namespace ; bestaat niet;
T16 ;uu:mm[] = start-uur;
T17 ;Master of Shadow\"M[] = master   S[] = shadow   [] = master & shadow";
T18 ;Clear last run\"C[] = clear   ,[] = hernemen";
T19 ;Wachttijd\"Aantal minuten tussen het starten in verschillende namespaces";
T20 ;Computer;
T21 ;Prioriteit\"1-[] = low   0[] = normaal   1[] = high";
T22 ;Q\"ABC[] = Q   [] = EA                    ";
 ;
T0F ;Gestion des jobs non-intercatives ;
T1F ;Fichier est en usage;
T2F ;No;Programme;Frequence ;Heure;A;Namesp.     Paramètres;Last run;Retard;Système;Priorité;Q;
T3F ;Ch. ;le ;-ieme;dernier jour;
T4F ; heures ;jour;jour/trav.;semaine;quinzaine;mois; min.;
T5F ;Jeudi;Vendredi;Samedi;Dimanche;Lundi;Mardi;Mercredi;
T6F ;Choix;W[] = modifiér   A[] = ajouter   V[] = radiér   L[] = logging;.[] = imprimer   C[] = clear last run   -[] = fin du programme   [] = suite;
T7F ;Numéro\"xx[] = numéro de la ligne";
T8F ;Ce numéro n'est pas sur l'ecran;
T9F ;Radiér\"V[] = radiér   ,[] = á reprendre";
T10F ;Radiér definitivement\"V[] = radier definitivement   ,[] = á reprendre";
T11F ;xx[] = jour du mois   99[] = dernier jour du mois;
T12F ;Active\"0[] = non   1[] = oui       ";
T13F ;N;O;
T14F ;Namespace;*[] = tous   ; n'est pas accessible;
T15F ;Namespace ; n'existe pas;
T16F ;hh:mm[] = heure de démarrage;
T17F ;Master ou Shadow\"M[] = master   S[] = shadow   [] = master & shadow";
T18F ;Radiér last run\"C[] = radiér   ,[] = á reprendre";
T19F ;Temps d'attente\"Nombre de minutes entre le démarrage dans les differentes namespaces";
T20F ;Systéme"
T21F ;Priorité\"1-[] = low   0[] = normal   1[] = high";
T22F ;Q\"ABC[] = Q   [] = EA                   ";
 ;
1 D INI^cQ6
 S K=$P($T(@("T0"_QT)),";",2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
 S R="302\2079",RH="702#779",RV="306#2006\344#2044\371#2071\377#2077" D ^cA319
 S K="\403\408\446\472\478\508\546\572\608\646\672" F I=2:1:$L(K,D) S FP=$P(K,D,I) W @F,$P($T(@("T2"_QT)),U,I)
11 D MASTER^cQ5 S (CS,MCS)=cs D NSPC^cQ21(.SYS,1)
 I $O(SYS(CS))="",$O(SYS(CS),-1)="" G 2
 S (K,NMSPT)=""
 F  S K=$O(SYS(K)) Q:K=""  D
 . I $TR(K,"0123456789")'=$TR(CS,"0123456789") K SYS(K)
 . I $TR(K,"0123456789")=$TR(CS,"0123456789") S NMSPT=NMSPT_$P(K,$TR(CS,"0123456789"),2)_" "
 S:$E(NMSPT,$L(NMSPT))=" " $E(NMSPT,$L(NMSPT))="" S MCS=CS,ZT=$ZT
 ;
2 S I4=0
 ;
3 S XP=703,I4S=I4 K A D TIME
 F  S I4=$O(^|MCS|cLOG(CS,"CTK0","AUTO",I4)) Q:I4=""!(XP>1900)  D
 . I $D(^(I4))=10 K ^(I4) Q
 . S L=^(I4),(K,P)=$P(L,D) D PARSE^cQCTK1
 . S NMSPS=$P(L,D,10) S:'$L(NMSPS) NMSPS="1" S:NMSPS="%SYS" NMSPC="%SYS"
 . I NMSPS'="%SYS" S NMSPC=$TR(NMSPC,"0123456789")_$S(NMSPS="*":1,1:$P(NMSPS," ")) I cs?1"V"2.N S NMSPC=cs
 . S NMSPC=cs
 . I $L(B),$D(^$|NMSPC|ROUTINE(B)) S K=$$TL^cQ13(B,NMSPC,P)
31 . S (FP,XP)=XP+100,A(I4)=XP W @F,$J(I4,3) S FP=XP+5 W @F,$E(K,1,36)
 . S RF=$P(L,D,2),FP=XP+43 W @F,$$FREQ(RF) S K=$P(L,D,3) D
 .. I RF=7!(RF=14) I $L(K) W ", ",$$DAG(K)
 .. I RF=30 W ", ",$S(K=99:$P($T(@("T3"_QT)),U,5),1:$P($T(@("T3"_QT)),U,3)_K_$P($T(@("T3"_QT)),U,4))
 . S FP=XP+69 W @F,$P(L,D,4) S FP=XP+75 W @F,$P($T(@("T13"_QT)),U,$P(L,D,5)+2)
 . S (FP,XP)=XP+100 S FP=XP+5 W @F,NMSPS
 . S FP=XP+17 I P["(" W @F,$E($P($P($P(P,":("),"(",2,$L(P,")")),")",1,$L(P,")")-1),1,24)
 . S RL="",X=$O(^cLOG(CS,"CTK0","AUTO",I4,boot,""),-1) I X S X=$O(^cLOG(CS,"CTK0","AUTO",I4,boot,X,""),-1) I X S RL=^(X)
 . S FP=XP+43 I $L(RL) W @F,$E($P(RL,D,2)_" "_$P(RL,D,3),1,25)
 . I '$L(RL),$L($P(L,D,7)) W @F,$P(L,D,7)," ",$P(L,D,8)
 . S FP=XP+71 W @F,$J(+$P(L,D,11),3)
 . S FP=XP+75 W @F,$P(L,D,12)
 . S (FP,XP)=XP+100,FP=XP+5 W @F,$P(L,D,13)
 . S FP=XP+43 S K=+$P(L,D,14) W @F,$S(K=-1:"low",K=1:"High",1:"Normal")
 . S FP=XP+69 S K=$P(L,D,15) W @F,$S(K="":"EA",1:K)
 S VV=0 I I4'="" S VV=1,I4=$O(^|MCS|cLOG(CS,"CTK0","AUTO",I4),-1)
 ;
4 L  D TIME
 S R="K\21\3\"_$P($T(@("T6"_QT)),U,2)_"\SC0\1\\""WAVLC.-""[K\\\1" D S0
 I K="-" G YZ
 G WIJZ:K="W",AAN:K="A",VERW:K="V",LOG:K="L",CLR:K="C" I K="" D CLS G 3
 D ^cQBGJBP:K="." D CLS G 1
41 D STERN G 4
 ;
LOG D S1 G 4:K="-",LOG:K="," D STERJ S FP=2103,J=0,(RD,RT)="" W @F,@F1
 F  S RD=$O(^|MCS|cLOG(CS,"CTK0","AUTO",LINE,boot,RD),-1) Q:RD=""  D
 . F  S RT=$O(^|MCS|cLOG(CS,"CTK0","AUTO",LINE,boot,RD,RT),-1) Q:RT=""   D
 .. W @F S FP=FP+100,J=J+1
 .. S K=^|MCS|cLOG(CS,"CTK0","AUTO",LINE,boot,RD,RT) W:$P(K,D)="no" @F92,*8
 .. W $J($P(K,D),5)," ",$J($P(K,D,2),8)," ",$J($TR($P(K,D,3)," "),5)
 .. W $J("->",3)," ",$J($P(K,D,6),8)," ",$J($TR($P(K,D,7)," "),5)
 .. W:$P(K,D)="no" @F93,*8 W:FP#100<40 "|"
 .. S:FP>2479 FP=2142 I J=8 S FP=2103,J=0 W @F R *K W @F,@F1
 I J'=0 S FP=2103 W @F R *K
 D STERN S FP=2101 W @F,@F1 L -^|MCS|cLOG(CS,"CTK0","AUTO",LINE)
LOGZ G 4
 ;
WIJZ D S1 G 4:K="-",WIJZ:K="," D STERJ S L=^|MCS|cLOG(CS,"CTK0","AUTO",LINE)
WIJZ1 S B=$P(L,D,1),R="B\21\3\"_$P($T(@("T2"_QT)),U,3)_"\\140\\$L(K)!(""-,""[K)\\\\\1" D S0 G 41:K="-",41:K="," S $P(L,D,1)=K
WIJZ2 S B=$P(L,D,2),R="B\22\3\"_$P($T(@("T2"_QT)),U,4)_"\SC1\5\CS1\\22\16\1\\1" D S0 G WIJZ1:K="-",41:K=","
 S $P(L,D,2)=+K W @F,@F2,$$FREQ(K),@F1 S K="" I $P(L,D,2)>30 G WIJZ5:$P(L,D,2)>57600 S $P(L,D,3)="",$P(L,D,4)="" G WIJZ6
WIJZ3 I $P(L,D,2)=7!($P(L,D,2)=14) S B=$P(L,D,3),R="B\22\36\"_$P($T(@("T4"_QT)),U,3)_"\SC2\1\CS2\\22\43\\\1" D S0 G WIJZ2:K="-",41:K="," W @F,@F2,$$DAG(+K)
WIJZ4 I $P(L,D,2)=30 S B=$P(L,D,3),R="B\22\36\"_$P($T(@("T4"_QT)),U,3)_"\SC3\2\CS3\\\\\\1" D S0 G WIJZ2:K="-",41:K=","
 S $P(L,D,3)=+K
WIJZ5 S B=$P(L,D,4),R="B\22\54\"_$P($T(@("T2"_QT)),U,5)_"\SC5\5\TCTR\\\\\\1" D S0 G 41:K=","
 I K="-" S K=$P(L,D,2) G WIJZ4:K=30,WIJZ3:K=7!(K=14),WIJZ2
 S $P(L,D,4)=K
WIJZ6 S B=$P(L,D,5),R="B\22\69\"_$P($T(@("T12"_QT)),U,2)_"\1\\""01-,""[K&$L(K)\\\\\1" D S0 G WIJZ2:K="-",41:K=","
 S $P(L,D,5)=K
WIJZ7 S B=$P(L,D,10),R="B\23\3\"_$P($T(@("T14"_QT)),U,2)_"\SC4\48\CS4\\\\1\\1" D S0 G WIJZ6:K="-",41:K=","
 I K'="*" D
 . K R F I=1:1:$L(K," ")  I $L($P(K," ",I)) S R($P(K," ",I))=""
 . S K="",I="" F  S I=$O(R(I)) Q:I=""  S K=K_I_" "
 . S K=$E(K,1,$L(K)-1)
 I '$L(K) G WIJZ7
 S $P(L,D,10)=K
WIJZ8 S B=$P(L,D,11),R="B\23\23\"_$P($T(@("T19"_QT)),U,2)_"\5\\""-,""[K!(K?.N)\\\1\\1" D S0 G WIJZ7:K="-",41:K=","
 S $P(L,D,11)=K
WIJZ9 I master=slave S K="" G WIJZ91
 S B=$P(L,D,12),R="B\23\43\"_$P($T(@("T17"_QT)),U,2)_"\1\\""MS-,""[K\\\1\\1" D S0 G WIJZ8:K="-",41:K=","
WIJZ91 S $P(L,D,12)=K
WIJZ93 S B=$P(L,D,13) I '$L(K) S K=boot
 S R="B\23\3\"_$P($T(@("T20"_QT)),U,2)_"\SC6\56\CS6\\\\1\\1" D S0 G WIJZ9:K="-",41:K=","
 S:K="." K=boot S $P(L,D,13)=K
WIJZ94 S B=+$P(L,D,14) I B=-1 S B="1-"
 S R="B\23\43\"_$P($T(@("T21"_QT)),U,2)_"\2\\""-10""[K!(K=""1-"")\\\1\\1" D S0 G WIJZ93:K="-",41:K=","
 S:K="1-" K=-1 S $P(L,D,14)=K
WIJZ95 S B=$P(L,D,15)
 S R="B\23\69\"_$P($T(@("T22"_QT)),U,2)_"\3\\K?.U!(""-""[K)\\\1\\1" D S0 G WIJZ94:K="-",41:K=","
 S:K="" K="EA" S $P(L,D,15)=K
WIJZ10 S ^|MCS|cLOG(CS,"CTK0","AUTO",LINE)=L I '$D(A(LINE)) S A(LINE)=$G(A(+$O(A(LINE),-1)))+200
 D STERN,CHECK,CLS S I4=I4S L -^|MCS|cLOG(CS,"CTK0","AUTO",LINE)
 G 3
 ;
AAN S LINE=$O(^|MCS|cLOG(CS,"CTK0","AUTO",""),-1)+1,L=""
 L +^|MCS|cLOG(CS,"CTK0","AUTO",LINE):1 E  G AAN
 G WIJZ1
 ;
VERW D S1 G 4:K="-",VERW:K="," D STERJ
VERW1 S R="K\22\3\"_$P($T(@("T9"_QT)),U,2)_"\1\\""-,V""[K&$L(K)\\\1" D S0 I "-,"[K D STERN G VERW:K="-",4:K=","
 S R="K\22\3\"_$P($T(@("T10"_QT)),U,2)_"\1\\""-,V""[K&$L(K)\\\1" D S0 G VERW1:K="-" I K="," G 41
 K ^|MCS|cLOG(CS,"CTK0","AUTO",LINE) L -^|MCS|cLOG(CS,"CTK0","AUTO",LINE)
 D STERN,RENUM,CLS S I4=I4S
 G 3
 ;
CLR D S1 G 4:K="-",CLR:K=","
 S R="K\22\3\"_$P($T(@("T18"_QT)),U,2)_"\1\\""-,C""[K&$L(K)\\\1" D S0
 I "-,"[K L -^|MCS|cLOG(CS,"CTK0","AUTO",LINE)  G CLR:K="-",41:K=","
 D STERJ F I=6,7,8 S $P(^|MCS|cLOG(CS,"CTK0","AUTO",LINE),D,I)=""
 S X=$O(^cLOG(CS,"CTK0","AUTO",LINE,boot,""),-1) I X S X=$O(^cLOG(CS,"CTK0","AUTO",LINE,boot,X,""),-1) I X K ^(X)
 D STERN,CLS S I4=I4S L -^|MCS|cLOG(CS,"CTK0","AUTO",LINE)
 G 3
 ;
YZ Q
 ;
S0 S R0=$P(R,D,5) I $L(R0),R0'["""" S $P(R,D,5)=R0_"^"_$T(+0)
S0A S R0=$P(R,D,7) I $L(R0),R0'="DCTR" S $P(R,D,7)="",R1=$P(R,D,8),R0=$P($T(@R0),U,2,99) S:$L(R1) R0=R0_"&("_R1_")" S $P(R,D,8)=R0
S0Z K R0,R1 D ^cQ1000 Q
 ;
S1 S R="K\21\3\"_$P($T(@("T7"_QT)),U,2)_"\3\\K?1.3N&K!(K=""-"")\\\" D S0 G S1Z:K="-"
 I '$D(A(+K)) S R=$P($T(@("T8"_QT)),U,2) D MS S K="," G S1Z
 S LINE=+K
 L +^|MCS|cLOG(CS,"CTK0","AUTO",LINE):1 E  S R=$P($T(@("T1"_QT)),";",2) D MS S K=","
S1Z Q
 ;
STERJ S FP=$G(A(LINE),702)-2 W @F,"*" Q
 ;
STERN S FP=$G(A(LINE),702)-2 W @F," " Q
 ;
SC0 W !?2,$P($T(@("T6"_QT)),U,3),!?2,$P($T(@("T6"_QT)),U,4)
SC0Z Q
 ;
SC1 W !?1 F I=1,2,7,+$H,14,30,3600 W:I=14 ! W "   ",I,"[]= ",$$FREQ(I)
SC1Z Q
 ;
CS1 ;"-,"[K&$L(K)!(";1;2;7;14;30;"[(U_(+K)_U))!(K>59&(K<86401))
 ;
SC2 W ! F I=0:1:6 W:I=5 ! W "  ",I,"[] = ",$$DAG(I)
SC2Z Q
 ;
CS2 ;"-,0123456"[K&$L(K)
 ;
SC3 W !?2,$P($T(@("T11"_QT)),U,2)
SC3Z Q
 ;
CS3 ;"-,"[K&$L(K)!(K?1.2N&K&(K<32))!(K=99)
 ;
SC4 N I S I="" W !?2,$P($T(@("T14"_QT)),U,3),"   "
 F  S I=$O(SYS(I)) Q:I=""  W ?2,$P(I,$TR(CS,"0123456789"),2)," "
 Q
 ;
CS4 ;"-,*"[K&$L(K)!(K?1.2N.(.1" ".N))!(K="%SYS")
 ;
SC5 W !?2,@F1,$P($T(@("T16"_QT)),U,2)
SC5Z Q
 ;
SC6 W !?2,"[] = ",B,"   .[] = ",boot
 Q
 ;
CS6 ;("-."[K)!(K?.ANP)
 ;
TCTR ;K?2N1":"2N&($E(K,1,2)<24)&($E(K,4,5)<60)!("-,"[K&$L(K))
 ;
FREQ(K) N I,L S K=+K
 S L=$P($T(@("T4"_QT)),U,$S(K=1:3,K=2:4,K=7:5,K=14:6,K=30:7,1:2))
 I K>57600 D  Q L
 . S %DN=K D 200^%DO S I=$P(%DX,"/",2),L=$E("0"_I,$L(I),3)_"."
 . S I=$P(%DX,"/"),I=$E("0"_I,$L(I),3),L=L_I_"."_$P(%DX,"/",3)
 Q $P($T(@("T3"_QT)),U,2)_$S(K>30:K\3600,1:"")_L_$S(K>30:K#3600\60_$P($T(@("T4"_QT)),U,8),1:"")
 ;
DAG(K) Q $P($T(@("T5"_QT)),U,K+2)
 ;
CLS F XP=800:100:1900 S FP=XP+3 W @F,$J("",3) S FP=FP+4 W @F,$J("",37) S FP=FP+38 W @F,$J("",26) S FP=FP+27 W @F,$J("",5) S FP=FP+6 W @F," "
 Q
 ;
CHECK N I,X,Y D MASTER^cQ5 S X=""
 F  S X=$O(^|MCS|cLOG(CS,"CTK0","AUTO",X)) Q:X=""  S Y=X D
 . F  S Y=$O(^(Y)) Q:Y=""  I $P(^(X),D,1,4)=$P(^(Y),D,1,4) K ^(Y)
 D RENUM Q
 ;
RENUM ;L +^|MCS|cLOG(CS,"CTK0","AUTO"):1 E  S R=$P($T(@("T1"_QT)),";",2) D MS Q
 L +^|MCS|cLOG(CS,"CTK0","AUTO"):1 E  Q
 N I,J,X S I="" K X,^HULP(boot,$J)
 F J=1:1 S I=$O(^|MCS|cLOG(CS,"CTK0","AUTO",I)) Q:I=""  M ^HULP(boot,$J,J)=^(I)
 K ^|MCS|cLOG(CS,"CTK0","AUTO")
 M ^|MCS|cLOG(CS,"CTK0","AUTO")=^HULP(boot,$J)
 K ^HULP(boot,$J)
 L -^|MCS|cLOG(CS,"CTK0","AUTO")
 Q
 ;
TRAP I $ZE["<NOSYS>" S R=$P($T(@("T14"_QT)),U,2)_" "_CS_$P($T(@("T14"_QT)),U,4) D MS G 11
 I $ZE["<NAMESPACE>" S R=$P($T(@("T15"_QT)),U,2)_UCL_$P($T(@("T15"_QT)),U,3) D MS G 31
 W !!,$ze,!! Q
 S $ZT="TRAP" ZQ
 ;
MS U $P S FP=2403 W @F,@F4,R,"  [] = ok ",@F5,@F2,@F0 R K
MSZ Q
 ;
TIME D ^cA105,^cA106 S K=DT_" "_TD_" - "_CS,FP=279-$L(K) W @F,@F92,K,@F93
 Q
 ;
ZZ ; 24.08.01 -  9 u 19 * Cache-r3.1.8