cwtotbur ; ;[ 02/25/94  10:29 AM ]
 ;
 Set Q="K"
 Do ^cA604
 ;
 ; Gefaktutreerd
 Set PRNr=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 .Quit:'$D(^KPR(PRNr,"J"_5810))
 .Set Next=""
 .For  Set Next=$O(^AKANAL(PRNr,Next)) Quit:Next=""  Do
 ..Set R=^AKANAL(PRNr,Next),KLNr=$P(R,D,2),Stuks=$P(R,D,4),Omzet=$P(R,D,12)
 ..Do CUMUL(PRNr,KLNr,Stuks,Omzet)
 ;
 ; Orders
 Set KLNr=0
 For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 .Set ORDNr=""
 .For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 ..Set Munt=$P(^KOD(KLNr,"F",ORDNr,1),D,18) Quit:'$D(^KBA(11,Munt))
 ..Set R=^KBA(11,Munt),Pariteit=$P(R,D,5)/$P(R,D,3)
 ..Set OLNr=100
 ..For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:OLNr=""  Do
 ...Set R=^KOD(KLNr,"F",ORDNr,OLNr)
 ...Set PRNr=$P(R,D,2) Quit:'PRNr  Quit:'$D(^KPR(PRNr,"J"_5810))
 ...Set Stuks=$P(R,D,3),Omzet=$P(R,D,9)*Pariteit
 ...Do CUMUL(PRNr,KLNr,Stuks,Omzet)
 ;
 ; Uitleveringen
 Set KLNr=0
 For  Set KLNr=$O(^KUL(KLNr)) Quit:KLNr=""  Do
 .Set BONNr=""
 .For  Set BONNr=$O(^KUL(KLNr,"F",BONNr)) Quit:BONNr=""  Do
 ..Set Munt=$P(^KUL(KLNr,"F",BONNr,1),D,18) Quit:'$D(^KBA(11,Munt))
 ..Set R=^KBA(11,Munt),Pariteit=$P(R,D,5)/$P(R,D,3)
 ..Set OLNr=100
 ..For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:OLNr=""  Do
 ...Set R=^KUL(KLNr,"F",BONNr,OLNr)
 ...Set PRNr=$P(R,D,2) Quit:'PRNr  Quit:'$D(^KPR(PRNr,"J"_5810))
 ...Set Stuks=$P(R,D,3),Omzet=$P(R,D,9)*Pariteit
 ...Do CUMUL(PRNr,KLNr,Stuks,Omzet)
 ;
 Set SubGroep="",(Count,TStuks,TKlanten,TOmzet)=0
 For  Set SubGroep=$O(Local(SubGroep)) Quit:SubGroep=""  Do
 .Set KLNr="",T=$$DISPLS^KLASS(SubGroep)
 .For  Set KLNr=$O(Local(SubGroep,KLNr)) Quit:KLNr=""  Do
 ..Set R=Local(SubGroep,KLNr)
 ..Set $P(T,D,2)=$P(T,D,2)+$P(R,D,2),$P(T,D,3)=$P(T,D,3)+1,$P(T,D,4)=$P(T,D,4)+$P(R,D,4)
 .Set Count=Count+1,Local(Count)=T
 .Set TStuks=TStuks+$P(T,D,2),TKlanten=TKlanten+$P(T,D,3),TOmzet=TOmzet+$P(T,D,4)
 .Kill Local(SubGroep)
 Set T="Totaal\"_TStuks_D_TKlanten_D_TOmzet,Count=Count+1,Local(Count)=T
 Set DL(1)="LD",LD(1)="Local",LD(2)="1;C;L;13;; | \2;N;R;10;;|\3;N;R;10;;|\4;N;R;15;"
 Set LD(8)="Subgroep      |    #Stuks | #Klanten |         Omzet"
 Set LD(10)="CB^"_$ZN,LD(11)="Burbidge"
 Do PRINT^OUTPUT(.LD,"SPT","S")
 Quit
 ;
CUMUL(PRNr,KLNr,Stuks,Omzet) 
 New sFL
 Do FETCHPR^PRODUKT2(PRNr,"sFL")
 Set SubGroep=$P(sFL("I"),D,3),R=$G(Local(SubGroep,KLNr))
 Set $P(R,D,2)=$P(R,D,2)+Stuks,$P(R,D,4)=$P(R,D,4)+Omzet
 Set Local(SubGroep,KLNr)=R
 Quit
 ;
CB(Ref) 
 New R
 If $L(Ref)>1 Set R=@Ref If $P(R,D)="Totaal" Quit "BR\;"
 Quit ""
 ;