cT66E ;Leveranciersbetalingen V6 ;%T66 ; [ 08/14/01  4:27 PM ]
 G 1
 ;
T0 ;Uitvoeren betaling;
T1 ;Banknummer ontbreekt bij leverancier ;
T2 ;Muntcode; verschillend van rekening\".[] = ok";
T3 ;Het bestand bevat lijnen voor verschillende muntcodes\".[] = ok";
T4 ;Landcode; verschillend van rekening\".[] = ok";
T5 ;Het bestand bevat banknummers voor verschillende landen\".[] = ok";
T6 ;Binnenland;Buitenland;
T8 ;Factuur ; reeds betaald; bedrag te groot; komt meerdere keren voor;
T9 ;Negatief bedrag voor leverancier ;
T10 ;Kostencode ontbreekt voor leverancier ;
T11 ;Bankcode ontbreekt voor leverancier ;
T12 ;ISO-landcode banknr/bankcode verschilt voor lev. ;
T13 ;Er zijn geen lijnen om een betaling uit te voeren ;
 ;
T0F ;Exécution paiement;
T1F ;N° bancair manque pour fournisseur ;
T2F ;Code mon.; différent du compte\".[] = ok";
T3F ;Le fichier contient plusieurs codes monétaires\".[] = ok";
T4F ;Code pays; différent du compte\".[] = ok";
T5F ;Le fichier contient des n° bancairs pour plusieurs pays\".[] = ok";
T6F ;National;Internat.;
T8F ;Facture ; déjà payée; montant supérieur; est reprise plusieurs fois;
T9F ;Montant négatif pour fournisseur ;
T10F ;Code frais manque pour fournisseur ;
T11F ;Code bancair manque pour fournisseur ;
T12F ;Code pays ISO n°/code bancair différent pour fourn. ;
T13F ;Il n'y a pas de lignes pour exécuter le paiement ;
 ;
T0E ;Uitvoeren betaling;
T1E ;Banknummer ontbreekt bij leverancier ;
T2E ;Muntcode; verschillend van rekening\".[] = ok";
T3E ;Het bestand bevat lijnen voor verschillende muntcodes\".[] = ok";
T4E ;Landcode; verschillend van rekening\".[] = ok";
T5E ;Het bestand bevat banknummers voor verschillende landen\".[] = ok";
T6E ;Binnenland;Buitenland;
T8E ;Factuur ; reeds betaald; bedrag te groot; komt meerdere keren voor;
T9E ;Negatief bedrag voor leverancier ;
T10E ;Kostencode ontbreekt voor leverancier ;
T11E ;Bankcode ontbreekt voor leverancier ;
T12E ;ISO-landcode banknr/bankcode verschilt voor lev. ;
T13E ;Er zijn geen lijnen om een betaling uit te voeren ;
 ;
 ; via module E[] vanuit BVB.LE
 ; B(1) = BVB
 ; UREF = BVB.LE
1 ;D O^cA612(7,1,15,80,1,0,0,0),T^cA612(" "_$P($T(@("T0"_QT)),U,2)_" ",0,1,1,0,0) ;10.03.00
 D P^cA612(7,1,15,80,1,0,0,0," "_$P($T(@("T0"_QT)),U,2)_" ",0,1,1,0,0)
13 K ^HULP(boot,$J)
15 S (SW,SWBB,SWLD,SWVM)=0,BA39=@("^"_Q_"BA(39)")
17 I BNR'?12N,$D(@("^"_Q_"BA")@("%T",11,BR)) S SWBB=1
 ;
 ; controle per leverancier
 ; UREF = BVB.LE
