cT69 ;Overzicht betalingen ;%T69 ; [ 01/03/01  7:41 PM ]
 G 1
 ;
T0 ;Overzicht betalingen ;
T1 ;Financiële rekening;
T2 ;Ongeldig protocolnummer ;
T3 ;Er zijn geen betalingen voor deze rekening ;
T4 ;Volgnummer betaling\"x[] = volgnummer van de gewenste betaling";
T5 ;Voorlopig;Definitief;
T6 ; Geadresseerde\ Fact/C.N.\Betaald ;1\in \ OGM/Referte;
T7 ; Overdracht; Eindtotaal;
T8 ;Uw keuze\"[] = detail printen   V[] = verwijderen";
T9 ;Bevestiging\"V[] = DEFINITIEF verwijderen";
 ;
T0F ;Aperçu des paiements ;
T1F ;Compte financier;
T2F ;N° de protocol invalide ;
T3F ;Il n'y a pas de paiements pour ce banque ;
T4F ;N° d'ordre de paiement\"x[] = n° d'ordre du paiement désiré";
T5F ;Provisoir;Définitif;
T6F ; Destination\ Fact/N.C.\Payé ;1\en \ VCS/Référence;
T7F ; Transfert; Total final;
T8F ;Votre choix\"[] = imprimer détail   V[] = annulation";
T9F ;Confirmation\"V[] = annulation DEFINITIVE";
 ;
T0E ;Survey payments ;
T1E ;Financial account;
T2E ;Invalid protocol number ;
T3E ;There are no payments for this account ;
T4E ;Payment serial number\"x[] = serial number of the desired payment";
T5E ;Provisional;Definitive;
T6E ; Addressee\ Inv./C.N.\Paid    ;1\in \ OGM/Ref.;
T7E ; Transfer;Final total;
T8E ;Choice\"[] = print detail   V[] = remove";
T9E ;Confirmation\"V[] = remove permanently";
 ;
