cT256 ;Boekh. verwerking betaling factuur ;%T686 ; [ 01/02/01  1:43 PM ]
 G 1
 ;
T0 ;Boekh. verwerking betaling factuur ;
 ;
T0F ;Imputation du paiement de facture ;
 ;
T0E ;Accounting processing payment of invoice ;
 ;
 ; Variabelen : BP, FDT, FNR, I1 van de klant, KC, KN, BEDR,
 ;              RB, TTB, FC , GEL
 ; indien meerdere tegenboekingen : GEL is geïndexeerd
 ;              GEL(1) = 1e rekening\bedrag op 1e rekening
 ;              GEL(2) = 2e rekening\bedrag op 2e rekening
 ;                ...
 ;            som van de bedragen in GEL() = BEDR - KKB 
 ;
 ; cumuls en historieken bijwerken
S1 N S1,S2 S X=D,$P(X,D,23)=D F S1=BJ:.01:BJ+.02 I '$D(^(S1)) S ^(S1)=X
S1A F X=0,1 I BC(X) S S1=X*.02+BJ,$P(^(S1),D,BX)=$P(^(S1),D,BX)+BC(X)
S1B S BH=BH\1 D:BPE @BPEC I HIS S S1="B"_RB_"#"_BNR_D G S1D
S1C S S1=BH_"B"_RB,S2=$S($D(^(S1)):^(S1),1:D),^(S1)=NUM_D_DAT_D_($P(S2,D,3)+BC(0))_D_($P(S2,D,4)+BC(1))_D_$P(S2,D,5,99) G S1Z
S1D S BH=BH+.01 S:BH#1=0 HIS=0,BH=BH-1 D ^cT00:'HIS G S1C:'HIS,S1D:$D(^(BH+.01)) S:'$D(^(BH)) ^(BH)=""
S1E I ^(BH)'[S1 G S1D:$L(^(BH))+$L(S1)>255 S ^(BH)=^(BH)_S1
S1Z S (BC(0),BC(1))=0 Q
 ;
 ; wegschrijven in FI
S2 S BNR=@Q93,@Q93=BNR+1 G S2:$D(@("^"_Q_"FI(BP,RB,BNR)"))
 S X=+$P(RB,"D",2) S:'X X="" S ^(BNR)=K_D_D_FNR_D_X_D_OM1
 S $P(^(BNR),D)=$T(+0),$P(^(BNR),D,28)=$H_D_$G(QU)
S2Z Q
 ;
S3(AR) ; locken grootboekrekening
S3A I '$$PLUS^cANLOCK(X,2,$$OMS^cAFA1("AR",$G(QT),1,1)_" "_AR,$S($G(JOBBED):0,1:2)) G S3A
S3Z Q
 ;
 ; meerdere tegenboekingen
S4 S S1="",S2=0,S3=0,S4=1,S5=0
 F  S S1=$O(GEL(S1)) Q:S1=""  D
 . S K=$P(GEL(S1),D,2),S2=S2+K I K>S3 S S4=S1      ; S2=som VM
 . S $P(GEL(S1),D,2)=$$BEDR^cAFE1(Q,K,VM,BF,"F")   ; S3=grootste bedrag
 . S S5=S5+$P(GEL(S1),D,2)                         ; S5=som BF
 S S2=$$BEDR^cAFE1(Q,S2,VM,BF,"F")  ; S2 nu in BF
 S S2=S2-S5 I S2'=0 S $P(GEL(S4),D,2)=$P(GEL(S4),D,2)+S2
S4A S S1="" F  S S1=$O(GEL(S1)) Q:S1=""  D
 .S REK=$P(GEL(S1),D)_" ",X="^"_Q_"AR(REK)" D S3(REK)
 .S K=$P(@("^"_Q_"AR(REK,0)"),D,2)
 .S K=D_FDT_D_NUM_D_CD_D_$P(GEL(S1),D,2)_D_$P("C\D",D,FC="F"+1)_"\A\"_$P(GEL(S1),D)_"#"_K_D_FNR_D_BPE_D_$P(GEL(S1),D,2)
 .D S2 S K=@("^"_Q_"AR(REK,0)"),HIS=$P(K,D,3),BC(FC="C")=$P(GEL(S1),D,2) D S1
 .L -@("^"_Q_"AR(REK)")
S4Z K REK,S1,S2,S3,S4,S5 Q     
 ;
1 N BC,BA39 S $ZT="TRAP^cAN000",BA39=@("^"_Q_"BA(39)")
 I $L(VM),VM'=BF,VM'=$P(BA39,D,9),VM'=$P(BA39,D,7) G YZ