2 S UI1=0 F  Q:SW  S UI1=$O(@UREF) Q:UI1=""  D
 . S J=^(UI1) I '$P(J,D,2) D DEL^cT66L Q           ; geen facturen
 . I $P(J,D,6)<0 D DEL^cT66L Q                     ; negatief bedrag
 . S I4=$P(J,D,5),K=$P(^DATA(Q,"BVB.LE.B",BVB,I4),D,10)
 . I K="" S K=$E($P($T(@("T1"_QT)),U,2)_$TR($P(^(I4),D,1,2),D," "),1,64),SW=1 D F1 Q
 . S K=$TR($E($P(K,"-"),1,2),"0123456789") I K="" S K=$P(BA39,D,3) I K="" S K="BE"
 . S ^HULP(boot,$J,1,K)=""                         ; landcode
 . S ^HULP(boot,$J,4,$P(J,D),K)=""                 ; ISO-landcode/lev.
21 S KC=0 F  Q:SW  S KC=$O(^HULP(boot,$J,4,KC)) Q:KC=""  D
 . S (IL,SWIFT)=$$SG^cAFA1("LE",KC,305)
 . I SWIFT S IL=$$SIG^cAFA1("SWIFT",SWIFT,105),IL=$$SIG^cAFA1("ISO.LAND",IL,101)
 . I IL="" S IL=$P(BA39,D,3) I IL="" S IL="BE"
 . S K="" F  Q:SW  S K=$O(^HULP(boot,$J,4,KC,K)) Q:K=""  D
 .. I K'=IL,'SWIFT D E1 Q      ; geen SWIFT
 .. I K'=IL D E2 Q             ; ISO-landcode banknummer <> bankcode
29 I SW G Y
 ;
 ; controle facturen
 ; UREF = BVB.DET
3 N UQC,USC,UREF
31 D DMS^cAN000("UQC","USC","BVB.DET") S UREF=^DMC(UQC,USC,"DATA","REF")
33 S UI1=0 F  Q:SW  S UI1=$O(@UREF) Q:UI1=""  D
 . S J=^(UI1),KC=$P(J,D),I1=$$UI1^cAFA1("LE",101,KC)
 . S FNR=$P(J,D,2),OF=$G(@("^"_Q_"LE(I1,FNR)")) I OF="" D E5 Q
 . S K=$P(OF,D,5)-$P(OF,D,12)
 . I $P(J,D,3)>K S K=$P($T(@("T8"_QT)),U,2)_FNR_$P($T(@("T8"_QT)),U,4),SW=1 D F1 Q
 . S K=$P(OF,D,9) D VM(K) I K="" S K=BF
 . S ^HULP(boot,$J,2,VM(K))=""                     ; muntcode
 . I FNR>989999 Q
 . I $D(^HULP(boot,$J,3,FNR)) S K=$P($T(@("T8"_QT)),U,2)_FNR_$P($T(@("T8"_QT)),U,5),SW=1 D F1 Q
 . S ^HULP(boot,$J,3,FNR)=""
38 I '$D(^HULP(boot,$J)) S K=$P($T(@("T13"_QT)),U,2) D F1 G Y
39 I SW G Y
 ;
 ; controle muntcode(s)
4 W /CUP(2,2),@F6,$P($T(@("T2"_QT)),U,2),@F9,": " S SWEUR=0
41 S I="" F  S I=$O(^HULP(boot,$J,2,I)) Q:I=""  D
 . S SWVM=SWVM+1 I SWVM>1 W ", " D
 .. I I=$P(BA39,D,7)!(I=$P(BA39,D,9)) S SWEUR=1 Q
 .. S SWBB=1
 . W I I 'SWBB,I'=$P(BA39,D,7),I'=$P(BA39,D,9) S SWBB=1
