kflad ;MODULE BEPALEN LEVERINGSADRES [ 03/04/2002  10:22 AM ]
 ;
 New R,LevAdr,KlantId,Optie,KlNaam,KlAdres
 If '$D(KLNr),$D(KC) New KLNr Set KLNr=KC
 Set LevAdr=$G(B(3)),KlantId=^KK1(KLNr),R=^KKL(KlantId,0)
 Set KlNaam=$P(R,D,2),KlAdres=$P(R,D,5)
 If $G(AutoMb),$D(^MBLOG("T",KLNr,LogNr,"LEVADR")) Set LevAdr=^MBLOG("T",KLNr,LogNr,"LEVADR")
 Else  Do
 .Set Optie="HP" If SWLA="KF17",KlAdres["POSTBUS" Set Optie=Optie_"A"
 .Set Optie=Optie_"M",R=$$SELECT^LEVADR(KLNr,Optie)
 .If 'R Do
 ..Set LevAdr=""
 ..Quit:"\\POST\HOOFD\"[(D_R_D)
 ..Do MANUEEL(.LevAdr,KLNr,$E(R,2,9))
 .Else  Set LevAdr=^KKL(KlantId,"L"_$J(R,3))
 If $P(LevAdr,D,19) Do
 .If $D(^KK1($P(LevAdr,D,19))) Do
 ..Set KlantId=^KK1($P(LevAdr,D,19))
 ..Set LevAdr=$P(LevAdr,D,1)_D_$P(^KKL(KlantId,0),D,2,9)_D_$P(LevAdr,D,10,99)
 .Else  Set (K,B(301))="",U3="NEEN",LevAdr=""
 If KlAdres["POSTBUS",$TR(LevAdr,D,"")="",'$$TXTPOP^FLOW("POSTBUSADRES","",KLNr_" "_KlNaam) Goto kflad
 If $P(LevAdr,D,5)["POSTBUS",'$$TXTPOP^FLOW("POSTBUSADRES","",KLNr_" "_KlNaam) Goto kflad
 Set $P(LevAdr,D,26)=$P(LevAdr,D,26),B(3)=LevAdr
 ;Set:$TR(B(3),D,"")="" (K,B(301))="",U3="NEEN"
 If $TR(B(3),D,"")="" Set (K,B(301))=""
 Else  Set K=1
 Do S1
 Set FP=UL*100+1
 Write @F,@F1
 Quit
 ;
S1 New I,U1,U2
 If SWLA'="KF17"!($TR(B(3),D,"")="") Do
 .Set U1=100
 .For  Set U1=$O(A(U1)) Quit:U1=""  Set U2=A(U1) If $P(U2,U,16)>301,$P(U2,U,16)<400 Do S2(U2)
 If SWLA="KF17" For I=2:1:25 Do
 .Kill B(300+I)
 .Set:$L($P(B(3),D,I)) B(300+I)=$P(B(3),D,I)
 Quit
 ;
S2(U2) New U3,X,K
 Set X=$P(U2,U,16),(K,U3)=$P(B(X\100),D,X#100)
 If $L($P(U2,U,8)) Xecute "Set U3="_$P(U2,U,8)
 Set FP=$P(U2,U,5)*100+$P(U2,U,6)
 Write @F,$J("",$P(U2,U,9)),$J("",$P(U2,U,13)),@F,U3
 Quit
 ;
MANUEEL(LevAdr,KLNr,AdresNr) 
 New %SC,vhScherm,I,R,sFL,KlantId,Pieces
 Set LevAdr=$G(LevAdr)
 If KLNr Do
 .Set vhScherm="N",KlantId=^KK1(KLNr)
 .If AdresNr Set LevAdr=^KKL(KlantId,"L"_$J(AdresNr,3))
 .Else  Do:"\HOOFD\POST\"[(D_AdresNr_D)
 ..For I=10:1:50 Set R=$G(^KKL(0,I)) Set:$P(R,U,16) Pieces($P(R,U,16))=""
 ..Set LevAdr=^KKL(KlantId,0)
 ..For I=1,19,24,25 Set $P(LevAdr,D,I)=""
 ..For I=1:1:$L(LevAdr,D) Set:'$D(Pieces(100+I)) $P(LevAdr,D,I)=""
 Else  Set vhScherm="E"
 Set sFL(1)=LevAdr
 Do @($S(vhScherm="N":"NIEUW",1:"EDIT")_"^vhScherm(""FLOWLEVADR"",,,,,,3)")   
 Do:%SC
 .Set LevAdr=sFL(1)
 Quit
 ;