cQCPF ;Manipulate cache.cpf ;cQCPF; [ 01/10/01  7:36 PM ]
 G YZ
 ;
T0 ;Manipulate cache.cpf ;
 ;
T0F ;Manipulate cache.cpf ;
 ;
BU() ; Backup entire cache.cpf
 D MASTER^cQ5
 S CF=$$CPF^cQFILE,ER=$$CF^cQFILE(CF),ER=$$OR^cQFILE(CF),I=1 I ER G BUZ
 F  S ER=$$RF^cQFILE(CF,.K) Q:ER  S ^cCPF(boot,"cache.cpf",I)=K,I=I+1
BUZ Q ER
 ;
COPY() ; Copy entire cache.cpf to drive:\DataM\Database\roepnaam\R\0
 D MASTER^cQ5 S CF=$$CPF^cQFILE
 S K=$$UC(cs) I K?1.U1.2N S K=$TR(K,"1234567890")
 S CFN=$P(CF,"\",1,2)_"\Database\"_K_"\R\0"
 S ER=$$CP^cQFILE(CF,CFN)
COPYZ Q ER
 ;
INIT W !!,"Copy default Global Mapping into cache.cpf",!
 W !!,"Roepnaam: " R RPN I RPN="-" G INIT
 W !!,"Aantal firma's: " R ANTL I ANTL="-" G INIT
 S CF=$$CPF^cQFILE,LOC=$P(CF,"\",1,2)_"\Database\"_RPN_"\"
 S LOC("R0")=LOC_"R\0\",LOC("G0")=LOC_"G\0\"
 F VNR=1:1:ANTL S LOC("G"_VNR)=LOC_"G\"_VNR_"\"
 D INITD
INITZ Q
 ;
INITD ; Do-it
 S RPN=$$UC(RPN) F VNR=1:1:ANTL S K=RPN S:RPN'?1"V"3.N K=K_VNR S NMSP(VNR)=K,GLOM(VNR)=K
 D DATF,NMSPF,GLOMF
 S CFN=$P(CF,".cpf")_".new",ER=$$CF^cQFILE(CFN),ER=$$OW^cQFILE(CFN) I ER G INITDZ
 S ER=$$OR^cQFILE(CF) I ER G INITDZ
 D DATS I 'ER D NMSPS I 'ER D GLOMS I 'ER D REST
 S ER=$$CF^cQFILE(CF),ER=$$CF^cQFILE(CFN)
 S K=$$FSEQ^cQFILE(CF),ER=$$CP^cQFILE(CF,CF_K)  ;make backup of cache.cpf
 S ER=$$CP^cQFILE(CFN,CF)  ;copy new file to cache.cpf
INITDZ Q
 ;
ST ; Copy Standard cache.cpf file
 S CFN=$P(CF,".cpf")_".new",ER=$$CF^cQFILE(CFN),ER=$$OW^cQFILE(CFN) I ER G STZ
 I '$D(SYSD) S SYSD=$E(CFN)
 S ROUT="cQCPF"_$S(VER=3:1,VER=4:2,1:1)
 F J=0:1 S K=$T(1+J^@ROUT) S K=$P(K,";",2) Q:K="END"  D
 . I K["DefLoginNSP" S K="DefLoginNSP="_$$UC(RPN)_"1"
 . I K["wijdir" S K=$P(K,"=",2),K="Wijdir="_SYSD_$E(K,2,$L(K))
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
 S ER=$$CF^cQFILE(CFN)
 S K=$$FSEQ^cQFILE(CF),ER=$$CP^cQFILE(CF,CF_K)  ;make backup of cache.cpf
 S ER=$$CP^cQFILE(CFN,CF)  ;copy new file to cache.cpf
STZ Q
 ;
DATF ; Find if DataSets for ROEPNAAM already there
 S ER=$$OR^cQFILE(CF) I ER G DATFZ
 F  S ER=$$RF^cQFILE(CF,.K) Q:ER  D  Q:ER  I K="[Datasets]" Q
 F  S ER=$$RF^cQFILE(CF,.K) Q:ER  Q:K=""  D
 . I $D(LOC("R0")),$P($$UC(K),",",2)=$$UC(LOC("R0")) K LOC("R0")
 . F I=0:1:ANTL S J="G"_I I $D(LOC(J)),$P($$UC(K),",",2)=$$UC(LOC(J)) K LOC(J)
 S ER=$$CF^cQFILE(CF)
DATFZ Q     
 ;
NMSPF ; Find if NameSpace for ROEPNAAM already exists
 S ER=$$OR^cQFILE(CF) I ER G NMSPFZ
 F  S ER=$$RF^cQFILE(CF,.K) Q:ER  I K="[Namespaces]" Q
 F  S ER=$$RF^cQFILE(CF,.K) Q:ER  Q:K=""  D
 . F I=1:1:ANTL I $D(NMSP(I)),$P($P($$UC(K),","),"=",2)=$$UC(NMSP(I)) K NMSP(I)
 S ER=$$CF^cQFILE(CF)
NMSPFZ Q
 ;
GLOMF ; Find out if Global Mapping for ROEPNAAM and Firma already exists
 S ER=$$OR^cQFILE(CF) I ER G GLOMFZ
 F  S ER=$$RF^cQFILE(CF,.K) Q:ER  D  Q:ER  I K["[NspMap." D
 . F I=1:1:ANTL I $D(GLOM(I)),$$UC(K)=$$UC("[NspMap."_GLOM(I)_"]") K GLOM(I)
 S ER=$$CF^cQFILE(CF)
GLOMFZ Q
 ;
DATS ; Set up DataSets for ROEPNAAM
 I '$D(LOC) G DATSZ
 F   S ER=$$RF^cQFILE(CF,.K) Q:ER  D  Q:ER  I K="[Datasets]" Q
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10))
 F   S ER=$$RF^cQFILE(CF,.K) Q:ER  Q:K=""  D  Q:ER
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10)) I $L(K) S L=K
 S L=$P($P(L,"="),"_",2)+1
 F I="R0","G0" I $D(LOC(I)) D
 . S K="DataSet_"_L_"="_RPN_"-"_I_","_LOC(I)_",,0,"_$S(VER=3:"C",1:"P,0,0"),L=L+1
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10))
 F VNR=1:1:ANTL S I="G"_VNR I $D(LOC(I)) D
 . S K="DataSet_"_L_"="_RPN_"-"_I_","_LOC(I)_",,0,"_$S(VER=3:"C",1:"P,0,0"),L=L+1
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10))
 S ER=$$WF^cQFILE(CFN,$C(13,10))