43 I SWVM-SWEUR>1 S R="K\22\3\"_$P($T(@("T3"_QT)),U,2)_"\1\\""-.,""[K&$L(K)" D R0 G 5:K=".",Y
45 S I=$O(^HULP(boot,$J,2,""))
47 S VM=$P(B(1),D,4) D VM(VM) I VM(VM)=$P(BA39,D,7)!(VM(VM)=$P(BA39,D,9))&'SWBB G 5
49 I VM(VM)'=I S R="K\22\3\"_$TR($P($T(@("T2"_QT)),U,2,3),U)_"\1\\""-.,""[K&$L(K)" D R0 G Y:K'="." S SWBB=1
 ;
 ; controle landcode(s)
5 W /CUP(4,2),@F6,$P($T(@("T4"_QT)),U,2),@F9,": "
51 S I="" F  S I=$O(^HULP(boot,$J,1,I)) Q:I=""  D
 . S SWLD=SWLD+1 I SWLD>1 W ", " S SWBB=1
 . W I
53 I SWLD>1 S R="K\22\3\"_$P($T(@("T5"_QT)),U,2)_"\1\\""-.,""[K&$L(K)" D R0 G 6:K=".",Y
55 S I=$O(^HULP(boot,$J,1,""))
57 S J=$$SIG^cAFA1("AR",$P(B(1),D,2),109),J=$TR($E($P(J,"-"),1,2),"0123456789") I J="" S J=$P(BA39,D,3) I J="" S J="BE"
59 I J'=I S R="K\22\3\"_$TR($P($T(@("T4"_QT)),U,2,3),U)_"\1\\""-.,""[K&$L(K)" D R0 G Y:K'="." S SWBB=1
 ;
 ; aanduiding binnenland/buitenland
 ; uitsplitsen per leverancier en muntcode
 ; UREF = BVB.DET
6 W /CUP(2,50),"|",/CUP(4,50),"|",/CUP(3,51),"> ",$P($T(@("T6"_QT)),U,2+SWBB)
61 K ^HULP(boot,$J) S SW=0
63 S UI1=0 F  Q:SW  S UI1=$O(@UREF) Q:UI1=""  D
 . S J=^(UI1),KC=$P(J,D),I1=$$UI1^cAFA1("LE",101,KC)
 . S FNR=$P(J,D,2),OF=$G(@("^"_Q_"LE(I1,FNR)")) I OF="" D E5 Q
 . S MF=$P(OF,D,9) D VM(MF) I MF="" S MF=BF
 . S ^HULP(boot,$J,KC,VM(MF),UI1)=J
65 S KC="" F  Q:SW  S KC=$O(^HULP(boot,$J,KC)) Q:KC=""  D
 . I SWBB D
 .. S K=$$SGN^cAFA1("LE",KC,2)
 .. I '$P(K,D,3) D E3 Q        ; geen kostencode
 .. I '$P(K,D,5) D E1 Q        ; geen SWIFT
 . S MF="" F  S MF=$O(^HULP(boot,$J,KC,MF)) Q:MF=""  D
 .. S K=0
 .. S I="" F  S I=$O(^HULP(boot,$J,KC,MF,I)) Q:I=""  S K=K+$P(^(I),D,3)
 .. S ^HULP(boot,$J,KC,MF)=K
 .. I K<0 D E4 Q               ; negatief bedrag
67 I SW G Y
 ;
 ; geen fouten: doorgaan
7 G ^cT66E1
 ;
 ; einde
Y K ^HULP(boot,$J)
YZ D C^cA612 Q
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
 ;
 ; foutboodschappen
E1 S K=$P($T(@("T11"_QT)),U,2) G EZ
E2 S K=$P($T(@("T12"_QT)),U,2) G EZ
E3 S K=$P($T(@("T10"_QT)),U,2) G EZ
E4 S K=$P($T(@("T9"_QT)),U,2) G EZ
E5 S K=$P($T(@("T8"_QT)),U,2)_FNR_$P($T(@("T8"_QT)),U,3) D F1 S SW=1 Q
EZ S K=$E(K_$TR($P($$SGN^cAFA1("LE",KC,0),D,1,2),D," "),1,64) D F1 S SW=1 Q
 ;
F1 S R=250
F2 D TXT^cAFA1(R)
FZ K R Q
 ;
 ; officiële muntcode
VM(K) I K="" S K=BF
 I '$D(VM(K)) S VM(K)=K I $D(@("^"_Q_"BA(11,K)")) S VM(K)=$P(^(K),D)
VMZ Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84