11 S CD="" I $E(RB)="D" G YZ:'$D(GEL) S CD=$$JRN^cAFO2("D",$E(RB,2,9))
13 S DAT=FDT,NUM=$E(DAT,1,5) S:$D(@("^"_Q_"AR(RB_"" "",0)")) CD=$P(^(0),D,10) G YZ:'$L(CD)
15 S (BC(0),BC(1))=0,K=RB_" " S:$E(RB)="D" K=RB S BR=@("^"_Q_"BA(12)"),^(BP,112)=$H,^(K)=$H,^(110)=$H S:'$D(OM1) OM1=""
17 S K=$$DC^cAFD1(DAT),Q93="^"_Q_"BA(4,RB,"_K_")" S:'$D(@Q93) @Q93=K_"0001"
19 I '$$PLUS^cANLOCK(Q93,2,"",$S($G(JOBBED):0,1:2)) G 19
 ;
 ; afboeken factuur bij de klant
2 S X="^"_Q_"KL(I1)" I '$$PLUS^cANLOCK(X,2,$$OMS^cAFA1("KL",$G(QT),1,1)_" "_KC_" "_$P($G(@X@(0)),D,2),$S($G(JOBBED):0,1:2)) G 2
21 S K=@("^"_Q_"KL(I1,FNR)"),HBEDR=BEDR,B=BEDR,BEDR="" S:B="" B=TTB S:B="." B=TTB,BEDR=KKB
 S B=$$BEDR^cAFE1(Q,B,VM,BF,"F") I B>FAK S B=FAK   ; VJ 29.11.00
 S K=FAK-B I $$OMREK^cAFE1(Q,K,BF,"BEF","F","")<5 S B=FAK
 S BEDR=$$BEDR^cAFE1(Q,BEDR,VM,BF,"F")             ; korting contant
 S K=B-BEDR I K<0 S BEDR=BEDR+K
23 S K=D_FDT_D_NUM_D_CD_D_B_D_$P("C\D",D,FC="C"+1)_"\K\"_KC_"#"_KN_D_FNR_D_BPE_D_B
25 D S2 S K=$D(@("^"_Q_"KL(I1,0)")),HIS=1,BC(FC'="C")=B D S1
27 S S1=$P(^(FNR),D,5)-HBEDR,S2=$P(^(FNR),D,10)-$$BEDR^cAFE1(Q,B,BF,$P($$MNTO^cAFE1(Q,BJ),D),"F")
 I S1!S2 S $P(^(FNR),D,5)=S1,$P(^(FNR),D,10)=S2
 E  K ^(FNR),@("^"_Q_"VF(FNR)")
29 L -@("^"_Q_"KL(I1)")
 ;
 ; korting contant
3 G 4:'BEDR S S1=$P(BR,D)_" ",X="^"_Q_"AR(S1)" D S3(S1)
31 S K=D_FDT_D_NUM_D_CD_D_BEDR_D_$P("D\C",D,FC="C"+1)_"\A\"_$P(BR,D)_"#"_$P(BR,D,2)_D_FNR_D_BPE_D_BEDR
33 D S2 S K=$P(BR,D)_" ",K=@("^"_Q_"AR(K,0)"),HIS=$P(K,D,3),BC(FC="C")=BEDR D S1
35 S K=$P(BR,D)_" " L -@("^"_Q_"AR(K)")
 ;
 ; rekening vooruitbetalingen
4 G 5:$E(RB)'="D"        ; indien rechtstreeks op financiële rekening
41 I $O(GEL("")) D S4 G 6 ; indien tegenboekingen op meerdere rekeningen
43 S S1=GEL_" ",X="^"_Q_"AR(S1)" D S3(S1)
45 S K=$P(@("^"_Q_"AR(GEL_"" "",0)"),D,2)
47 S K=D_FDT_D_NUM_D_CD_D_(B-BEDR)_D_$P("C\D",D,FC="F"+1)_"\A\"_GEL_"#"_K_D_FNR_D_BPE_D_(B-BEDR)
48 D S2 S K=GEL_" ",K=@("^"_Q_"AR(K,0)"),HIS=$P(K,D,3),BC(FC="C")=B-BEDR D S1
49 S K=GEL_" " L -@("^"_Q_"AR(K)") G 6
 ;
 ; indien rechtstreekse financiële post (niet gebruikt)
5 S S1=RB_" ",X="^"_Q_"AR(S1)" D S3(S1)
51 S X=@("^"_Q_"AR(RB_"" "",0)"),HIS=0,BC(FC="C")=B-BEDR D S1
53 S K=RB_" " L -@("^"_Q_"AR(K)")
 ;
 ; boeken op grootboekrekening klanten
6 S S1=$P(@("^"_Q_"BA(14,0)"),D)_" ",X="^"_Q_"AR(S1)" D S3(S1)
61 S X=@("^"_Q_"AR(S1,0)"),HIS=0,BC(FC'="C")=B D S1
63 S K=$P(@("^"_Q_"BA(14,0)"),D)_" " L -@("^"_Q_"AR(K)")
 ;
YZ K S1,S2,NUM,DAT,CD,BC,BEDR,BNR,GEL,OM1,Q93,HBEDR Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84