DATSZ Q
 ;
NMSPS ; Set up NameSpace for ROEPNAAM
 I '$D(NMSP) G NMSPSZ
 F   S ER=$$RF^cQFILE(CF,.K) Q:ER  D  Q:ER  I K="[Namespaces]" Q
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10))
 F   S ER=$$RF^cQFILE(CF,.K) Q:ER  Q:K=""  D  Q:ER
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10)) I $L(K) S L=K
 S L=$P($P(L,"="),"_",2)+1
 F I=1:1:ANTL I $D(NMSP(I)) D
 . S K="Nsp_"_L_"="_NMSP(I)_","_RPN_"-G"_I_",CACHESYS,"_RPN_"-R0,CACHESYS,CACHELIB,CACHETEMP",L=L+1
 . S ER=$$WF^cQFILE(CFN,K_$C(13,10))
 S ER=$$WF^cQFILE(CFN,$C(13,10))
NMSPSZ Q
 ;
GLOMS ; Set up Global Mapping for ROEPNAAM and Firma
 I '$D(GLOM) G GLOMSZ
 F L="[NspMap.","" D
 . F   S ER=$$RF^cQFILE(CF,.K) Q:ER  D  Q:ER  Q:L=""&(K=L)  I $L(L),K[L Q
 .. S ER=$$WF^cQFILE(CFN,K_$C(13,10))
 F I=1:1:ANTL I $D(GLOM(I)) D
 . F J=0:1 S K=$T(1+J^cQCPF0) S K=$P(K,";",2) Q:K="END"  D  Q:ER
 .. I K["[NspMap." S K="[NspMap."_GLOM(I)_"]"
 .. F  Q:K'["roepnaam"  S K=$P(K,"roepnaam")_RPN_$P(K,"roepnaam",2,$L(K,"roepnaam"))
 .. F  Q:K'["Gx"  S K=$P(K,"Gx")_"G"_I_$P(K,"Gx",2,$L(K,"Gx"))
 .. S ER=$$WF^cQFILE(CFN,K_$C(13,10))
GLOMSZ Q
 ;
REST ; Continue until end of cache.cpf
 F   S ER=$$RF^cQFILE(CF,.K) Q:ER  S ER=$$WF^cQFILE(CFN,K_$C(13,10)) Q:ER
RESTZ Q
 ;
YZ Q
 ;
UC(K) Q $TR(K,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")
 ;
ZZ ; 24.08.01 -  9 u 19 * Cache-r3.1.8