vhLVHERR ;LOKALE VARIABELEN -> ^ERROR ;%A400; Do uit %A220,%A405, Do van %A105,%A106 [ 12/23/2003  4:18 PM ]
 ;
%A400 
 If $P($ZU(5),",")'="MGR",$P(%(0),"\",4)'["<DSCON>" Do
 .If $P(%(0),"\",4)["Stopped",$P(%(0),"\",4)["by Auto-Backup" Quit
 .New D,U,MailId,Program,TUserId,Tekst,Refer,Urgentie,AutoDel,Device,UserId,User,ErrorNr
 .Set D="\",U=";",ErrorNr=$P($P($ZR,"(",2),",")
 .Set Program=$P($T(+1),";",1,2),TUserId="ERROR",Device=$G(%("$I"),$I),Device=$$IO^cQ5(Device)
 .Set UserId=$O(^vhUSER("ID",Device,""))
 .Set User="" Set:UserId User=$P($G(^vhUSER("D",UserId)),D,2)
 .Set Tekst="System : "_$ZU(5)_"~"_"Date   : "_$P(%(0),"\")_"~"_"Time   : "_$P(%(0),"\",2)
 .Set Tekst=Tekst_"~"_"User   : "_$P(%(0),"\",3) Set:$L(User) Tekst=Tekst_" ("_User_")"
 .Set Tekst=Tekst_"~"_"Error  : "_$P(%(0),"\",4)
 .Set Refer="ERROR\"_ErrorNr_"\R\",(Urgentie,AutoDel)=1
 .Set MailId=$$SYSTEM^vhMAIL("","",Program,TUserId,Tekst,Refer,Urgentie,AutoDel)
 Quit
 ;
CHKUTL(FromDate,ToDate,NoMail) 
 New (FromDate,ToDate,NoMail)
 Set D="\"
 Set FromDate=+$G(FromDate),ToDate=+$G(ToDate),NoMail=$G(NoMail) Set:'FromDate FromDate=+$H Set:'ToDate ToDate=+$H
 Set (Tekst,TxtDate)=""
 Set:FromDate'=ToDate TxtDate=" ("_$$EXTDATE^vhDTyp(FromDate)_" - "_$$EXTDATE^vhDTyp(ToDate)_")"
 For FromDate=FromDate:1:ToDate Do
 .Set Errors=$G(^UTILITY("%ER",FromDate,0))
 .Quit:'Errors
 .Set Tekst=Tekst_"~~Date   : "_$$EXTDATE^vhDTyp(FromDate)
 .Set Tekst=Tekst_"~Er werd" Set:Errors'=1 Tekst=Tekst_"en" Set Tekst=Tekst_" ŞB"_Errors
 .Set Tekst=Tekst_" fout" Set:Errors'=1 Tekst=Tekst_"en" Set Tekst=Tekst_" gevonden in ^UTILITYŞb"
 .Set (ErrorNr,ErrCount)=0
 .For  Set ErrorNr=$O(^UTILITY("%ER",FromDate,ErrorNr)) Quit:'ErrorNr  Do
 ..Set Error=$P(^UTILITY("%ER",FromDate,ErrorNr,0),"=",2),Time=$P(^UTILITY("%ER",FromDate,ErrorNr,1),",",2)
 ..Set Job=$P(^UTILITY("%ER",FromDate,ErrorNr,2),"=",2),Device=$P(^UTILITY("%ER",FromDate,ErrorNr,3),"=",2)
 ..Set User=$$USERNAME^vhUSER($$DEVUSER^vhUSER(Device))
 ..Set Tekst=Tekst_"~~Number : "_ErrorNr
 ..Set Tekst=Tekst_"~Time   : "_$$EXTTIME^vhDTyp(Time,"TL")
 ..Set Tekst=Tekst_"~"_"User   : Job "_Job_" Dev "_Device Set:$L(User) Tekst=Tekst_" ("_User_")"
 ..Set Tekst=Tekst_"~"_"Error  : "_Error
 If $L(Tekst) Do
 .Set Tekst="System : ŞBŞK"_$ZU(5)_"ŞbŞk"_TxtDate_Tekst
 .If NoMail Do
 ..Do WRAP^vhRtn1("","Tekst","",.Tekst)
 ..For Tekst=1:1:Tekst Do
 ...Write !,Tekst(Tekst)
 ...Quit:(Tekst#23)
 ...Write !,"[] = vervolg"
 ...Read R
 ...Write $C(13),"            ",*27,"[A"
 .Else  Do
 ..Set Program=$P($T(+1),";")_"LOKALE VARIABELEN -> ^UTILITY",TUserId="ERROR"
 ..Set (Urgentie,AutoDel)=1
 ..For I=1:1 Set Tekst(I)=$E(Tekst,1,500),$E(Tekst,1,500)="" Quit:Tekst=""
 ..Set MailId=$$SYSTEM^vhMAIL("","",Program,TUserId,.Tekst,.Refer,Urgentie,AutoDel)
 Quit
 ;