cQINST ;Install database customer ;cQINST; [ 01/10/01  7:20 PM ]
 W !!,$P($T(T0),";",2),!
 W !,"Usage:",!?8,"D INTERN^"_$T(+0),!,"or",!?8,"D EXTERN^"_$T(+0),!!
 G YZ
 ;
T0 ;Installeren database klant ;
 ;
T0F ;Installer base des donneés client ;
 ;
INTERN ; Copieer basis voor klant
 W !!,$P($T(T0),";",2),"INTERN"
 D MASTER^cQ5 S (CS,MCS)=cs D NSPC^cQ21(.SYS,1),NS^cQ21(.NS),DB^cQ21(.DB)
 I $O(SYS(CS))="",$O(SYS(CS),-1)="" G YZ
DB W !,"Kopiëer welke basis-namespace? : " R K G YZ:K="-" I K="?" D NMSP G DB
 S K=$$UC^cQFILE(K) S:K="" K=" " I '$D(SYS(K)) D NMSP G DB
 S SNMSP=K
SYS W !,"Naar welk systeem?",!,"(\\system\drive, bvb \\DAM-TEST-W2K\C): " R K I K="-" G DB
 S K=$TR(K,"/","\") I K["_" W !!,"Underscore '_' NIET toegelaten ",! G SYS
 I $L(K)<2 G SYS
 S SYS=K S:$E(SYS,$L(SYS))="\" SYS=$E(SYS,1,$L(SYS)-1)
 I $E(K,1,2)="\\" D  S SYSD=$$UC^cQFILE(K) I K="-" G SYS
 . S K=$P(K,"\",4) I $L(K)>1 S K=$E(K,$L(K))
 . S SYSD=$$UC^cQFILE(K)
 . W !,"Drive op dat systeem: [] = ",SYSD,"  : " R K S:K="" K=SYSD
RPN W !,"Roepnaam? :" R K I K="-" G SYS
 S K=$$UC^cQFILE(K) I '$L(K) G RPN
 I $L(K)>6!(K'?.A.1"-".AN) W !,"Maximaal 6 karakters, bvb TEST, ABC1, ABC-1",! G RPN
 S RPN=K
FIRM W !,"Aantal firma's? : " R K I K="-" G RPN
 I K<1!(K>99) W !,"Geef een getal tussen 0 en 100 (1 t.e.m. 99)",! G FIRM
 S ANTL=K
OK W !!,"OK om verder te gaan? (J/N) : " R K I K="-" G FIRM
 S K=$$UC^cQFILE(K) I '(K="J"!(K="N")) G OK
 I K="N" G SYS
 S VER=$ZV[" (Intel) 4"*4
 ;
 S DDIR=SYS_"\DataM\Database\"_RPN
 ; Copy databases
 W !!,"Copy databases",!
 K S S S("R0")=DB(NS(SNMSP,"routines"))_"Cache.dat"
 S K=DB(NS(SNMSP,"globals")),S("G1")=K_"Cache.dat",S("G0")=$P(K,"\",1,$L(K,"\")-2)_"\0\Cache.dat"
 S T("R0")=DDIR_"\R\0\Cache.Dat"
 F I=0:1:ANTL S T("G"_I)=DDIR_"\G\"_I_"\Cache.dat" I '$D(S("G"_I)) S S("G"_I)=S("G1")
 S I="" F  S I=$O(T(I)) Q:I=""  I $ZU(140,4,T(I))=0 K S(I),T(I)
 I $D(S("R0")) S ER=$$CP^cQFILE(S("R0"),T("R0")) I ER D ERROR G INTERNZ
 F I=0:1:ANTL S J="G"_I I $D(S(J)) S ER=$$CP^cQFILE(S(J),T(J)) Q:ER
 I ER D ERROR G INTERNZ
 ;
 ; Modify cache.cpf
 W !!,"Modify cache.cpf",!
 S CF=SYS_"\DataM\CacheSys\Cache.cpf",I="" K LOC
 F  S I=$O(T(I)) Q:I=""  D
 . S K=T(I) I $E(K,1,2)="\\" S K=SYSD_":\"_$P(K,"\",5,$L(K,"\"))
 . S LOC(I)=$P(K,"\",1,$L(K,"\")-1)_"\"
 D INITD^cQCPF I ER D ERROR G INTERNZ
 ;
 W !!,"Je moet deze configuratie activeren om"
 W !," de namespace",$S(ANTL>1:"s",1:"")," te kunnen gebruiken",!
INTERNZ Q
 ;
EXTERN ; Copieer database naar zijn toestel
 W !!,$P($T(T0),";",2),"OP DEFINITIEF TOESTEL"
 D MASTER^cQ5 S (CS,MCS)=cs D NSPC^cQ21(.SYS,1),NS^cQ21(.NS),DB^cQ21(.DB)
 I $O(SYS(CS))="",$O(SYS(CS),-1)="" G YZ
DBN W !,"Kopiëer welke namespace? : " R K G YZ:K="-" I K="?" D NMSP G DBN
 S K=$$UC^cQFILE(K) S:K="" K=" " I '$D(SYS(K)) D NMSP G DBN
 S SNMSP=K
RPNN S RPN=SNMSP I SNMSP?1.U1.2N S RPN=$TR(SNMSP,"1234567890")
 W !,"Roepnaam : ",RPN
FIRMN W !,"Aantal firma's? : " R K I K="-" G RPNN
 S ANTL=K
SYSN W !,"Naar welk systeem?",!,"(\\system\drive, bvb \\DAM-TEST-W2K\C): " R K I K="-" G DBN
 S SYS=K S:$E(SYS,$L(SYS))="\" SYS=$E(SYS,1,$L(SYS)-1)
 I $L(K)<2 G SYSN
 I $E(K,1,2)="\\" D  S SYSD=$$UC^cQFILE(K) I K="-" G SYSN
 . S K=$P(K,"\",4) I $L(K)>1 S K=$E(K,$L(K))
 . S SYSD=$$UC^cQFILE(K)
 . W !,"Drive op dat systeem: [] = ",SYSD,"  : " R K S:K="" K=SYSD
STN W !,"Kopiëer eerst de 'standaard' Cache.cpf (J/N)? : " R K I K="-" G SYSN
 S K=$$UC^cQFILE(K) I '(K="J"!(K="N")) G STN
 S STN=K="J"
VER W !,"Welke Caché versie (3 of 4 )? : " R K I K="-" G SYSN
 I '(K="3"!(K="4")) G VER
 S VER=K
OKN W !!,"OK om verder te gaan? (J/N) : " R K I K="-" G SYSN
 S K=$$UC^cQFILE(K) I '(K="J"!(K="N")) G OKN
 I K="N" G SYSN
 ;
 S DDIR=SYS_"\DataM\Database\"_RPN
 ; Copy databases
 W !!,"Copy databases",!
 K S,T S S("R0")=DB(NS(SNMSP,"routines"))_"Cache.dat"
 S K=DB(NS(SNMSP,"globals")),S("G0")=$P(K,"\",1,$L(K,"\")-2)_"\0\Cache.dat"
 F I=1:1:ANTL S S("G"_I)=DB(NS($$UC^cQFILE(RPN)_I,"globals"))_"Cache.dat"
 S T("R0")=DDIR_"\R\0\Cache.Dat"
 F I=0:1:ANTL S T("G"_I)=DDIR_"\G\"_I_"\Cache.dat"
 S ER=$$CP^cQFILE(S("R0"),T("R0")) I ER D ERROR G EXTERNZ
 F I=0:1:ANTL S J="G"_I,ER=$$CP^cQFILE(S(J),T(J)) Q:ER
 I ER D ERROR G EXTERNZ
 ;
 ; Copy Standard Cache.cpf
 I STN  D
 . W !,"Copy 'standard' cache.cpf",!
 . S CF=SYS_"\DataM\CacheSys\Cache.cpf" D ST^cQCPF
 . W !,"Create 'journal' directories",!
 . S K=$$MD^cQFILE(SYS_"\DataM\Journal\Aij\")
 . S K=$$MD^cQFILE(SYS_"\DataM\Journal\Wij\")
 ; Modify cache.cpf
 W !!,"Modify cache.cpf",!
 S CF=SYS_"\DataM\CacheSys\Cache.cpf",I="" K LOC
 F  S I=$O(T(I)) Q:I=""  D
 . S K=T(I) I $E(K,1,2)="\\" S K=SYSD_":\"_$P(K,"\",5,$L(K,"\"))
 . S LOC(I)=$P(K,"\",1,$L(K,"\")-1)_"\"
 D INITD^cQCPF I ER D ERROR G EXTERNZ
 ;
 W !!,"Je moet deze configuratie activeren om"
 W !," de namespace",$S(ANTL>1:"s",1:"")," te kunnen gebruiken",!
EXTERNZ Q
 ;
YZ Q
 ;
ERROR U 0 W !,"Er is een fout opgetreden!  Actie gestopt!",!
 Q
 ;
NMSP ; show avalaible namespaces
 N I W ! S I="" F  S I=$O(SYS(I)) Q:I=""  W $J(I,10)
NMSPZ Q
 ;
ZZ ; 24.08.01 -  9 u 19 * Cache-r3.1.8