vhJRNL ; Journaling
 Quit
 
 ; Deze routine word om de minuut op CACHE01 opgeroepen
 ; om ^|"JRNL-ADMIN1"|("ADMIN1","CTK0","AUTO",xx,"CACHE01",$H) op te zetten.
 ; Hiermee kan via $$CHECK^vhJRNL nagekeken worden of de journaling nog actief is.
CTK0
 Quit
 
 ; Ophalen van het te kontroleren nummer
CTKNR()
 New R,CTKNr
 Set CTKNr=""
 For  Set CTKNr=$O(^|"JRNL-ADMIN1"|cLOG("ADMIN1","CTK0","AUTO",CTKNr)) Quit:CTKNr=""  Do  Quit:$P(R,D)="CTK0^vhJRNL"
 . Set R=^|"JRNL-ADMIN1"|cLOG("ADMIN1","CTK0","AUTO",CTKNr)
 Quit CTKNr
 
 ; Controleren of de jounaling nog actief is, indien niet verwitigen via mail
CHECK
 New %TC,R,CTKNr,From,To,ToGroep,Subject,Body,Status,Date,Time,WaitTime
 Set $ZT="^cA400"
 Do INIT
 Do ADD^vhLock("vhJRNL(""CHECK"")")
 Do:%TC
 . Set From=$ZUTIL(110)_"@VANHOECKE.BE"
 . Set ToGroep="SYS",To=$$MAILTO(ToGroep)
 . Set CTKNr=$$CTKNR(),WaitTime=300
 . If CTKNr Do
 . . If $P($H,",",2)>82800!($P($H,",",2)<10800) Quit  ; Niet tussen 23:00 en 03:00 (Backup)
 . . Set R=$G(^|"JRNL-ADMIN1"|cLOG("ADMIN1","CTK0","AUTO",CTKNr))
 . . Quit:'$P(R,D,5)  ; Controle is op non aktief gezet
 . . Set Date=$O(^|"JRNL-ADMIN1"|cLOG("ADMIN1","CTK0","AUTO",CTKNr,"CACHE01",""),-1)
 . . If Date="" Set CTKNr="" Quit  ; Het contrleitem is opgezet maar heeft geen logging
 . . Set Time=$O(^|"JRNL-ADMIN1"|cLOG("ADMIN1","CTK0","AUTO",CTKNr,"CACHE01",Date,""),-1)
 . . If Time="" Set CTKNr="" Quit  ; Het contrleitem is opgezet maar heeft geen logging
 . . Set ^TaskManager("CHECK^vhJRNL")=$H
 . . Quit:$$DIFFTIME^vhDTyp(Date_","_Time,$H)'>WaitTime  ; Vijf minuten respijt
 . . Set Subject="Journaling",Body="De journaling is gestopt,"_$C(13)_"gelieve de nodige aktie te ondernemen."
 . . Set Status=$$SendMiniMail^vhLib(From,To,Subject,Body)
 . . For  Hang 60 Do  Quit:$$DIFFTIME^vhDTyp(Date_","_Time,$H)'>WaitTime  ; Wachten tot de journaling hestart en bijgewerkt is
 . . . Set Date=$O(^|"JRNL-ADMIN1"|cLOG("ADMIN1","CTK0","AUTO",CTKNr,"CACHE01",""),-1)
 . . . Set:Date="" Date=$P($H,",")
 . . . Set Time=$O(^|"JRNL-ADMIN1"|cLOG("ADMIN1","CTK0","AUTO",CTKNr,"CACHE01",Date,""),-1)
 . . . Set:Time="" Time=$P($H,",",2)
 . If 'CTKNr Do  ; Het controleitem is niet opgezet
 . . Set Subject="Journaling",Body="CTK0^vhJRNL bestaat niet meer."
 . . Set Status=$$SendMiniMail^vhLib(From,To,Subject,Body)
 . Do REMOVE^vhLock("vhJRNL(""CHECK"")")
 Quit
 
MAILTO(ToGroep)
 New To
 Set ToGroep=$G(ToGroep,"ERROR")
 If ToGroep="SYS" Set To=$LB("CW@VANHOECKE.BE","PV@VANHOECKE.BE")
 Else  Set To=$LB("CW@VANHOECKE.BE")
 Quit To
 
INIT
 Set D="\"
 Quit