cT66L ;Leveranciersbetalingen V6 ;%T66 ; [ 03/13/01  4:35 PM ]
 G 1
 ;
T0 ;Totaal per leverancier ;
T5 ;Factuurnummer; komt reeds voor bij deze betaling; reeds betaald;
T6 ;Bevestiging\"+[] = enkel leveranciers met positief saldo";
 ;
T0F ;Total par fournisseur ;
T5F ;N° de facture; existe déjà pour ce paiement; déjà payé;
T6F ;Confirmation\"+[] = seulement fournisseurs avec un solde positif";
 ;
T0E ;Totaal per leverancier ;
T5E ;Factuurnummer; komt reeds voor bij deze betaling; reeds betaald;
T6E ;Bevestiging\"+[] = enkel leveranciers met positief saldo";
 ;
 ; opbouw BVB.LE : do uit %T66
 ; (UREF = BVB)
1 N UQC,USC,UREF,UI1
11 D DMS^cAN000("UQC","USC","BVB.DET") S UREF=^DMC(UQC,USC,"DATA","REF")
13 D EG^cAFA1
15 K ^DATA(Q,"BVB.LE",BVB),^HULP(boot,$J)
17 S BF=$$BF^cAFA1 D VM(BF)
 ;
 ; detaillijnen BVB.DET groeperen per leverancier_muntcode
 ; UREF = BVB.DET
2 S UI1=0,VNR=0
21 S UI1=$O(@UREF) I UI1="" G 3
23 S OF=^(UI1),KC=$P(OF,D),MF=$P(OF,D,6) D VM(MF) I MF="" S MF=BF
25 S I4=$G(^HULP(boot,$J,KC,VM(MF)))
27 I 'I4 S VNR=VNR+1,I4=VNR,^(VM(MF))=I4
29 D S2 G 21
 ;
 ; begunstigde & banknummer
3 S UI1=0 F  S UI1=$O(^DATA(Q,"BVB.LE",BVB,UI1)) Q:UI1=""  D
 . S J=^(UI1),KC=$P(J,D),I4=$P(J,D,5)
 . I '$D(^DATA(Q,"BVB.LE.B",BVB,I4)) D S1
 ;
4 D C^cA612
41 K OPNIEUW D BS^cAN210("BVB.LE",1,1,1,0)                ; totaal/lev.
43 I $G(OPNIEUW) D CUM^cT66,REF^cT66 W /CUP(1,1),@F1 G 13 ; na kopiëren
 ;
 ; einde
Y K KC,VM,VNR,I4,TOT,OPNIEUW
YA K ^DATA(Q,"BVB.LE",BVB),^HULP(boot,$J)
YZ Q
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
 ;
 ; begunstigde & banknummer van 1 leverancier: afh. van "factoring"
S1 N B
S1A S B(1)=$$SGN^cAFA1("LE",KC,0),B(2)=^(1)
S1B I '$P(B(2),D,10) S J="101\102\102\104\105\106\107\108\109\201"
S1C I $P(B(2),D,10) S J="101\102\211\299\212\213\214\215\216\217"
S1D F I=1:1 S K=$P(J,D,I) Q:K=""  S $P(B(0),D,I)=$P(B(K\100),D,K#100)
S1Y S ^DATA(Q,"BVB.LE.B",BVB,I4)=B(0)
S1Z Q
 ;
 ; totaal per leverancier_muntcode
S2 S R=$G(^DATA(Q,"BVB.LE",BVB,I4))
S2A S $P(R,D)=KC                                 ; leverancier
S2B S $P(R,D,2)=$P(R,D,2)+1                      ; aantal doc.
S2C S $P(R,D,3)=$P(R,D,3)+$P(OF,D,3)             ; totaal bedrag
S2D S $P(R,D,4)=MF                               ; muntcode
S2E S $P(R,D,5)=$P(OF,D,5)                       ; vvvvvv
S2F S $P(R,D,6)=$P(R,D,6)+$P(OF,D,4)             ; totaal HBF
S2Y S ^DATA(Q,"BVB.LE",BVB,I4)=R
S2Z Q
 ;
 ; Delete : kill combinatie leverancier_muntcode in BVB.LE
 ; UREF = BVB.LE
DEL S R=@UREF K @UREF
DELA N UQC,USC,UREF,UI1
DELB D DMS^cAN000("UQC","USC","BVB.DET") S UREF=^DMC(UQC,USC,"DATA","REF")
DELC N BEGIN,EINDE S BEGIN=$P(R,D,5)*1E6+1E12,EINDE=BEGIN+999999
DELD S UI1=BEGIN F  S UI1=$O(@UREF) Q:UI1=""!(UI1>EINDE)  D
 . S OF=^(UI1) I $P(OF,D)=$P(R,D),$P(OF,D,6)=$P(R,D,4) K ^(UI1)
DELZ D CUM^cT66 Q
 ;
 ; positief saldo : module +[] in BVB.LE
 ; UREF = BVB.LE
POS S R="K\22\3\"_$P($T(@("T6"_QT)),U,2)_"\1\\K=""+""!(K=""-"")" D R0 G POSZ:K="-"
POSA S UI1=0 F  S UI1=$O(@UREF) Q:UI1=""  I $P(^(UI1),D,3)<0 D DEL
POSZ Q
 ;
F ; manueel factuur ingeven
FA S R="FNR\22\3\"_$P($T(@("T5"_QT)),U,2)_"\\6\\K?6N!(K=""-"")" D R0 G FZ:'K
FB I '$D(@("^"_Q_"AF(FNR)")) S K=$P($T(@("T5"_QT)),U,2)_" "_FNR_$P($T(@("T5"_QT)),U,4) D TXT^cAFA1(250) G FA
FC S KC=$P(^(FNR),D) I KC[" " S KC=$P(KC," ",2)
FD S I1=$$UI1^cAFA1("LE",101,KC),OF=$G(@("^"_Q_"LE(I1,FNR)"))
FE S K=$P(OF,D,5)-$P(OF,D,6)-$P(OF,D,12) I $P(OF,D)="C" S K=-K ;-$P(OF,D,6)
FF S R=$$OMREK^cAFA1(K,$P(OF,D,9),HBF,"A",1),TOT=0 D S1^cT66Y2 I SW G FA
FG S OF=@$ZR,MF=$P(OF,D,6) D VM(MF) I MF="" S MF=BF
FH S I4=$G(^HULP(boot,$J,KC,VM(MF)))
FI I 'I4 S VNR=VNR+1,I4=VNR,^(VM(MF))=I4
FJ D S2 S NUI1=I4         ; BVB.LE
FK S I4=$P(OF,D,5) D S1   ; BVB.LE.B
FL N UQC,USC,UREF
FM D DMS^cAN000("UQC","USC","BVB.DET") S UREF=^DMC(UQC,USC,"DATA","REF")
FN D CUM^cT66,REF^cT66
FZ Q
 ;
 ; officiële muntcode
VM(K) I K="" S K=BF
 I '$D(VM(K)) S VM(K)=K I $D(@("^"_Q_"BA(11,K)")) S VM(K)=$P(^(K),D)
VMZ Q
 ;
ZZ ; 30.03.01 - 13 u 39 * V7.85