1 S K=$P($T(@("T0"_QT)),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
11 S R="BR\1000\1\1\1\1\1\1\" D ^cT278 G YZ:K="-" S B(1)=^(BR,0)
13 W /CUP(4,3),/SGR(4),$P($T(@("T1"_QT)),U,2),/SGR(0)," : ",$TR($P(B(1),D,1,2),D," "),@F1
15 S HBF=$P(B(1),D,11),PRO=$P(B(1),D,12) I $L(PRO),PRO'=0 G 2
17 S K=$P($T(@("T2"_QT)),U,2) D F1 G 11
 ;
 ; alle betalingen tonen
2 K A,C S I2=0 F  S I2=$O(@("^"_Q_"L3(PRO,I2)")) Q:I2=""  I $G(A)<15 D
 . S A=$G(A)+1,A(A)=^(I2),C(A)=I2
 . W /CUP(A+5,3),$J(A,2),". (",$$DCO^cAFA1(I2\1),") "
 . S R=$P(A(A),D)_D_12_D_D_$$DEC($P(A(A),D,7)) D ^cA103 W $P(A(A),D,7)
 . W "  ",$P(A(A),D,2)
 . W /CUP(A+5,60)," ",$P($T(@("T5"_QT)),U,$P(A(A),D,4)+2),/WCML
21 I '$D(A) S K=$P($T(@("T3"_QT)),U,2) D F1 G 11
23 S R="K\22\3\"_$P($T(@("T4"_QT)),U,2)_D_$L(A)_"\\K?.N&K!(K=""-"")" D R0 G 11:K="-"
25 S NR=+K I '$D(A(NR)) G 23
27 S I2=C(NR)
29 S R="K\23\3\"_$P($T(@("T8"_QT)),U,2)_"\1\\""-V""[K\\\1" D R0 G 23:K="-",5:K="V"
 ;
 ; plaats papier
3 S R=0_D_1 D ^cA345 G 2:$L(K)
31 S HD(1)=D,HD(2)=D_$TR($P(B(1),D,1,2),D," "),HD(3)=D_$$BANK^cAFO1($P(B(1),D,9))_" - "_HBF
33 S TAB="30\41\57\61\79",TIT(1)=$P($T(@("T6"_QT)),U,2,99)
 ;
 ; alfabetische lijst
4 S I1=" " F  S I1=$O(@("^"_Q_"LE(I1)")) Q:I1=""  D
 . Q:'$D(^(I1,0))
 . S KC=$P(^(0),D)
 . Q:'$D(@("^"_Q_"L3(PRO,I2,KC)"))
 . I $G(LN),$G(LNMAX),LN+4>LNMAX S END=4 D ^cA334
 . S SW=1,I4="" F  S I4=$O(@("^"_Q_"L3(PRO,I2,KC,I4)")) Q:I4=""  D
 .. S N=^(I4),VM=$P(N,D,16) I VM="" S VM=$$BF
 .. S TXT(1)="" I SW<5 D
 ... I SW=1 S TXT(1)=$TR($P(N,D,1,2),D," ")_D_D_1
 ... I SW=2 S TXT(1)=$P(N,D,3)_D_D_1
 ... I SW=3 S TXT(1)=$TR($P(N,D,4,5),D," ")_D_D_1
 ... I SW=4 S TXT(1)=$$BANK($P(N,D,8))_D_D_1
 .. S TXT(2)=" "_$P(N,D,9)_" "_$P(N,D,14)
 .. S TXT(3)=$P(N,D,11) I $P(N,D,9)="C" S TXT(3)=-TXT(3)
 .. S TXT(3)=TXT(3)_"\\\\1\"_$$DEC(VM)
 .. S TXT(4)=VM
 .. S TXT(5)=$P(N,D,18) I TXT(5)="" S TXT(5)=$P(N,D,13)
 .. S TXT(5)=TXT(5)_D_D_1 D ^cA334 S SW=SW+1
 . I SW<5 D
 .. S TXT(2)="",TXT(3)="",TXT(4)="",TXT(5)=""
 .. I SW=2 S TXT(1)=$P(N,D,3)_D_D_1 D ^cA334 S SW=SW+1
 .. I SW=3 S TXT(1)=$TR($P(N,D,4,5),D," ")_D_D_1 D ^cA334 S SW=SW+1
 .. I SW=4 S TXT(1)=$$BANK($P(N,D,8))_D_D_1 D ^cA334
 . S END=132 D ^cA334
41 S AFS(1,1)=$P($T(@("T7"_QT)),U,3)
43 S AFS(1,3)=$P(A(NR),D)_"\\\\1\"_$$DEC($P(A(NR),D,7))
45 S AFS(1,4)=$P(A(NR),D,7),END=1 D ^cA334
47 G 2
 ;
 ; aflopen ^_Q_L3: betaling onderweg bij openstaande factuur wegdoen
5 S R="K\23\3\"_$P($T(@("T9"_QT)),U,2)_"\1\\""-V""[K\\\1" D R0 G 2:K'="V"
50 I $P(A(NR),D,4) S KC="" F  S KC=$O(@("^"_Q_"L3(PRO,I2,KC)")) Q:KC=""  D
 . S I1=$$UI1^cAFA1("LE",101,KC)
 . S I4="" F  S I4=$O(@("^"_Q_"L3(PRO,I2,KC,I4)")) Q:I4=""  D
 .. S J=^(I4),FNR=$P(J,D,14),OF=$G(@("^"_Q_"LE(I1,FNR)"))
 .. I $L(OF) D
 ... S $P(OF,D,12)=$P(OF,D,12)-$P(J,D,11) I '$P(OF,D,12) S $P(OF,D,11)=0
 ... S $P(OF,D,13)=$P(OF,D,13)-$P(J,D,19)
 ... I '$P(J,D,19) S $P(OF,D,13)=$P(OF,D,13)-$P(J,D,17)
 ... S @("^"_Q_"LE(I1,FNR)")=OF
 .. K @("^"_Q_"L3(PRO,I2,KC,I4)")
51 K @("^"_Q_"L3(PRO,I2)")
53 W /CUP(6,1),@F1 G 2
 ;
YZ Q
 ;
R0 S R0=$P(R,D,5) I $L(R0),R0'["""" S $P(R,D,5)=R0_"^"_$T(+0)
R0A S R0=$P(R,D,7) I $L(R0),R0'="DCTR" S $P(R,D,7)="",R1=$P(R,D,8),R0=$P($T(@R0),U,2,99) S:$L(R1) R0=R0_"&("_R1_")" S $P(R,D,8)=R0
R0Z S $P(R,D,12)=$T(+0) K R0,R1 D ^cA100 Q  ; v11 30.05.94
 ;
BF() ; muntkode BF ophalen
 N R S R=$P($G(@("^"_Q_"BA(39)")),D) I R="" S R="BEF"
 Q R
 ;
DEC(VM) ; decimalen muntkode
 N R
 I $L(VM) S R=2 I $D(@("^"_Q_"BA(11,VM)")) S R=+$P(^(VM),D,7)
 I VM=$$BF!(VM="") S R=QD
 Q R
 ;
BANK(K) ; bank-nummer
 N R,RL I $L(K) D
 . S R=$P(K,"-"),RL=$P($G(@("^"_Q_"BA(39)")),D,3)
 . S:RL'?1.3U RL="BE" S:R'?1.3U R=RL I R?1.3U,$D(^BA(6,R,2)) X "S K="_^(2)
 Q K
 ;
F1 S R=250
F2 D TXT^cAFA1(R)
FZ K R Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84