cT661Q ;Betalingsvoorstel leveranciers ;%T66 ; [ 03/13/01  4:27 PM ]
 G 1
 ;
T0 ;Brede lijst ;
T1 ;Leverancier\ Nr.\\Document\Dat.doc.\Vervald.\Openstaand;2\Kort.cont.\Te betalen;2\Munt\Factuurnr. lev.\ Nr.;
 ;
T0F ;Liste large ;
T1F ;Fournisseur\ No.\\Document\Dat.doc.\Echéance\Non soldées;2\Esc.Compt.\A payer;2\Mon.\N° fact. fourn.\ No.;
 ;
T0E ;Brede lijst ;
T1E ;Leverancier\ Nr.\\Document\Dat.doc.\Vervald.\Openstaand;2\Kort.cont.\Te betalen;2\Munt\Factuurnr. lev.\ Nr.;
 ;
 ; brede lijst via module Q[] bij BVS.DET
 ; initialisatie printervariabelen
1 D ^cAN3223(1,1,">80","") G YZ:K="-"
11 S HD(1)=D,HD(2)=D_$$UC^cAFA1($P(^DMC(UQC,USC,"TAAL",$E(QT_"N")),D,2))_";C;F82",HD(3)=D
12 I $P(UTIT,D,5)=2 S HD(2)=D_$$UC^cAFA1($P(^DMH(UQH,USH,0,"TIT","ALT"),D,QTU))_";C;F82"
13 S TAB="31\36\38\47\56\65\79\90\105\110\126\131"
15 S TIT(1)=$P($T(@("T1"_QT)),U,2,4)
17 S I=0 F  S I=$O(UTOP(I)) Q:I=""  D
 . S J=UTOP(I),TOP($P(J,D),$P(J,D,2))=$P(J,D,3)_U_($P(J,D,2)-1)
19 S (OLEV,LEVNAAM)="",LIJN=1
 ;
 ; doorlopen bestand BVS (betalingsvoorstel)
2 S UI1=0 F  S UI1=$O(@(UREF)) Q:UI1=""  D
 . S INH=^(UI1)
 . S LEV=$G(@("^"_Q_"L1($P(INH,D))"))
 . S FACNR=$P(INH,D,2)
 . S INH2=$G(@("^"_Q_"LE(LEV,FACNR)"))
 . D S1
 ; voor laatste leverancier eventueel banknr drukken
21 I OLEV'="" D S2
 ;
 ; einde
3 S END=1 D ^cA334
 ;
YZ K I,J,OLEV,LEV,LEVNAAM,LIJN,INH,INH2,FACNR,ADEC,BANKNR Q
 ;
 ; opzetten TXT variabelen
S1 I LEV'=OLEV&(OLEV'="") D
 . D S2                        ; banknummer vorige leverancier
 . S END=132 D ^cA334          ; blanco lijn na elke leverancier
 . S LIJN=1
S1A S LEVNAAM=$TR($P(@("^"_Q_"LE(LEV,0)"),D,1,2),D," "),BANKNR=$P(^(1),D) I $P(^(1),D,10) S BANKNR=$P(^(1),D,17)
S1B S OLEV=LEV I LIJN=1 S TXT(1)=LEVNAAM
S1C I LIJN=2&(BANKNR'="") D S3
S1D I LIJN>2 S TXT(1)=""
S1E S TXT(3)=$P(INH2,D),TXT(2)=$P(INH,D,7)_D_1,TXT(12)=TXT(2)
S1F I $P(INH2,D)="C" D
 . S $P(INH2,D,5)=-$P(INH2,D,5)
 . S $P(INH2,D,4)=-$P(INH2,D,4)
S1G S TXT(4)=$P(INH,D,2)_D_1,TXT(5)=$P(INH2,D,2),TXT(6)=$P(INH2,D,3)
S1H S ADEC=$$DEC^cAFA1($P(INH,D,6)) ; bepalen van decimalen via VM
S1I S TXT(7)=$P(INH2,D,5)_"\\\\1\"_ADEC,TXT(8)=$P(INH2,D,6)_"\\\\1\"_ADEC
 ; I $P(INH2,D)="C" S TXT(8)="" ; VJ 13.03.01
S1J S TXT(9)=$P(INH,D,3)_"\\\\1\"_ADEC,TXT(10)=$P(INH,D,6),TXT(11)=$P(INH2,D,7)
S1K S LIJN=LIJN+1 D ^cA334 K TXT
S1Z Q
 ;
 ; indien er maar 1 lijn is voor 1 leverancier, banknr extra op lege
 ; lijn afdrukken
S2 I LIJN=2&(BANKNR'="") D S3,^cA334
S2Z Q
 ;
 ; outputformaat banknummer
S3 S BANKNR=$$BANK^cAFO1(BANKNR),TXT(1)=BANKNR
S3Z Q
 ;
ZZ ; 30.03.01 - 13 u 39 * V7.85